pm_mathErf::getErfInv Interface Reference

Generate and return the Inverse Error Function \(\ms{erf}^{-1}(x)\) for an input real value in range \((-1, +1)\) as defined in the details section of pm_mathErf. More...

Detailed Description

Generate and return the Inverse Error Function \(\ms{erf}^{-1}(x)\) for an input real value in range \((-1, +1)\) as defined in the details section of pm_mathErf.

The complementary inverse error function \(\ms{erfc}^{-1}(y), y\in(0, 2)\) can be readily computed as getErfInv(1 - y).
See the documentation of pm_mathErf for more information.

Parameters

[in]	x	: The input scalar (or array of the same shape as other array-like arguments) of the same type and kind as the output erfinv.
[in]	abserr	: The input positive scalar (or array of the same shape as other array-like arguments) of the same type and kind as the output erfinv. If present, the output approximate value for the inverse error function is guaranteed to be at most abserr away from the true value \(\ms{erf}^{-1}(x)\). This guarantee is currently tested and validated up to \(2\times10^{-26}\). (optional, default = 100 * epsilon(x))

Returns

erfinv : The output scalar (or array of the same shape as input array-like arguments) of,

1. type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128),
   

containing the approximate value of the inverse error function at the specified input point x.

Possible calling interfaces ⛓

use pm_mathErf, only: getErfInv
 
erfinv = getErfInv(x, abserr = abserr)
erfinv(..) = getErfInv(x(..), abserr = abserr(..))

Warning

The condition 0 < abserr must hold for the corresponding input arguments.
The conditions -1 < x .and. x < 1 must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getErfInv
setErfInv
getNormCDF
setNormCDF
getNormQuan
setNormQuan
getNormRand
setNormRand
getNormLogPDF
setNormLogPDF

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK, RKH
    use pm_mathErf, only: getErfInv
    use pm_io, only: display_type
 
    implicit none
 
    real(RKH), allocatable :: erfinv(:)
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("erfinv = [real(RKH) :: getErfInv(0.), getErfInv(0.d0)]")
                    erfinv = [real(RKH) :: getErfInv(0.), getErfInv(0.d0)]
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("erfinv = [getErfInv(-1. + epsilon(0.))]")
                    erfinv = [getErfInv(-1. + epsilon(0.))]
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("erfinv = [getErfInv(+1. - epsilon(0.))]")
                    erfinv = [getErfInv(+1. - epsilon(0.))]
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("erfinv = getErfInv([real :: -.99, -.75, -0.5, -0.1, 0., .1, .5, .75, .99])")
                    erfinv = getErfInv([real :: -.99, -.75, -0.5, -0.1, 0., .1, .5, .75, .99])
    call disp%show("erfinv")
    call disp%show( erfinv )
    call disp%show("erf(erfinv)")
    call disp%show( erf(erfinv) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array of the regularized Incomplete Beta function for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        use pm_kind, only: RKB, RKG => RKH, RKL => RKS, RKS, RKD
        use pm_arraySpace, only: setLinSpace
        integer(IK) , parameter :: NP = 2000
        integer :: fileUnit, i
        real(RKG) :: erfval(NP)
        call setLinSpace(erfval, -1._RKG + epsilon(0._RKL), 1._RKG - epsilon(0._RKL))
        open(newunit = fileUnit, file = "getErfInv.RK.txt")
        do i = 1, NP
            write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKD), getErfInv(real(erfval(i), RKD))
        end do
        close(fileUnit)
        open(newunit = fileUnit, file = "getErfInv.RKS.abserr.txt")
        do i = 1, NP
            write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKS), real(erfval(i), RKS) - erf(real(getErfInv(real(erfval(i), RKS)), RKB))
        end do
        close(fileUnit)
        open(newunit = fileUnit, file = "getErfInv.RKD.abserr.txt")
        do i = 1, NP
            write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKD), real(erfval(i), RKD) - erf(real(getErfInv(real(erfval(i), RKD)), RKB))
        end do
        close(fileUnit)
        open(newunit = fileUnit, file = "getErfInv.RKH.abserr.txt")
        do i = 1, NP
            write(fileUnit, "(*(g0,:,' '))") real(erfval(i), RKH), real(erfval(i), RKH) - erf(real(getErfInv(real(erfval(i), RKH)), RKB))
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
erfinv = [real(RKH) :: getErfInv(0.), getErfInv(0.d0)]
erfinv
+0.00000000000000000000000000000000000, +0.00000000000000000000000000000000000
erf(erfinv)
+0.00000000000000000000000000000000000, +0.00000000000000000000000000000000000
 
 
erfinv = [getErfInv(-1. + epsilon(0.))]
erfinv
-3.74392127990722656250000000000000000
erf(erfinv)
-0.999999880790818503613783522210309248
 
 
erfinv = [getErfInv(+1. - epsilon(0.))]
erfinv
+3.74392127990722656250000000000000000
erf(erfinv)
+0.999999880790818503613783522210309344
 
 
erfinv = getErfInv([real :: -.99, -.75, -0.5, -0.1, 0., .1, .5, .75, .99])
erfinv
-1.82138657569885253906250000000000000, -0.813419818878173828125000000000000000, -0.476936280727386474609375000000000000, -0.888559892773628234863281250000000000E-1, +0.00000000000000000000000000000000000, +0.888559892773628234863281250000000000E-1, +0.476936280727386474609375000000000000, +0.813419818878173828125000000000000000, +1.82138657569885253906250000000000000
erf(erfinv)
-0.990000008506047801752279420046811002, -0.749999983278341053252938360742249376, -0.500000004065233062995271124000763142, -0.999999986376798060532971720489789201E-1, +0.00000000000000000000000000000000000, +0.999999986376798060532971720489789201E-1, +0.500000004065233062995271124000763142, +0.749999983278341053252938360742249376, +0.990000008506047801752279420046810906
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
import os
 
fontsize = 17
 
parent = os.path.basename(os.path.dirname(__file__))
pattern = parent + "*.txt"
 
fileList = glob.glob(pattern)
for file in fileList:
 
    df = pd.read_csv(file, delimiter = " ")
 
    fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
    ax = plt.subplot()
 
    for i in range(1,len(df.values[0,:]+1)):
 
            plt.plot( df.values[:, 0]
                    , df.values[:,i]
                    , linewidth = 2
                    )
 
    plt.xticks(fontsize = fontsize - 2)
    plt.yticks(fontsize = fontsize - 2)
    ax.set_xlabel("x", fontsize = fontsize)
    if "abserr" in file:
        nbit = file.split(".")[1][2:]
        label = [r"x - erf(erfinv(x))"]
        ax.set_ylabel("{}-bits Absolute Error".format(nbit), fontsize = fontsize)
    else:
        label = [r"erfinv(x)"]
        ax.set_ylabel("Inverse Error Function", fontsize = fontsize)
 
    plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
    ax.tick_params(axis = "y", which = "minor")
    ax.tick_params(axis = "x", which = "minor")
 
    ax.legend   ( label
                , fontsize = fontsize
               #, loc = "center left"
               #, bbox_to_anchor = (1, 0.5)
                )
 
    plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Test:

test_pm_mathErf

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Nov 10, 2009, 8:53 PM, Michigan

Definition at line 191 of file pm_mathErf.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_mathErf.F90