pm_distUnifSphere::setUnifSphereRand Interface Reference

Return a (collection) of random vector(s) of size ndim uniformly distributed on the surface of an \(n\)-sphere, optionally with the specified input mean(1:ndim) and optionally affine-transformed to a non-uniform distribution on the surface of an \((n+1)\)-ellipsoid represented by the Cholesky Factorization of its Gramian matrix. More...

Detailed Description

Return a (collection) of random vector(s) of size ndim uniformly distributed on the surface of an \(n\)-sphere, optionally with the specified input mean(1:ndim) and optionally affine-transformed to a non-uniform distribution on the surface of an \((n+1)\)-ellipsoid represented by the Cholesky Factorization of its Gramian matrix.

Parameters

[in,out]	rng	: The input/output scalar that can be an object of, type rngf_type, implying the use of intrinsic Fortran uniform RNG. type xoshiro256ssw_type, implying the use of xoshiro256** uniform RNG. (optional, default = rngf_type.)
[out]	rand	: The output contiguous array of rank 1 of length ndim of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the random output vector.
[in]	mean	: The input contiguous vector of the same type, kind, rank, and size as the output rand, representing the center of the sphere. (optional, default = [(0., i = 1, size(rand))]. It must be present if the input argument chol is missing.)
[in]	chol	: The input contiguous matrix of shape (ndim, ndim) whose specified triangular subset contains the Cholesky Factorization of the Gramian matrix of the corresponding hyper-ellipsoid on which the output random vectors must be distributed proportional to the ellipsoidal surface curvature. (optional, the default is the Identity matrix of rank ndim. It must be present if and only if the input argument subset is also present.)
[in]	subset	: The input scalar constant that can be any of the following: the constant uppDia or an object of type uppDia_type implying that the upper-diagonal triangular block of the input chol must be used while the lower subset is not referenced. the constant lowDia or an object of type lowDia_type implying that the lower-diagonal triangular block of the input chol must be used while the upper subset is not referenced. This argument is merely a convenience to differentiate the different procedure functionalities within this generic interface. (optional. It must be present if and only if the input argument chol is present.)

Possible calling interfaces ⛓

use pm_distUnifSphere, only: setUnifSphereRand
 
! single vector, using default rng
 
call setUnifSphereRand(rand(1:ndim), mean(1:ndim))
call setUnifSphereRand(rand(1:ndim), chol(1:ndim, 1:ndim), subset)
call setUnifSphereRand(rand(1:ndim), mean(1:ndim), chol(1:ndim, 1:ndim), subset)
 
! single vector, using custom rng
 
call setUnifSphereRand(rng, rand(1:ndim), mean(1:ndim))
call setUnifSphereRand(rng, rand(1:ndim), chol(1:ndim, 1:ndim), subset)
call setUnifSphereRand(rng, rand(1:ndim), mean(1:ndim), chol(1:ndim, 1:ndim), subset)
 
! collection of `nsam` vectors, using default rng
 
call setUnifSphereRand(rand(1:ndim, 1:nsam), mean(1:ndim))
call setUnifSphereRand(rand(1:ndim, 1:nsam), chol(1:ndim, 1:ndim), subset)
call setUnifSphereRand(rand(1:ndim, 1:nsam), mean(1:ndim), chol(1:ndim, 1:ndim), subset)
 
! collection of `nsam` vectors, using custom rng
 
call setUnifSphereRand(rng, rand(1:ndim, 1:nsam), mean(1:ndim))
call setUnifSphereRand(rng, rand(1:ndim, 1:nsam), chol(1:ndim, 1:ndim), subset)
call setUnifSphereRand(rng, rand(1:ndim, 1:nsam), mean(1:ndim), chol(1:ndim, 1:ndim), subset)

Warning

The condition all(shape(chol) == size(rand, 1)) must hold for the corresponding input arguments.
The condition size(mean, 1, IK) == size(rand) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

Remarks

The procedures under discussion are impure. The procedures of this generic interface are pure when the input argument rng is set to xoshiro256ssw_type and the compile-time macro CHECK_ENABLED is set to 0 or is undefined.

The procedures under discussion are impure.

See also

getNormRand
setNormRand
getUnifRand
setUnifRand
getUnifSphereRand
setUnifSphereRand
getUnifEllRand
setUnifEllRand
getUnifParRand
setUnifParRand

Example usage ⛓

program example
 
    use pm_kind, only: SK
    use pm_kind, only: IK, LK, RK ! all real kinds are supported.
    use pm_io, only: display_type
    use pm_matrixChol, only: getMatChol, uppDia, lowDia
    use pm_distUnifSphere, only: setUnifSphereRand
    use pm_distCov, only: getCovRand
 
    implicit none
 
    integer(IK), parameter  :: NDIM = 2_IK  ! The number of dimensions of the MVN distribution.
    real(RK)                :: mean(NDIM), gramian(NDIM, NDIM), chol(NDIM, NDIM), rand(NDIM)
    integer(IK)             :: info
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Multivariate Uniform Ellipsoidal random vector with given mean and Gramian matrix specified via the Cholesky Lower Triangle.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setUnifSphereRand(rand)")
                    call setUnifSphereRand(rand)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    call disp%skip()
    call disp%show("mean = [-5., -5.]")
                    mean = [-5., -5.]
    call disp%show("call setUnifSphereRand(rand, mean)")
                    call setUnifSphereRand(rand, mean)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    call disp%skip()
    call disp%show("gramian = getCovRand(mold = 1., ndim = ndim)")
                    gramian = getCovRand(mold = 1., ndim = ndim)
    call disp%show("chol = getMatChol(gramian, lowDia)")
                    chol = getMatChol(gramian, lowDia)
    call disp%show("chol")
    call disp%show( chol )
    call disp%show("call setUnifSphereRand(rand, chol, lowDia)")
                    call setUnifSphereRand(rand, chol, lowDia)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    call disp%skip()
    call disp%show("mean")
    call disp%show( mean )
    call disp%show("chol")
    call disp%show( chol )
    call disp%show("call setUnifSphereRand(rand, mean, chol, lowDia)")
                    call setUnifSphereRand(rand, mean, chol, lowDia)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example rand array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        integer(IK) :: fileUnit, i
        integer(IK), parameter :: NVEC = 150_IK
        open(newunit = fileUnit, file = "setUnifSphereRand.RK.txt")
            do i = 1, NVEC
                call setUnifSphereRand(rand)
                write(fileUnit,"(*(g0,:,','))") rand
            end do
        close(fileUnit)
        open(newunit = fileUnit, file = "setUnifSphereRandMean.RK.txt")
            do i = 1, NVEC
                call setUnifSphereRand(rand, mean)
                write(fileUnit,"(*(g0,:,','))") rand
            end do
        close(fileUnit)
        open(newunit = fileUnit, file = "setUnifSphereRandChol.RK.txt")
            chol = getMatChol(getCovRand(mold = 1., ndim = ndim), lowDia)
            do i = 1, NVEC
                call setUnifSphereRand(rand, chol, lowDia)
                write(fileUnit,"(*(g0,:,','))") rand
            end do
        close(fileUnit)
        open(newunit = fileUnit, file = "setUnifSphereRandMeanChol.RK.txt")
            chol = getMatChol(getCovRand(mold = 1., ndim = ndim), lowDia)
            do i = 1, NVEC
                call setUnifSphereRand(rand, mean, chol, lowDia)
                write(fileUnit,"(*(g0,:,','))") rand
            end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Multivariate Uniform Ellipsoidal random vector with given mean and Gramian matrix specified via the Cholesky Lower Triangle.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
call setUnifSphereRand(rand)
rand
-0.48319007093502975, -0.87551547978879340
 
 
mean = [-5., -5.]
call setUnifSphereRand(rand, mean)
rand
-5.2985379453652151, -4.0456022342979230
 
 
gramian = getCovRand(mold = 1., ndim = ndim)
chol = getMatChol(gramian, lowDia)
chol
+1.0000000000000000, +0.0000000000000000
+0.73046934604644775, +0.68294548427123736
call setUnifSphereRand(rand, chol, lowDia)
rand
+0.56086135713348562, +0.97510924728627191
 
 
mean
-5.0000000000000000, -5.0000000000000000
chol
+1.0000000000000000, +0.0000000000000000
+0.73046934604644775, +0.68294548427123736
call setUnifSphereRand(rand, mean, chol, lowDia)
rand
-4.8473015812454419, -4.2135220172244114
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
for kind in ["RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
 
    for file in fileList:
 
        df = pd.read_csv(file, delimiter = ",", header = None)
 
        # definitions for the axes
        left, width = 0.1, 0.65
        bottom, height = 0.1, 0.65
        spacing = 0.015
 
        # start with a square Figure
        fig = plt.figure(figsize=(8, 8))
 
        plt.rcParams.update({'font.size': fontsize - 2})
        ax = fig.add_axes([left, bottom, width, height]) # scatter plot
        ax_histx = fig.add_axes([left, bottom + height + spacing, width, 0.2], sharex = ax) # histx
        ax_histy = fig.add_axes([left + width + spacing, bottom, 0.2, height], sharey = ax) # histy
 
        for axes in [ax, ax_histx, ax_histy]:
            axes.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
            axes.tick_params(axis = "y", which = "minor")
            axes.tick_params(axis = "x", which = "minor")
 
        # no labels
        ax_histy.tick_params(axis = "y", labelleft = False)
        ax_histx.tick_params(axis = "x", labelbottom = False)
 
        # the scatter plot:
        ax.scatter  ( df.values[:, 0]
                    , df.values[:,1]
                    , s = 8
                    , zorder = 1000
                    )
 
        ax_histx.hist(df.values[:, 0], bins = 50, zorder = 1000)
        ax_histy.hist(df.values[:,1], bins = 50, orientation = "horizontal", zorder= 1000)
 
        ax.set_xlabel("X", fontsize = 17)
        ax.set_ylabel("Y", fontsize = 17)
 
        plt.tight_layout()
        plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Test:

test_pm_distUnifSphere

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, April 23, 2017, 12:36 AM, Institute for Computational Engineering and Sciences (ICES), University of Texas at Austin

Definition at line 2576 of file pm_distUnifSphere.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distUnifSphere.F90