pm_distNorm::setNormRand Interface Reference

Return a scalar or array of arbitrary rank of random values from the standard univariate Normal distribution.
More...

Detailed Description

Return a scalar or array of arbitrary rank of random values from the standard univariate Normal distribution.

The procedures of this generic interface use the Ziggurat rejection method to generate Normal-distributed random numbers.

Parameters

[in,out]	rng	: The input/output scalar that can be an object of, type rngf_type, implying the use of intrinsic Fortran uniform RNG for Gamma RNG. type xoshiro256ssw_type, implying the use of xoshiro256** uniform RNG for Normal RNG. (optional, default = rngf_type, implying the use of the intrinsic Fortran RNG.)
[out]	rand	: The output scalar, or array of rank 1, or array of arbitrary rank if the rng argument is missing or set to rngf_type, or of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128). On output, it contains standard Normal-distributed random value(s).
[in]	zig	: The input matrix of shape (1:2, 0:*) of the same type and kind as the output argument rand, containing the information about the Ziggurat layers. This matrix is directly (and must have been) returned by getZigNorm. (optional. default = ZIG_RKB)

Possible calling interfaces ⛓

use pm_distNorm, only: setNormRand
 
call setNormRand(rand(..))
call setNormRand(rand(..), zig(:,:))
 
call setNormRand(rand(:))
call setNormRand(rand(:), zig(:,:))
 
call setNormRand(rng, rand)
call setNormRand(rng, rand, zig(:,:))
 
call setNormRand(rng, rand(:))
call setNormRand(rng, rand(:), zig(:,:))

Warning

The condition precision(rand) <= ZIG_PRECISION must hold for the corresponding input arguments.
The condition all(0._RKG <= zig) must hold for the corresponding input arguments.
The condition size(zig, 1) == 2 must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds. The procedures of this generic interface are always impure when the input argument rng is missing.

Remarks

The procedures under discussion are elemental. The procedures under this generic interface are non-elemental when the input argument zig is present or rng is set to an object of type xoshiro256ssw_type.

See also

getNormRand
setNormRand
setNormRandBox
getNormLogPDF
getNormCDF

Example usage ⛓

program example
 
    use pm_kind, only: SK
    use pm_kind, only: IK, RK ! all real kinds are supported.
    use pm_distNorm, only: setNormRand
    use pm_arraySpace, only: setLinSpace
    use pm_arraySpace, only: setLogSpace
    use pm_io, only: display_type
 
    implicit none
 
    integer(IK), parameter  :: NP = 1000_IK
    real(RK), dimension(NP) :: rand ! mean, std,
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    !call setLinSpace(mean, x1 = -5._RK, x2 = +5._RK)
    !call setLogSpace(std, logx1 = log(0.1_RK), logx2 = log(10._RK))
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Normal random number from a Standard Normal distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setNormRand(rand(1))")
                    call setNormRand(rand(1))
    call disp%show("rand(1)")
    call disp%show( rand(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setNormRand(rand(1:5))")
                    call setNormRand(rand(1:5))
    call disp%show("rand(1:5)")
    call disp%show( rand(1:5) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example rand array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        use pm_distNorm, only: getZigNorm
        real(RK) :: abserr
        real(RK), allocatable :: zig(:,:)
        integer(IK) :: fileUnit, i
        integer(IK), parameter :: NP = 10000_IK
        real(RK), dimension(NP) :: rand1, rand2, rand3
        zig = getZigNorm(2_IK, abserr)
        call setNormRand(rand1, zig); rand1 = rand1 * 3.0_RK + 2._RK
        call setNormRand(rand2, zig); rand2 = rand2 * 1.0_RK + 0._RK
        call setNormRand(rand3); rand3 = rand3 * 1.0_RK - 5._RK
        open(newunit = fileUnit, file = "setNormRand.RK.txt")
        write(fileUnit,"(3(g0,:,' '))") ( rand1(i) &
                                        , rand2(i) &
                                        , rand3(i) &
                                        , i = 1,NP &
                                        )
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Normal random number from a Standard Normal distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
call setNormRand(rand(1))
rand(1)
+0.80252009389077461
 
 
call setNormRand(rand(1:5))
rand(1:5)
-0.24646726760892629, -0.11577041583496477, +0.72691743029498113, -1.3053477470218346, +1.8072169383799661
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : "Normal Random Number ( real/imaginary components )"
        , "IK" : "Normal Random Number ( integer-valued )"
        , "RK" : "Normal Random Number ( real-valued )"
        }
legends =   [ r"$\mu = -5.,~\sigma = 1.0$"
            , r"$\mu = 0.0,~\sigma = 1.0$"
            , r"$\mu = 2.0,~\sigma = 3.0$"
            ]
 
for kind in ["IK", "CK", "RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = " ", header = None)
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
        ax = plt.subplot()
 
        if kind == "CK":
            plt.hist( df.values[:,0:3]
                    , histtype = "stepfilled"
                    , alpha = 0.5
                    , bins = 75
                    )
        else:
            plt.hist( df.values[:,0:3]
                    , histtype = "stepfilled"
                    , alpha = 0.5
                    , bins = 75
                    )
            ax.legend   ( legends
                        , fontsize = fontsize
                        )
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel(xlab[kind], fontsize = 17)
        ax.set_ylabel("Count", fontsize = 17)
        ax.set_title("Histograms of {} Normal random numbers".format(len(df.values[:, 0])), fontsize = 17)
 
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
 
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Benchmarks:

Benchmark :: The runtime performance of setNormRand for different implementations of the Box-Muller algorithm. ⛓

! Test the overhead of calling `setNormRand()` vs. Fortran intrinsic procedure `random_number()`.
program benchmark
 
    use pm_kind, only: IK, RK, RKG => RK, SK
    use pm_distNorm, only: xoshiro256ssw_type
    use pm_distNorm, only: setNormRand
    use pm_distNorm, only: getZigNorm
    use pm_bench, only: bench_type
 
    implicit none
 
    integer(IK)                         :: ibench
    integer(IK)                         :: nlay
    integer(IK)                         :: iset
    integer(IK)                         :: fileUnit
    integer(IK)         , parameter     :: NSET = 13_IK
    integer(IK)         , parameter     :: NSIM = 10000_IK
    real(RKG)           , allocatable   :: zig(:,:)
    real(RKG)                           :: rand(NSIM)
    real(RKG)                           :: dummy = 0._RKG
    type(bench_type)    , allocatable   :: bench(:)
    type(xoshiro256ssw_type)            :: rng
 
    rng = xoshiro256ssw_type()
    bench = [ bench_type(name = SK_"setNormRandX256", exec = setNormRandX256, overhead = setOverhead) &
            , bench_type(name = SK_"setNormRandFRNG", exec = setNormRandFRNG, overhead = setOverhead) &
            ]
 
    open(newunit = fileUnit, file = "main.out", status = "replace")
 
        write(fileUnit, "(*(g0,:,','))") "ZigguratLayerCount", (bench(ibench)%name, ibench = 1, size(bench))
 
        loopOverZigSets: do iset = 1, NSET
 
            nlay = 2**iset
            zig = getZigNorm(nlay, dummy)
            write(*,"(*(g0,:,' '))") "Benchmarking setNormRand() with ziggurat set size and abserr", nlay, dummy
            do ibench = 1, size(bench)
                bench(ibench)%timing = bench(ibench)%getTiming(miniter = 10_IK)
            end do
            write(fileUnit, "(*(g0,:,','))") nlay, (bench(ibench)%timing%mean / NSIM, ibench = 1, size(bench))
            write(*,"(*(g0,:,' '))") dummy
 
        end do loopOverZigSets
 
    close(fileUnit)
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead()
        call getDummy()
    end subroutine
 
    subroutine getDummy()
        dummy = dummy + sum(rand)
    end subroutine
 
    subroutine setNormRandFRNG()
        call setNormRand(rand, zig)
        call getDummy()
    end subroutine
 
    subroutine setNormRandX256()
        call setNormRand(rng, rand, zig)
        call getDummy()
    end subroutine
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
import os
dirname = os.path.basename(os.getcwd()) 
 
fontsize = 14
 
df = pd.read_csv("main.out", delimiter = ",")
colnames = list(df.columns.values)
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.plot( df[colnames[0]].values
            , df[colname].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel(colnames[0], fontsize = fontsize)
ax.set_ylabel("Runtime [ seconds ]", fontsize = fontsize)
ax.set_title(" vs. ".join(colnames[1:])+"\nLower is better.", fontsize = fontsize)
ax.set_xscale("log")
ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.png")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.plot( df[colnames[0]].values
            , df[colname].values / df[colnames[1]].values.min()
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel(colnames[0], fontsize = fontsize)
ax.set_ylabel("Runtime compared to the fastest {}.".format(colnames[1]), fontsize = fontsize)
ax.set_title("Runtime Ratio Comparison. Lower means faster.\nLower than 1 means faster than the fastest {}() run.".format(colnames[1]), fontsize = fontsize)
ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, bbox_to_anchor = (1, 0.5)
           #, loc = "center left"
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.ratio.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. The benchmark procedures named setNormRandX256 and setNormRandFRNG call the generic interface setNormRand to generate Normal random values via Ziggurat algorithm with the Xoshiro256** and the intrinsic Fortran Uniform RNG, respectively.
   This benchmark confirms the popular choice of the number of 256 Ziggurat layers as the optimal value.
   Nevertheless, the benchmarks appear to show improvements with even larger number of Ziggurat layers, depending on the platform, processor, and compiler choice.
   

Test:

test_pm_distNorm

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 2022 of file pm_distNorm.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distNorm.F90