pm_distUnifEll::getUnifEllRand Interface Reference

Generate and return a (collection) of random vector(s) of size ndim from the ndim-dimensional MultiVariate Uniform Ellipsoidal (MVUE) distribution, optionally with the specified input mean(1:ndim) and the specified subset of the Cholesky Factorization of the Gramian matrix of the MVUE distribution. More...

Detailed Description

Generate and return a (collection) of random vector(s) of size ndim from the ndim-dimensional MultiVariate Uniform Ellipsoidal (MVUE) distribution, optionally with the specified input mean(1:ndim) and the specified subset of the Cholesky Factorization of the Gramian matrix of the MVUE distribution.

The procedures of this generic interface are merely wrappers around the subroutine interface setUnifRand.

Parameters

[in,out]	rng	: The input/output scalar that can be an object of, type rngf_type, implying the use of intrinsic Fortran uniform RNG. type xoshiro256ssw_type, implying the use of xoshiro256** uniform RNG. (optional, default = rngf_type.)
[in]	mean	: The input contiguous vector of the same type, kind, rank, and size as the output rand, representing the mean of the MVUE distribution. (optional, default = [(0., i = 1, size(rand))]. It must be present if the input argument chol is missing.)
[in]	chol	: The input contiguous matrix of shape (ndim, ndim) whose specified triangular subset contains the Cholesky Factorization of the Gramian matrix of the MVUE distribution. (optional, the default is the Identity matrix of rank ndim. It must be present if and only if the input argument subset is also present.)
[in]	subset	: The input scalar constant that can be any of the following: the constant uppDia or an object of type uppDia_type implying that the upper-diagonal triangular block of the input chol must be used while the lower subset is not referenced. the constant lowDia or an object of type lowDia_type implying that the lower-diagonal triangular block of the input chol must be used while the upper subset is not referenced. This argument is merely a convenience to differentiate the different procedure functionalities within this generic interface. (optional. It must be present if and only if the input argument chol is present.)
[in]	nsam	: The input scalar integer of default kind IK containing the number of random MVUE vectors to generate. (optional. If present, the output rand is of rank 2, otherwise is of rank 1.)

Returns

rand : The output vector of

1. type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128),
   

containing the MVUE distributed random output vector(s):

1. If the input argument nsam is missing, then rand shall be of shape (1:ndim).
   
2. If the input argument nsam is present, then rand shall be of shape (1:ndim, 1:nsam).
   

Possible calling interfaces ⛓

use pm_distUnifEll, only: getUnifEllRand
 
! single vector, using default rng
 
rand(1:ndim) = getUnifEllRand(mean(1:ndim))
rand(1:ndim) = getUnifEllRand(chol(1:ndim, 1:ndim), subset)
rand(1:ndim) = getUnifEllRand(mean(1:ndim), chol(1:ndim, 1:ndim), subset)
 
! single vector, using custom rng
 
rand(1:ndim) = getUnifEllRand(rng, mean(1:ndim))
rand(1:ndim) = getUnifEllRand(rng, chol(1:ndim, 1:ndim), subset)
rand(1:ndim) = getUnifEllRand(rng, mean(1:ndim), chol(1:ndim, 1:ndim), subset)
 
! collection of `nsam` vectors, using default rng
 
rand(1:ndim, 1:nsam) = getUnifEllRand(mean(1:ndim), nsam)
rand(1:ndim, 1:nsam) = getUnifEllRand(chol(1:ndim, 1:ndim), subset, nsam)
rand(1:ndim, 1:nsam) = getUnifEllRand(mean(1:ndim), chol(1:ndim, 1:ndim), subset, nsam)
 
! collection of `nsam` vectors, using custom rng
 
rand(1:ndim, 1:nsam) = getUnifEllRand(rng, mean(1:ndim), nsam)
rand(1:ndim, 1:nsam) = getUnifEllRand(rng, chol(1:ndim, 1:ndim), subset, nsam)
rand(1:ndim, 1:nsam) = getUnifEllRand(rng, mean(1:ndim), chol(1:ndim, 1:ndim), subset, nsam)

Remarks

The procedures under discussion are impure.

See also

pm_ellipsoid
getNormRand
setNormRand
getUnifRand
setUnifRand

Example usage ⛓

program example
 
    use pm_kind, only: SK
    use pm_kind, only: IK, LK, RK ! all real kinds are supported.
    use pm_io, only: display_type
    use pm_matrixChol, only: getMatChol, uppDia, lowDia
    use pm_distUnifEll, only: getUnifEllRand
 
    implicit none
 
    integer(IK), parameter  :: NDIM = 2_IK  ! The number of dimensions of the MVN distribution.
    real(RK)                :: mean(NDIM), gramian(NDIM, NDIM), choLow(NDIM, NDIM), rand(NDIM)
    integer(IK)             :: info
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Generate random numbers from the (Standard) Multivariate Uniform Ellipsoidal distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Multivariate Uniform Ellipsoidal random vector with a particular mean and Identity Gramian matrix.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("mean = [-5., -5.]")
                    mean = [-5., -5.]
    call disp%show("rand = getUnifEllRand(mean)")
                    rand = getUnifEllRand(mean)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Multivariate Uniform Ellipsoidal random vector with zero mean and Gramian matrix specified via the Cholesky Lower Triangle.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("gramian = reshape([1., 1., 1., 4.], shape = [NDIM, NDIM])")
                    gramian = reshape([1., 1., 1., 4.], shape = [NDIM, NDIM])
    call disp%show("choLow = getMatChol(gramian, lowDia)")
                    choLow = getMatChol(gramian, lowDia)
    call disp%show("choLow")
    call disp%show( choLow )
    call disp%show("rand = getUnifEllRand(choLow, lowDia)")
                    rand = getUnifEllRand(choLow, lowDia)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Multivariate Uniform Ellipsoidal random vector with given mean and Gramian matrix specified via the Cholesky Lower Triangle.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("mean")
    call disp%show( mean )
    call disp%show("choLow")
    call disp%show( choLow )
    call disp%show("rand = getUnifEllRand(mean, choLow, lowDia)")
                    rand = getUnifEllRand(mean, choLow, lowDia)
    call disp%show("rand")
    call disp%show( rand )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example rand array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        integer(IK) :: fileUnit, i
        integer(IK), parameter :: NVEC = 5000_IK
        open(newunit = fileUnit, file = "getUnifEllRandMean.RK.txt")
            do i = 1, NVEC
                write(fileUnit,"(*(g0,:,','))") getUnifEllRand(mean)
            end do
        close(fileUnit)
        open(newunit = fileUnit, file = "getUnifEllRandChol.RK.txt")
            do i = 1, NVEC
                write(fileUnit,"(*(g0,:,','))") getUnifEllRand(choLow, lowDia)
            end do
        close(fileUnit)
        open(newunit = fileUnit, file = "getUnifEllRandMeanChol.RK.txt")
            do i = 1, NVEC
                write(fileUnit,"(*(g0,:,','))") getUnifEllRand(mean, choLow, lowDia)
            end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Generate random numbers from the (Standard) Multivariate Uniform Ellipsoidal distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Multivariate Uniform Ellipsoidal random vector with a particular mean and Identity Gramian matrix.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
mean = [-5., -5.]
rand = getUnifEllRand(mean)
rand
-0.78040564368514631, +0.25372573286899741
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Multivariate Uniform Ellipsoidal random vector with zero mean and Gramian matrix specified via the Cholesky Lower Triangle.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
gramian = reshape([1., 1., 1., 4.], shape = [NDIM, NDIM])
choLow = getMatChol(gramian, lowDia)
choLow
+1.0000000000000000, +0.0000000000000000
+1.0000000000000000, +1.7320508075688772
rand = getUnifEllRand(choLow, lowDia)
rand
-0.48470720199361156, +0.40355619489689837
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Multivariate Uniform Ellipsoidal random vector with given mean and Gramian matrix specified via the Cholesky Lower Triangle.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
mean
-5.0000000000000000, -5.0000000000000000
choLow
+1.0000000000000000, +0.0000000000000000
+1.0000000000000000, +1.7320508075688772
rand = getUnifEllRand(mean, choLow, lowDia)
rand
-5.6540525514129572, -5.8891770890215769
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
for kind in ["RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
 
    for file in fileList:
 
        df = pd.read_csv(file, delimiter = ",", header = None)
 
        # definitions for the axes
        left, width = 0.1, 0.65
        bottom, height = 0.1, 0.65
        spacing = 0.015
 
        # start with a square Figure
        fig = plt.figure(figsize=(8, 8))
 
        plt.rcParams.update({'font.size': fontsize - 2})
        ax = fig.add_axes([left, bottom, width, height]) # scatter plot
        ax_histx = fig.add_axes([left, bottom + height + spacing, width, 0.2], sharex = ax) # histx
        ax_histy = fig.add_axes([left + width + spacing, bottom, 0.2, height], sharey = ax) # histy
 
        for axes in [ax, ax_histx, ax_histy]:
            axes.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
            axes.tick_params(axis = "y", which = "minor")
            axes.tick_params(axis = "x", which = "minor")
 
        # no labels
        ax_histy.tick_params(axis = "y", labelleft = False)
        ax_histx.tick_params(axis = "x", labelbottom = False)
 
        # the scatter plot:
        ax.scatter  ( df.values[:, 0]
                    , df.values[:,1]
                    , s = 8
                    , zorder = 1000
                    )
 
        ax_histx.hist(df.values[:, 0], bins = 50, zorder = 1000)
        ax_histy.hist(df.values[:,1], bins = 50, orientation = "horizontal", zorder= 1000)
 
        ax.set_xlabel("X", fontsize = 17)
        ax.set_ylabel("Y", fontsize = 17)
 
        plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Test:

test_pm_distUnifEll

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, April 23, 2017, 12:36 AM, Institute for Computational Engineering and Sciences (ICES), University of Texas at Austin

Definition at line 559 of file pm_distUnifEll.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distUnifEll.F90