pm_mathErf::setErfInv Interface Reference

Return the Inverse Error Function \(\ms{erf}^{-1}(x)\) for an input real value in range \((-1, +1)\) as defined in the details section of pm_mathErf. More...

Detailed Description

Return the Inverse Error Function \(\ms{erf}^{-1}(x)\) for an input real value in range \((-1, +1)\) as defined in the details section of pm_mathErf.

The complementary inverse error function \(\ms{erfc}^{-1}(y), y\in(0, 2)\) can be readily computed as call setErfInv(1 - y).
See the documentation of pm_mathErf for more information.

Parameters

[in]	erfinv	: The output scalar (or array of the same shape as input array-like arguments) of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the approximate value of the inverse error function at the specified input point x.
[in]	x	: The input scalar (or array of the same shape as other array-like arguments) of the same type and kind as the output erfinv.
[in]	abserr	: The input positive scalar (or array of the same shape as other array-like arguments) of the same type and kind as the output erfinv. If present, the output approximate value for the inverse error function is guaranteed to be at most abserr away from the true value \(\ms{erf}^{-1}(x)\). This guarantee is currently tested and validated up to \(2\times10^{-26}\). A reasonable value could be epsilon(x)**0.66. The current implementation of this generic interface contains three methods of computing the inverse error function corresponding to three levels of increasing accuracy, For any 1.e-7 < abserr, the output erfinv will have at most an absolute error 1.e-7 with respect to theoretical value. For any 2.e-24 < abserr, the output erfinv will have at most an absolute error 2.e-24 with respect to theoretical value. For any abserr < 2.e-24, the output erfinv is currently verified to have at most an absolute error 2.e-26 with respect to theoretical value. For a wide range of input x values, the absolute error is practically orders of magnitude smaller than this verified upper limit for the error. See the example illustrations below for more information.

Possible calling interfaces ⛓

use pm_mathErf, only: setErfInv
 
call setErfInv(erfinv, x, abserr)
call setErfInv(erfinv, x(..), abserr(..))

Warning

The condition 0 < abserr must hold for the corresponding input arguments.
The conditions -1 < x .and. x < 1 must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getErfInv
setErfInv
getNormCDF
setNormCDF
getNormQuan
setNormQuan
getNormRand
setNormRand
getNormLogPDF
setNormLogPDF

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK, RKH
    use pm_mathSubAdd, only: operator(.subadd.)
    use pm_mathErf, only: setErfInv
    use pm_arrayResize, only: setResized
    use pm_io, only: display_type
 
    implicit none
 
    real(RKH), allocatable :: erfinv(:), x(:)
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("x = [real(RKH) :: 0., 0.5]")
                    x = [real(RKH) :: 0., 0.5]
    call disp%show("x")
    call disp%show( x )
    call disp%show("call setResized(erfinv, size(x, 1, IK))")
                    call setResized(erfinv, size(x, 1, IK))
    call disp%show("call setErfInv(erfinv, x, abserr = epsilon(x))")
                    call setErfInv(erfinv, x, abserr = epsilon(x))
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("x = .subadd. 1. - .subadd. epsilon(0.)")
                    x = .subadd. 1. - .subadd. epsilon(0.)
    call disp%show("x")
    call disp%show( x )
    call disp%show("call setResized(erfinv, size(x, 1, IK))")
                    call setResized(erfinv, size(x, 1, IK))
    call disp%show("call setErfInv(erfinv, x, abserr = epsilon(x))")
                    call setErfInv(erfinv, x, abserr = epsilon(x))
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("x = [-.99, -.75, -0.5, -0.1, 0., .1, .5, .75, .99]")
                    x = [-.99, -.75, -0.5, -0.1, 0., .1, .5, .75, .99]
    call disp%show("x")
    call disp%show( x )
    call disp%show("call setResized(erfinv, size(x, 1, IK))")
                    call setResized(erfinv, size(x, 1, IK))
    call disp%show("call setErfInv(erfinv, x, abserr = epsilon(x))")
                    call setErfInv(erfinv, x, abserr = epsilon(x))
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array of the regularized Incomplete Beta function for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        use pm_kind, only: RKB, RKG => RKH
        use pm_arraySpace, only: setLinSpace
        integer(IK) , parameter :: NP = 2000
        integer :: fileUnit, i
        real(RKG) :: erfval(NP), erfinv(NP)
 
        call setLinSpace(erfval, -1._RKG + sqrt(epsilon(0._RKG)), 1._RKG - sqrt(epsilon(0._RKG)))
 
        open(newunit = fileUnit, file = "setErfInv.RK.txt")
        call setErfInv(erfinv, erfval, abserr = 100 * epsilon(0._RKG))
        do i = 1, NP
            write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKG), real(erfinv(i), RKG)
        end do
        close(fileUnit)
 
        block
            use pm_kind, only: RKG => RKS
            open(newunit = fileUnit, file = "setErfInv.RKS.abserr.txt")
            call setErfInv(erfinv, erfval, abserr = real(100 * epsilon(0._RKG), RKH))
            do i = 1, NP
                write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKG), real(erfval(i), RKG) - erf(real(erfinv(i), RKB))
            end do
            close(fileUnit)
        end block
 
        block
            use pm_kind, only: RKG => RKD
            open(newunit = fileUnit, file = "setErfInv.RKD.abserr.txt")
            call setErfInv(erfinv, erfval, abserr = real(100 * epsilon(0._RKG), RKH))
            do i = 1, NP
                write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKG), real(erfval(i), RKG) - erf(real(erfinv(i), RKB))
            end do
            close(fileUnit)
        end block
 
        block
            use pm_kind, only: RKG => RKH
            open(newunit = fileUnit, file = "setErfInv.RKH.abserr.txt")
            call setErfInv(erfinv, erfval, abserr = real(100 * epsilon(0._RKG), RKH))
            do i = 1, NP
                write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKG), real(erfval(i), RKG) - erf(real(erfinv(i), RKB))
            end do
            close(fileUnit)
        end block
 
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
x = [real(RKH) :: 0., 0.5]
x
+0.00000000000000000000000000000000000, +0.500000000000000000000000000000000000
call setResized(erfinv, size(x, 1, IK))
call setErfInv(erfinv, x, abserr = epsilon(x))
erfinv
-0.132513883613671435781879776977691272E-34, +0.476936276204469873381418342335513784
erf(erfinv)
-0.149525905620586266620169289835968551E-34, +0.499999999999999999999999989836624968
 
 
x = .subadd. 1. - .subadd. epsilon(0.)
x
-0.999999880790710449218750000000000000, +0.999999880790710449218750000000000000
call setResized(erfinv, size(x, 1, IK))
call setErfInv(erfinv, x, abserr = epsilon(x))
erfinv
-3.74392116277679962488913660265320747, +3.74392116277679962488913660265320747
erf(erfinv)
-0.999999880790710449218750000097940664, +0.999999880790710449218750000097940664
 
 
x = [-.99, -.75, -0.5, -0.1, 0., .1, .5, .75, .99]
x
-0.990000009536743164062500000000000000, -0.750000000000000000000000000000000000, -0.500000000000000000000000000000000000, -0.100000001490116119384765625000000000, +0.00000000000000000000000000000000000, +0.100000001490116119384765625000000000, +0.500000000000000000000000000000000000, +0.750000000000000000000000000000000000, +0.990000009536743164062500000000000000
call setResized(erfinv, size(x, 1, IK))
call setErfInv(erfinv, x, abserr = epsilon(x))
erfinv
-1.82138660090027777498853581706459074, -0.813419847597618541690289359089294846, -0.476936276204469873381418342335513784, -0.888559918253064817186753173353988263E-1, -0.132513883613671435781879776977691272E-34, +0.888559918253064817186753173353988263E-1, +0.476936276204469873381418342335513784, +0.813419847597618541690289359089294846, +1.82138660090027777498853581706459074
erf(erfinv)
-0.990000009536743164062500001249670844, -0.749999999999999999999999999531804119, -0.499999999999999999999999989836624968, -0.100000001490116119384765624995815857, -0.149525905620586266620169289835968551E-34, +0.100000001490116119384765624995815857, +0.499999999999999999999999989836624968, +0.749999999999999999999999999531804119, +0.990000009536743164062500001249670844
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
import os
 
fontsize = 17
 
parent = os.path.basename(os.path.dirname(__file__))
pattern = parent + "*.txt"
 
fileList = glob.glob(pattern)
for file in fileList:
 
    df = pd.read_csv(file, delimiter = " ")
 
    fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
    ax = plt.subplot()
 
    for i in range(1,len(df.values[0,:]+1)):
 
            plt.plot( df.values[:, 0]
                    , df.values[:,i]
                    , linewidth = 2
                    )
 
    plt.xticks(fontsize = fontsize - 2)
    plt.yticks(fontsize = fontsize - 2)
    ax.set_xlabel("x", fontsize = fontsize)
    if "abserr" in file:
        nbit = file.split(".")[1][2:]
        label = [r"x - erf(erfinv(x))"]
        ax.set_ylabel("{}-bits Absolute Error".format(nbit), fontsize = fontsize)
    else:
        label = [r"erfinv(x)"]
        ax.set_ylabel("Inverse Error Function", fontsize = fontsize)
 
    plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
    ax.tick_params(axis = "y", which = "minor")
    ax.tick_params(axis = "x", which = "minor")
 
    ax.legend   ( label
                , fontsize = fontsize
               #, loc = "center left"
               #, bbox_to_anchor = (1, 0.5)
                )
 
    plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Test:

test_pm_mathErf

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Nov 10, 2009, 8:53 PM, Michigan

Definition at line 340 of file pm_mathErf.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_mathErf.F90