pm_distUnifPar::getUnifParRand Interface Reference

Generate and return a random vector from the \(\ndim\)-dimensional MultiVariate Uniform Parallelepiped (MVUP) Distribution.
More...

Detailed Description

Generate and return a random vector from the \(\ndim\)-dimensional MultiVariate Uniform Parallelepiped (MVUP) Distribution.

See the documentation of pm_distUnifPar for details of the definition of the PDF.

Parameters

[in]	lb	: The input scalar or contiguous vector of the same type and kind as the output argument rand. If ub is a scalar, then lb must be a scalar representing the lower bound of the ndim-dimensional hyper-cube support of the distribution. If ub is a vector, then lb must be a vector representing the lower bound of the ndim-dimensional hyper-rectangle support of the distribution. If ub is a matrix, then lb must be a vector representing the origin of the coordinate system with respect to which the ndim-dimensional hyper-parallelepiped support of the distribution is determined. (optional. default = 0)
[in]	ub	: The input scalar or contiguous vector/matrix of the same type and kind as the output argument rand. If ub is a scalar, it represents the upper bound of the ndim-dimensional hyper-cube support of the distribution. In such a case, the input optional argument ndim must be specified. If ub is a vector of shape (1:ndim), it represents the upper bounds of the ndim-dimensional hyper-rectangle support of the distribution along each dimension. If ub is a square matrix of shape (1:ndim, 1:ndim), it contains the representative matrix of the ndim-dimensional hyper-parallelepiped support of the distribution.
[in]	ndim	: The input positive scalar of type integer of default kind IK, containing the number of dimensions of the distribution. (optional. It must be present if and only if the input lb and ub are scalar.)

Returns

rand : The output vector of shape (1:ndim) of,

1. type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128),

containing a random vector from the support of the distribution.

Possible calling interfaces ⛓

use pm_distUnifPar, only: getUnifParRand
 
rand(1:ndim) = getUnifParRand(ub(1:ndim))             ! Uniform Hyper-rectangle support
rand(1:ndim) = getUnifParRand(ub, ndim)               ! Uniform Hyper-cube support
 
rand(1:ndim) = getUnifParRand(lb(1:ndim), ub(1:ndim)) ! Uniform Hyper-rectangle support
rand(1:ndim) = getUnifParRand(lb, ub, ndim)           ! Uniform Hyper-cube support
!

Warning

The condition 0 < ndim must hold for the corresponding input arguments.
The condition all(lb /= ub) must hold for the corresponding input arguments.
Although there is theoretically no limit on the possible values of lb and ub with respect to each other, the condition all(lb < ub) is expected (but not checked) to hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_io, only: display_type
    use pm_distUnifPar, only: getUnifParRand
 
    implicit none
 
    real :: rand(5)
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("rand(1:2) = getUnifParRand(ub = 1., ndim = 2)")
                    rand(1:2) = getUnifParRand(ub = 1., ndim = 2)
    call disp%show("rand(1:2)")
    call disp%show( rand(1:2) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("rand(1:2) = getUnifParRand(lb = -100., ub = 1., ndim = 2)")
                    rand(1:2) = getUnifParRand(lb = -100., ub = 1., ndim = 2)
    call disp%show("rand(1:2)")
    call disp%show( rand(1:2) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("rand(1:5) = getUnifParRand(ub = [1., 2., 3., 4., 5.]) ! random vector of dimension 5.")
                    rand(1:5) = getUnifParRand(ub = [1., 2., 3., 4., 5.])
    call disp%show("rand(1:5)")
    call disp%show( rand(1:5) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("rand(1:5) = getUnifParRand(lb = -[1., 2., 3., 4., 5.], ub = [1., 2., 3., 4., 5.]) ! random vector of dimension 5.")
                    rand(1:5) = getUnifParRand(lb = -[1., 2., 3., 4., 5.], ub = [1., 2., 3., 4., 5.])
    call disp%show("rand(1:5)")
    call disp%show( rand(1:5) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("rand(1:2) = getUnifParRand(ub = reshape([1., 1., -1., -1.], shape = [2, 2]))")
                    rand(1:2) = getUnifParRand(ub = reshape([1., 1., -1., -1.], shape = [2, 2]))
    call disp%show("rand(1:2)")
    call disp%show( rand(1:2) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("rand(1:2) = getUnifParRand(lb = [10., 10.], ub = reshape([1., 1., -1., -1.], shape = [2, 2]))")
                    rand(1:2) = getUnifParRand(lb = [10., 10.], ub = reshape([1., 1., -1., -1.], shape = [2, 2]))
    call disp%show("rand(1:2)")
    call disp%show( rand(1:2) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        use pm_arraySpace, only: setLinSpace
        real :: rand(2, 4)
        integer(IK) :: fileUnit, i
        open(newunit = fileUnit, file = "getUnifParRand.RK.txt")
        do i = 1, 1000
            rand(:,1) = getUnifParRand(lb = -[2., 2.], ub = -[0., 1.])
            rand(:,2) = getUnifParRand(ub = reshape([1., 1., -1., +1.], shape = [2, 2]))
            rand(:,3) = getUnifParRand(lb = [2.0, -2.], ub = reshape([1., 1., +2., -2.], shape = [2, 2]))
            rand(:,4) = getUnifParRand(lb = [1.5, -.5], ub = reshape([2., 1., 1., 2.], shape = [2, 2]))
            write(fileUnit, "(*(g0,:,','))") rand
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
rand(1:2) = getUnifParRand(ub = 1., ndim = 2)
rand(1:2)
+0.850678325, +0.511220396
 
 
rand(1:2) = getUnifParRand(lb = -100., ub = 1., ndim = 2)
rand(1:2)
-15.1568966, -88.3737488
 
 
rand(1:5) = getUnifParRand(ub = [1., 2., 3., 4., 5.]) ! random vector of dimension 5.
rand(1:5)
+0.533918738E-1, +1.36438107, +2.69066095, +2.02097845, +3.16281509
 
 
rand(1:5) = getUnifParRand(lb = -[1., 2., 3., 4., 5.], ub = [1., 2., 3., 4., 5.]) ! random vector of dimension 5.
rand(1:5)
-0.454303145, -1.16930032, +2.82529736, +2.72344017, -0.689319611
 
 
rand(1:2) = getUnifParRand(ub = reshape([1., 1., -1., -1.], shape = [2, 2]))
rand(1:2)
-0.149664283, -0.149664283
 
 
rand(1:2) = getUnifParRand(lb = [10., 10.], ub = reshape([1., 1., -1., -1.], shape = [2, 2]))
rand(1:2)
+9.55906010, +9.55906010
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
for kind in ["RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
 
    for file in fileList:
 
        df = pd.read_csv(file, delimiter = ",", header = None)
 
        # definitions for the axes
       #left, width = 0.1, 0.65
       #bottom, height = 0.1, 0.65
       #spacing = 0.015
 
        # start with a square Figure
        fig = plt.figure(figsize = (8, 6))
 
        plt.rcParams.update({'font.size': fontsize - 2})
        ax = plt.subplot()
       #ax = fig.add_axes([left, bottom, width, height]) # scatter plot
       #ax_histx = fig.add_axes([left, bottom + height + spacing, width, 0.2], sharex = ax) # histx
       #ax_histy = fig.add_axes([left + width + spacing, bottom, 0.2, height], sharey = ax) # histy
       #
       #for axes in [ax, ax_histx, ax_histy]:
       #    axes.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
       #    axes.tick_params(axis = "y", which = "minor")
       #    axes.tick_params(axis = "x", which = "minor")
       #
       
 
        # the scatter plot:
        for i in range(0, len(df.values[0,:]), 2):
            ax.scatter  ( df.values[:,i]
                        , df.values[:,i+1]
                        , s = 8
                        , zorder = 1000
                        )
 
       #ax_histx.hist(df.values[:, 0], bins = 50, zorder = 1000)
       #ax_histy.hist(df.values[:,1], bins = 50, orientation = "horizontal", zorder= 1000)
 
        ax.set_aspect("equal")
        ax.set_xlabel("X", fontsize = 17)
        ax.set_ylabel("Y", fontsize = 17)
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        plt.minorticks_on()
 
        plt.tight_layout()
        plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Test:

test_pm_distUnifPar

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, April 23, 2017, 12:36 AM, Institute for Computational Engineering and Sciences (ICES), University of Texas at Austin

Definition at line 470 of file pm_distUnifPar.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distUnifPar.F90