pm_distUnifElls::setUnifEllsRand Interface Reference

Return a collection of random vectors of size ndim from the ndim-dimensional Multiple MultiVariate Uniform Ellipsoidal (MMVUE) distribution, with the specified input mean(1:ndim, 1:nell) and optionally the specified subset of the Cholesky Factorization of the Gramian matrices of the MMVUE distribution.
More...

Detailed Description

Return a collection of random vectors of size ndim from the ndim-dimensional Multiple MultiVariate Uniform Ellipsoidal (MMVUE) distribution, with the specified input mean(1:ndim, 1:nell) and optionally the specified subset of the Cholesky Factorization of the Gramian matrices of the MMVUE distribution.

Here,

1. the variable ndim represents the number of dimensions of the domain of the distribution (that is, the number of dimensions of the ellipsoids),
2. the variable nsam represents the number of randomly sampled points from the set of ellipsoids specified by the input arguments,
3. the variable nell represents the number of ellipsoids in the distirbution.

Parameters

[in,out]	rng	: The input/output scalar that can be an object of, type rngf_type, implying the use of intrinsic Fortran uniform RNG. type xoshiro256ssw_type, implying the use of xoshiro256** uniform RNG.
[out]	rand	: The output contiguous vector of shape (1:ndim) (or matrix of shape (1:ndim, 1:nsam)) of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the (nsam) random output vector(s).
[out]	mahalSq	: The output vector of shape (1:nell) (or matrix of shape (1:nell, 1:nsam)) of the same type and kind as the output rand, containing the squared Mahalanobis distance(s) of individual randomly sampled vector(s rand(:, isam)) from the centers of the specified ellipsoids in the distribution via the input argument mean(1:ndim, 1:nell). A value larger than 1 for the vector element mahalSq(iell) (or matrix element mahalSq(iell, isam)) implies that the random vector rand(1:ndim, isam) is outside ellipsoid iell specified by the input arguments. A value less than 1 implies that the random vector is within the ellipsoid. Thus, for vector mahalSq(1:nell), the expression count(mahalSq(1:nell) <= 1) yields the membership count of rand(1:ndim) in all input ellipsoids. for matrix mahalSq(1:nell, 1:nsam), the expression count(mahalSq(1:nell, isam) <= 1) yields the membership count of rand(1:ndim, isam) in all input ellipsoids.
[out]	invmul	: The output scalar (or vector of shape (1:nsam)) of the same type and kind as the output rand, (each element of) which represents the inverse of the number of ellipsoids within which the corresponding random vector rand(1:ndim) (or rand(1:ndim, isam)) falls.
[out]	membership	: The output scalar (or vector of shape (1:nsam)) of type integer of default kind IK, (the isam element of) which contains the ID of the ellipsoid from which (the isam) sampled point has been generated.
[in]	mean	: The input contiguous matrix of shape (1:ndim, 1:nell), of the same type and kind as the output rand, representing the centers of the ellipsoids in the distribution.
[in]	chol	: The input contiguous array of shape (1:ndim, 1:ndim, 1:nell) whose specified triangular subset contains the Cholesky Factorization of the Gramian matrix of the MMVUE distribution. (optional, the default is the Identity matrix of rank ndim. It must be present if and only if the input argument subset and invGram are also present.)
[in]	subset	: The input scalar constant that can be any of the following: the constant uppDia or an object of type uppDia_type implying that the upper-diagonal triangular block of the input chol must be used while the lower subset is not referenced. the constant lowDia or an object of type lowDia_type implying that the lower-diagonal triangular block of the input chol must be used while the upper subset is not referenced. This argument is merely a convenience to differentiate the different procedure functionalities within this generic interface. (optional. It must be present if and only if the input argument chol is present.)
[in]	invGram	: The input array of shape (1:ndim, 1:ndim, 1:nell) of the same type and kind as the output argument rand, containing the collection of square matrices of full inverse representative Gramian matrix of the \(\ndim\)-dimensional ellipsoids in the distribution. This argument is needed to determine the membership of the output random vector(s) in the ellipsoids. (optional. It must be present if and only if the input argument chol is present.)
[in]	cumPropVol	: The input vector of shape (0:nell) of the same type and kind as the output argument rand, the subset (1:nell) contains the cumulative proportions of the multiplicative traces of the input Cholesky factors chol of the ellipsoids in the distribution. This argument can be computed as, use pm_mathCumPropExp, only: setCumPropExp, sequence use pm_matrixTrace, only: getMatMulTraceLog real(typeof(rand)) :: cumPropVol(size(mean, 2)) do iell = 1, size(mean, 2, IK) cumPropVol(iell) = getMatMulTraceLog(chol(:, :, iell)) end do call setCumPropExp(cumPropVol, maxArray = maxval(cumPropVol), control = sequence) The presence of this argument significantly boosts the algorithm performance by avoiding redundant, repetitive computations. (optional. It must be present if and only if the input arguments chol and invGram are present and the output argument rand is of rank 1.)

Possible calling interfaces ⛓

use pm_distUnifElls, only: setUnifEllsRand, uppDia, lowDia
 
! 1D output random vector.
 
call setUnifEllsRand(rng, rand(1:ndim), mahalSq(1:nell), invmul, membership, mean(1:ndim, 1:nell))
call setUnifEllsRand(rng, rand(1:ndim), mahalSq(1:nell), invmul, membership, mean(1:ndim, 1:nell), chol(1:ndim, 1:ndim, 1:nell), subset, invGram(1:ndim, 1:ndim, 1:nell), cumPropVol(1:nell))
 
! 2D output random vector.
 
call setUnifEllsRand(rng, rand(1:ndim, 1:nsam), mahalSq(1:nell, 1:nsam), invmul(1:nsam), membership(1:nsam), mean(1:ndim, 1:nell))
call setUnifEllsRand(rng, rand(1:ndim, 1:nsam), mahalSq(1:nell, 1:nsam), invmul(1:nsam), membership(1:nsam), mean(1:ndim, 1:nell), chol(1:ndim, 1:ndim, 1:nell), subset, invGram(1:ndim, 1:ndim, 1:nell))

Warning

The condition size(mean, 1) == size(rand, 1) must hold for the corresponding input arguments.
The condition size(mean, 2) == size(cumPropVol) must hold for the corresponding input arguments.
The condition rank(rand) == 2 .and. size(invmul) == size(rand, 2) must hold for the corresponding input arguments.
The condition rank(rand) == 2 .and. size(invmul) == size(membership) must hold for the corresponding input arguments.
The condition rank(rand) == 2 .and. all(shape(mahalSq) == [size(mean, 2), size(rand, 2)]) must hold for the corresponding input arguments.
The condition size(chol, 1) <= size(chol, 2) must hold for the corresponding input arguments (to ensure that arguments can be passed without data copy).
The condition all(shape(invGram) == [size(mean, 1), size(mean, 1), size(mean, 2)) must hold for the corresponding input arguments.
The condition all([size(chol, 1), size(chol, 3)] == shape(mean)) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

Remarks

The procedures under discussion are impure. The procedures of this generic interface are pure when the input argument rng is set to xoshiro256ssw_type and the compile-time macro CHECK_ENABLED is set to 0 or is undefined.

See also

pm_distNorm
pm_distUnif
pm_distUnifEll
pm_distUnifPar
pm_distUnifElls
pm_distMultiNorm
getUnifEllsLogPDF

Example usage ⛓

program example
 
    use pm_kind, only: SK
    use pm_kind, only: IK, LK
    use pm_io, only: display_type
    use pm_arrayResize, only: setResized
    use pm_distUnif, only: getUnifRand, rngf_type
    use pm_matrixChol, only: getMatChol, uppDia, lowDia
    use pm_distUnifElls, only: setUnifEllsRand
    use pm_distChol, only: getCholRand, uppDia
    use pm_matrixInv, only: getMatInv, choUpp
    use pm_io, only: getErrTableWrite, trans
 
    implicit none
 
    integer(IK) :: ndim, iell, nell, nsam
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    block
        use pm_kind, only: TKG => RKD
        real(TKG), allocatable :: mean(:,:), invGram(:, :, :), chol(:, :, :), rand(:, :), mahalSq(:, :), invmul(:)
        integer(IK), allocatable :: membership(:)
 
        call disp%skip()
        call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
        call disp%show("! Random vectors from Multiple Multivariate Uniform Balls with particular means.")
        call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
        call disp%skip()
 
        call disp%skip()
        call disp%show("ndim = 2; nell = getUnifRand(5, 20); nsam = nell * 1000")
                        ndim = 2; nell = getUnifRand(5, 20); nsam = nell * 1000
        call disp%show("[ndim, nell, nsam]")
        call disp%show( [ndim, nell, nsam] )
        call disp%show("mean = getUnifRand(-5._TKG, +5._TKG, ndim, nell)")
                        mean = getUnifRand(-5._TKG, +5._TKG, ndim, nell)
        call disp%show("mean")
        call disp%show( mean )
        call disp%show("call setResized(mahalSq, [nell, nsam])")
                        call setResized(mahalSq, [nell, nsam])
        call disp%show("call setResized(rand, [ndim, nsam])")
                        call setResized(rand, [ndim, nsam])
        call disp%show("call setResized(membership, nsam)")
                        call setResized(membership, nsam)
        call disp%show("call setResized(invmul, nsam)")
                        call setResized(invmul, nsam)
        call disp%show("call setUnifEllsRand(rngf_type(), rand, mahalSq, invmul, membership, mean)")
                        call setUnifEllsRand(rngf_type(), rand, mahalSq, invmul, membership, mean)
        call disp%show("if (0 /= getErrTableWrite(SK_'setUnifEllsRandMean.txt', reshape([transpose(rand), real(membership, TKG)], [nsam, ndim + 1_IK]))) error stop 'Failed to write the random vectors file.'")
                        if (0 /= getErrTableWrite(SK_'setUnifEllsRandMean.txt', reshape([transpose(rand), real(membership, TKG)], [nsam, ndim + 1_IK]))) error stop 'Failed to write the random vectors file.'
        call disp%skip()
 
        call disp%skip()
        call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
        call disp%show("! Random vectors from Multiple Multivariate Uniform Ellipsoids with particular means.")
        call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
        call disp%skip()
 
        call disp%show("call setResized(chol, [ndim, ndim, nell])")
                        call setResized(chol, [ndim, ndim, nell])
        call disp%show("call setResized(invGram, [ndim, ndim, nell])")
                        call setResized(invGram, [ndim, ndim, nell])
        call disp%show("do iell = 1, nell; chol(:, :, iell) = getCholRand(0._TKG, ndim, uppDia); invGram(:, :, iell) = getMatInv(chol(:, :, iell), choUpp); end do")
                        do iell = 1, nell; chol(:, :, iell) = getCholRand(0._TKG, ndim, uppDia); invGram(:, :, iell) = getMatInv(chol(:, :, iell), choUpp); end do
        call disp%show("chol")
        call disp%show( chol )
        call disp%show("call setUnifEllsRand(rngf_type(), rand, mahalSq, invmul, membership, mean, chol, uppDia, invGram)")
                        call setUnifEllsRand(rngf_type(), rand, mahalSq, invmul, membership, mean, chol, uppDia, invGram)
        call disp%show("if (0 /= getErrTableWrite(SK_'setUnifEllsRandMeanChol.txt', reshape([transpose(rand), real(membership, TKG)], [nsam, ndim + 1_IK]))) error stop 'Failed to write the random vectors file.'")
                        if (0 /= getErrTableWrite(SK_'setUnifEllsRandMeanChol.txt', reshape([transpose(rand), real(membership, TKG)], [nsam, ndim + 1_IK]))) error stop 'Failed to write the random vectors file.'
        call disp%skip()
 
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Random vectors from Multiple Multivariate Uniform Balls with particular means.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
ndim = 2; nell = getUnifRand(5, 20); nsam = nell * 1000
[ndim, nell, nsam]
+2, +8, +8000
mean = getUnifRand(-5._TKG, +5._TKG, ndim, nell)
mean
-2.9804421326474309, -1.3482927006721832, -1.8110630665431691, -1.2959631379537750, -2.3023795164443817, -3.2850247288326160, -3.7832705104089750, +2.5396567470788884
-1.5727114409381304, +2.1622703623306281, -1.4907322130678793, -0.43266049777419990, +0.46715356928837792, -1.5122260044751368, +3.7114548256281150, -3.1941187613007731
call setResized(mahalSq, [nell, nsam])
call setResized(rand, [ndim, nsam])
call setResized(membership, nsam)
call setResized(invmul, nsam)
call setUnifEllsRand(rngf_type(), rand, mahalSq, invmul, membership, mean)
if (0 /= getErrTableWrite(SK_'setUnifEllsRandMean.txt', reshape([transpose(rand), real(membership, TKG)], [nsam, ndim + 1_IK]))) error stop 'Failed to write the random vectors file.'
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Random vectors from Multiple Multivariate Uniform Ellipsoids with particular means.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
call setResized(chol, [ndim, ndim, nell])
call setResized(invGram, [ndim, ndim, nell])
do iell = 1, nell; chol(:, :, iell) = getCholRand(0._TKG, ndim, uppDia); invGram(:, :, iell) = getMatInv(chol(:, :, iell), choUpp); end do
chol
slice(:,:,1) = 
+1.0000000000000000, -0.95884781933593966
+0.0000000000000000, +0.28392051591019835
slice(:,:,2) = 
+1.0000000000000000, -0.95291922971898457
+0.0000000000000000, +0.30322424314651525
slice(:,:,3) = 
+1.0000000000000000, +0.45418607629981694
+0.0000000000000000, +0.89090684591340796
slice(:,:,4) = 
+1.0000000000000000, -0.95610742758034245E-1
+0.0000000000000000, +0.99541879923440113
slice(:,:,5) = 
+1.0000000000000000, +0.97555519530861168
+0.0000000000000000, +0.21975454695267746
slice(:,:,6) = 
+1.0000000000000000, +0.23659867030462828
+0.0000000000000000, +0.97160746662944175
slice(:,:,7) = 
+1.0000000000000000, -0.59234887991871332
+0.0000000000000000, +0.80568157758449821
slice(:,:,8) = 
+0.99999999999999989, -0.34683977841435364E-1
+0.0000000000000000, +0.99939832983705490
call setUnifEllsRand(rngf_type(), rand, mahalSq, invmul, membership, mean, chol, uppDia, invGram)
if (0 /= getErrTableWrite(SK_'setUnifEllsRandMeanChol.txt', reshape([transpose(rand), real(membership, TKG)], [nsam, ndim + 1_IK]))) error stop 'Failed to write the random vectors file.'
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
import os
procname = os.path.basename(os.getcwd())
 
linewidth = 2
fontsize = 17
 
pattern = procname + "*.txt"
fileList = glob.glob(pattern)
 
for file in fileList:
 
    df = pd.read_csv(file, delimiter = ",", header = None)
 
    # definitions for the axes
    left, width = 0.1, 0.65
    bottom, height = 0.1, 0.65
    spacing = 0.015
 
    # start with a square Figure
    fig = plt.figure(figsize = (8, 8), dpi = 200)
 
    plt.rcParams.update({'font.size': fontsize - 2})
    ax = fig.add_axes([left, bottom, width, height]) # scatter plot
    ax_histx = fig.add_axes([left, bottom + height + spacing, width, 0.2], sharex = ax) # histx
    ax_histy = fig.add_axes([left + width + spacing, bottom, 0.2, height], sharey = ax) # histy
 
    for axes in [ax, ax_histx, ax_histy]:
        axes.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        axes.tick_params(axis = "y", which = "minor")
        axes.tick_params(axis = "x", which = "minor")
 
    # no labels
    ax_histy.tick_params(axis = "y", labelleft = False)
    ax_histx.tick_params(axis = "x", labelbottom = False)
 
    # the scatter plot:
    ax.scatter  ( df.values[:, 0]
                , df.values[:, 1]
                , c = df.values[:, -1]
                , zorder = 1000
                , marker = "o"
                , alpha = 1
                , s = 0.3
                )
 
    ax_histx.hist(df.values[:, 0], bins = 50, zorder = 1000)
    ax_histy.hist(df.values[:, 1], bins = 50, orientation = "horizontal", zorder = 1000)
 
    ax.set_xlabel("X", fontsize = 17)
    ax.set_ylabel("Y", fontsize = 17)
 
    plt.savefig(file.replace(".txt",".svg"))

Visualization of the example output ⛓

Test:

test_pm_distUnifElls

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, April 23, 2017, 12:36 AM, Institute for Computational Engineering and Sciences (ICES), University of Texas at Austin

Definition at line 915 of file pm_distUnifElls.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distUnifElls.F90