pm_sysPath::isFailedRemove Interface Reference

Generate and return .true. if the requested path removal action from the file system failed, otherwise return .false. indicating success.
More...

Detailed Description

Generate and return .true. if the requested path removal action from the file system failed, otherwise return .false. indicating success.

The procedures of this generic interface perform the path removal action whether the input path points to a file or an empty or non-empty directory.
The removal strategy depends on the nature of the input path:

1. If the input path points to a single file, then the path is removed from the file system using Fortran intrinsic routines.
   
2. If the input path points to a multiple files via a pattern specification or a directory, then the path is removed via the relevant shell commands.
   

Parameters

[in]	path	: The input scalar character of default kind SK containing a POSIX-style or Windows-style path to a file or directory.
[in]	recursive	: The input scalar logical of default kind LK. If .true. the removal action will be performed recursively (including all subdirectories). This input argument is relevant only if the input path is a directory potentially with subdirectories. (optional, default = .false.)
[in]	forced	: The input scalar logical of default kind LK. If .true. the removal action will be performed without any questions asked (and nonexistent files will be ignored). Note that setting force = .true. is required to ignore errors raised on Windows related to non-existence of the specified path or pattern. (optional, default = .false.)
[in]	wait	: The input scalar logical of default kind LK with the same functionality as the wait argument of the Fortran intrinsic execute_command_line(). If .true., the procedure will wait for the shell action to terminate before returning the control to the Fortran program. Otherwise, the system call will be done asynchronously and the success of the action will not be verified. (optional, default = .true.)
[in]	ntry	: The input scalar positive integer of default kind IK representing the number of times the requested action should be attempted. Multiple tries are particularly useful on Windows platforms where applications take the ownership of a particular resource on the system and may not allow other applications to utilize the resource. For example, Dropbox is a well-known example of an application that blocks any other applications from making any changes to a specific path with which it is working, preventing any manipulation of the path by other applications. (optional, default = 1)
[in,out]	errmsg	: The input/output scalar character of default kind SK of arbitrary length type parameter. If present and an error occurs, it is assigned an explanatory message describing the nature of the error that has occurred. If the length of errmsg is too short for the output error message, the message tail will be clipped as needed. A length of LEN_IOMSG characters is likely sufficient to capture most error messages in full. (optional. If missing, no error message will be output.)

Returns

failed : The output scalar logical of default kind LK. It is .true. if and only if an error occurs while performing the requested task.
This includes the possibility of the input path not existing before the removal action.

Possible calling interfaces ⛓

use pm_kind, only: LK, IK, SK
use pm_sysPath, only: isFailedRemove
character(2047, SK) :: errmsg
logical(LK) :: failed, forced
logical(LK) :: recursive
logical(LK) :: wait
integer(IK) :: ntry
 
failed = isFailedRemove(path, recursive = recursive, forced = forced, wait = wait, ntry = ntry, errmsg = errmsg)

Warning

Note that this procedure does not verify the conformance of the input paths to the naming conventions of the current processor shell. For example,

1. if the shell is POSIX-conforming, then the path is expected to conform to the POSIX conventions.
   
2. if the shell is Windows CMD or PowerShell, the path is expected to conform to the Windows conventions.
   

This procedure interprets the input paths verbatim.
This procedure potentially calls the operating system to create the input destination path directories.
To minimize security vulnerabilities and to properly handle the presence of whitespace or other potentially problematic characters, the input path will be interpreted verbatim by calling getPathVerbatim.

Asynchronous removal action.
Note that even if the processor supports asynchronous command execution (wait = .false.), there is no mechanism provided for finding out later whether the command being executed asynchronously has terminated or what its exit status exitstat was.

The input ntry must be a positive (non-zero) integer.
This condition is verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

Remarks

The procedures under discussion are impure.

The procedures under discussion are recursive.

See also

isFailedCopy
isFailedMove
isFailedRemove
isFailedMakeDir

Example usage ⛓

program example
 
    use pm_kind, only: LK, IK, SK
    use pm_io, only: display_type
    use pm_container, only: css_type
    use pm_arrayResize, only: setResized
    use pm_sysPath, only: isFailedRemove, isFailedMakeDir, isExtant, isFile, getPathNew, getDirSep, ls, glob, isDir
 
    implicit none
 
    integer :: i, unit
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%")
    call disp%show("! Remove file.")
    call disp%show("!%%%%%%%%%%%%%")
    call disp%skip()
 
    block
        character(:, SK), allocatable :: path, dir
        call disp%skip()
        call disp%show("dir = getPathNew(prefix = SK_'tempdir_') ! define a temp directory name.")
                        dir = getPathNew(prefix = SK_'tempdir_')
        call disp%show("dir")
        call disp%show( dir , deliml = SK_"""" )
        call disp%show("if (isFailedMakeDir(dir)) error stop 'directory creation failed.'")
                        if (isFailedMakeDir(dir)) error stop 'directory creation failed.'
        call disp%show("path = getPathNew(dir) ! define a temp path name.")
                        path = getPathNew(dir)
        call disp%show("path")
        call disp%show( path , deliml = SK_"""" )
        call disp%show("open(newunit = unit, file = path, status = 'replace'); close(unit) ! Create a file in a randomly-named directory.")
                        open(newunit = unit, file = path, status = 'replace'); close(unit) ! Create a file in a randomly-named directory.
        call disp%show("isExtant(path)")
        call disp%show( isExtant(path) )
        call disp%show("if (isFailedRemove(path)) error stop 'removal failed.'")
                        if (isFailedRemove(path)) error stop 'removal failed.'
        call disp%show("[isFile(path), isExtant(path)]")
        call disp%show( [isFile(path), isExtant(path)] )
        call disp%show(.not."if ( isFailedRemove(path)) error stop 'removal of non existing path fails unless `forced`.'")
                        if (.not. isFailedRemove(path)) error stop 'removal of non existing path fails unless `forced`.'
        call disp%show("if (isFailedRemove(path, forced = .true._LK)) error stop 'removal of non existing path fails unless `forced`.'")
                        if (isFailedRemove(path, forced = .true._LK)) error stop 'removal of non existing path fails unless `forced`.'
        call disp%show("isDir(dir)")
        call disp%show( isDir(dir) )
        call disp%show("if (isFailedRemove(dir, forced = .true._LK, recursive = .true._LK)) error stop 'removal of directory failed.'")
                        if (isFailedRemove(dir, forced = .true._LK, recursive = .true._LK)) error stop 'removal of directory failed.'
        call disp%show("isDir(dir)")
        call disp%show( isDir(dir) )
        call disp%skip()
        call disp%skip()
    end block
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Remove directory or files matching pattern.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    block
        type(css_type), allocatable :: list(:)
        character(:, SK), allocatable :: dir, pattern
        call disp%skip()
        call disp%show("dir = getPathNew(prefix = SK_'tempdir_') ! define a temp directory name.")
                        dir = getPathNew(prefix = SK_'tempdir_')
        call disp%show("dir")
        call disp%show( dir , deliml = SK_"""" )
        call disp%show("if (isFailedMakeDir(dir)) error stop 'directory creation failed.'")
                        if (isFailedMakeDir(dir)) error stop 'directory creation failed.'
        call disp%show("call setResized(list, 5_IK)")
                        call setResized(list, 5_IK)
        call disp%show("do i = 1, 3; list(i)%val = getPathNew(dir, prefix = SK_'tempfile_'); end do ! define temp path names.")
                        do i = 1, 3; list(i)%val = getPathNew(dir, prefix = SK_'tempfile_'); end do
        call disp%show("do i = 4, size(list); list(i)%val = getPathNew(dir, prefix = SK_'dumpfile_'); end do ! define temp path names.")
                        do i = 4, size(list); list(i)%val = getPathNew(dir, prefix = SK_'dumpfile_'); end do
        call disp%show("list")
        call disp%show( list , deliml = SK_"""" )
        call disp%show("ls(dir)")
        call disp%show( ls(dir) , deliml = SK_"""" )
        call disp%show("do i = 1, size(list); open(newunit = unit, file = list(i)%val, status = 'replace'); close(unit); end do ! Create random files with specified patterns.")
                        do i = 1, size(list); open(newunit = unit, file = list(i)%val, status = 'replace'); close(unit); end do ! Create random files with specified patterns.
        call disp%show("ls(dir)")
        call disp%show( ls(dir) , deliml = SK_"""" )
        call disp%show("pattern = dir//getDirSep()//SK_'*ump*'")
                        pattern = dir//getDirSep()//SK_'*ump*'
        call disp%show("pattern")
        call disp%show( pattern , deliml = SK_"""" )
        call disp%show("glob(pattern)")
        call disp%show( glob(pattern) , deliml = SK_"""" )
        call disp%show("if (isFailedRemove(pattern, forced = .true._LK, recursive = .true._LK)) error stop 'removal of file(s) matching pattern '''//pattern//''' failed.'")
                        if (isFailedRemove(pattern, forced = .true._LK, recursive = .true._LK)) error stop 'removal of file(s) matching pattern '''//pattern//''' failed.'
        call disp%show("glob(pattern)")
        call disp%show( glob(pattern) , deliml = SK_"""" )
        call disp%skip()
        call disp%show("pattern = SK_'./*emp*'")
                        pattern = SK_'./*emp*'
        call disp%show("pattern")
        call disp%show( pattern , deliml = SK_"""" )
        call disp%show("glob(pattern)")
        call disp%show( glob(pattern) , deliml = SK_"""" )
        call disp%show("if (isFailedRemove(pattern, forced = .true._LK, recursive = .true._LK)) error stop 'removal of directories and files matching pattern '''//pattern//''' failed.'")
                        if (isFailedRemove(pattern, forced = .true._LK, recursive = .true._LK)) error stop 'removal of directories and files matching pattern '''//pattern//''' failed.'
        call disp%show("glob(pattern)")
        call disp%show( glob(pattern) , deliml = SK_"""" )
        call disp%skip()
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%
! Remove file.
!%%%%%%%%%%%%%
 
 
dir = getPathNew(prefix = SK_'tempdir_') ! define a temp directory name.
dir
"tempdir_20241114_224744_023_pid_1"
if (isFailedMakeDir(dir)) error stop 'directory creation failed.'
path = getPathNew(dir) ! define a temp path name.
path
"tempdir_20241114_224744_023_pid_1/new_20241114_224744_028_pid_1"
open(newunit = unit, file = path, status = 'replace'); close(unit) ! Create a file in a randomly-named directory.
isExtant(path)
T
if (isFailedRemove(path)) error stop 'removal failed.'
[isFile(path), isExtant(path)]
F, F
if (.not. isFailedRemove(path)) error stop 'removal of non existing path fails unless `forced`.'
if (isFailedRemove(path, forced = .true._LK)) error stop 'removal of non existing path fails unless `forced`.'
isDir(dir)
T
if (isFailedRemove(dir, forced = .true._LK, recursive = .true._LK)) error stop 'removal of directory failed.'
isDir(dir)
F
 
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Remove directory or files matching pattern.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
dir = getPathNew(prefix = SK_'tempdir_') ! define a temp directory name.
dir
"tempdir_20241114_224744_041_pid_1"
if (isFailedMakeDir(dir)) error stop 'directory creation failed.'
call setResized(list, 5_IK)
do i = 1, 3; list(i)%val = getPathNew(dir, prefix = SK_'tempfile_'); end do ! define temp path names.
do i = 4, size(list); list(i)%val = getPathNew(dir, prefix = SK_'dumpfile_'); end do ! define temp path names.
list
"tempdir_20241114_224744_041_pid_1/tempfile_20241114_224744_046_pid_1", "tempdir_20241114_224744_041_pid_1/tempfile_20241114_224744_048_pid_1", "tempdir_20241114_224744_041_pid_1/tempfile_20241114_224744_050_pid_1", "tempdir_20241114_224744_041_pid_1/dumpfile_20241114_224744_052_pid_1", "tempdir_20241114_224744_041_pid_1/dumpfile_20241114_224744_054_pid_1"
ls(dir)
""
do i = 1, size(list); open(newunit = unit, file = list(i)%val, status = 'replace'); close(unit); end do ! Create random files with specified patterns.
ls(dir)
"dumpfile_20241114_224744_052_pid_1", "dumpfile_20241114_224744_054_pid_1", "tempfile_20241114_224744_046_pid_1", "tempfile_20241114_224744_048_pid_1", "tempfile_20241114_224744_050_pid_1"
pattern = dir//getDirSep()//SK_'*ump*'
pattern
"tempdir_20241114_224744_041_pid_1/*ump*"
glob(pattern)
"tempdir_20241114_224744_041_pid_1/dumpfile_20241114_224744_052_pid_1", "tempdir_20241114_224744_041_pid_1/dumpfile_20241114_224744_054_pid_1"
if (isFailedRemove(pattern, forced = .true._LK, recursive = .true._LK)) error stop 'removal of file(s) matching pattern '''//pattern//''' failed.'
glob(pattern)
 
 
pattern = SK_'./*emp*'
pattern
"./*emp*"
glob(pattern)
"./tempdir_20241114_224744_041_pid_1"
if (isFailedRemove(pattern, forced = .true._LK, recursive = .true._LK)) error stop 'removal of directories and files matching pattern '''//pattern//''' failed.'
glob(pattern)
 
 
 

Test:

test_pm_sysPath

Todo:

High Priority: The current Fortran standard 202x does not allow passing characters of non-default kind to the intrinsic Fortran statements and procedures.
As such, the implementation of this procedure for non-default character kinds leads to compile-time kind mismatch errors.
This procedure should be converted back to a generic interface in the future when non-default character kinds are also fully supported by the intrinsic functions.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Tuesday March 7, 2017, 3:09 AM, Institute for Computational Engineering and Sciences (ICES), The University of Texas Austin

Definition at line 3749 of file pm_sysPath.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_sysPath.F90