pm_cosmicRate::getLogRateDensityB10 Interface Reference

Generate and return the unnormalized Comoving LGRB Formation Rate (LGFR) density for a given redshift \(z\) based on the Metallicity-corrected estimates of Butler et al. (2010): B10, assuming a piecewise power-law LGFR model. More...

Detailed Description

Generate and return the unnormalized Comoving LGRB Formation Rate (LGFR) density for a given redshift \(z\) based on the Metallicity-corrected estimates of Butler et al. (2010): B10, assuming a piecewise power-law LGFR model.

The model of B10 is based on the Poweto distribution Star Formation Rate (SFR) model proposed by Hopkins and Beacom (2006).

\begin{equation} \end{equation}

Parameters

[in]

logzplus1

: The input scalar or contiguous array of arbitrary rank of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128) containing the natural logarithm of the redshift plus one, \(\log(z+1)\), at which the formation rate density must be computed.

Returns

logRateDensity : The output of the same type, kind, and rank as the input argument logzplus1 containing the natural logarithm of the unnormalized cosmic formation rate density of LGRBs at the requested redshift.

Possible calling interfaces ⛓

use pm_cosmicRate, only: getLogRateDensityB10
 
logRateDensity = getLogRateDensityB10(logzplus1)

Warning

The input argument logzplus1 must be non-negative since negative redshift is cosmologically undefined.
This condition is verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getLogRateDensityH06
getLogRateDensityL08
getLogRateDensityM14
getLogRateDensityM17
getLogRateDensityF18
getLogRateDensityP15

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK, RKG => RKD
    use pm_cosmicRate, only: getLogRateDensityB10
    use pm_arraySpace, only: getLinSpace
    use pm_io, only: display_type
 
    implicit none
 
    type(display_type) :: disp
    real(RKG) :: redshift = 5.5_RKG
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!Compute the log(RateDensity) according to the B10 LGRB rate density parameters for the Hopkins and Beacom (2006) SFR model.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("redshift")
    call disp%show( redshift )
    call disp%show("getLogRateDensityB10(log(redshift + 1))")
    call disp%show( getLogRateDensityB10(log(redshift + 1)) )
    call disp%skip()
 
    ! Generate both the cosmic rate and the rate density.
 
    block
        use pm_cosmology, only: getVolComDiffNormed
        integer(IK) :: fileUnit, i
        real(RKG) :: maxRateFormLGRB, maxRateDensityFormLGRB
        real(RKG), allocatable :: zplus1(:), logzplus1(:), rateFormLGRB(:), rateDensityFormLGRB(:)
        logzplus1 = getLinSpace(0.01_RKG, log(13._RKG), 500_IK)
        zplus1 = exp(logzplus1)
        rateDensityFormLGRB = exp(getLogRateDensityB10(logzplus1))
        rateFormLGRB = rateDensityFormLGRB * getVolComDiffNormed(zplus1, reltol = sqrt(epsilon(0._RKG)))
        maxRateDensityFormLGRB = maxval(rateDensityFormLGRB)
        maxRateFormLGRB = maxval(rateFormLGRB)
        open(newunit = fileUnit, file = "getLogRateDensityB10.csv")
        write(fileUnit, "(*(g0,:,','))") "redshift, rateFormLGRB, rateDensityFormLGRB"
        do i = 1, size(zplus1)
            write(fileUnit, "(*(g0,:,','))") zplus1(i) - 1, rateFormLGRB(i) / maxRateFormLGRB, rateDensityFormLGRB(i) / maxRateDensityFormLGRB
        end do
        close(fileUnit)
    end block
 
    ! Set up a Markov Chain Monte Carlo sampler to generate random sample from the target rate density model.
 
    block
        use pm_err, only: err_type
        use pm_sampling, only: paradram_type, getErrSampling
        type(paradram_type) :: sampler
        type(err_type) :: err
        sampler%outputFileName = "./zdistB10"
        sampler%outputStatus = "retry"
        sampler%domainAxisName = ["redshift"]
        sampler%domainCubeLimitLower = [0._RKG]
        sampler%outputSampleSize = 2500
        sampler%outputChainSize = 5000
        sampler%proposalStart = [3]
        err = getErrSampling(sampler, getLogFunc, 1_IK)
        if (err%occurred) error stop err%msg
    end block
 
contains
 
    recursive function getLogFunc(redshift) result(logRateDensity)
        use pm_cosmology, only: getVolComDiffNormed
        real(RKG), intent(in), contiguous :: redshift(:)
        real(RKG) :: logRateDensity
        real(RKG) :: zplus1
        zplus1 = redshift(1) + 1
        logRateDensity = getLogRateDensityB10(log(zplus1)) + log(getVolComDiffNormed(zplus1, reltol = sqrt(epsilon(0._RKG))))
    end function
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!Compute the log(RateDensity) according to the B10 LGRB rate density parameters for the Hopkins and Beacom (2006) SFR model.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
redshift
+5.5000000000000000
getLogRateDensityB10(log(redshift + 1))
+2.6296316147601200
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
#pip install paramonte
 
import os
examname = os.path.basename(os.getcwd())
modelName = examname[-3:]
 
 
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
fontsize = 17
 
df = pd.read_csv(examname + ".csv", delimiter = ",")
 
fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
ax = plt.subplot()
 
for colname in df.columns[1:]:
    plt.plot( df.values[:, 0]
            , df[colname].values
            , linestyle = "-"
            , linewidth = 2
            )
 
labels = []
for colname in list(df.columns[1:]): labels.append(modelName + ": " + colname)
ax.legend   ( labels
            , fontsize = fontsize
           #, loc = "center left"
           #, bbox_to_anchor = (1, 0.5)
            )
 
ax.set_xlabel(df.columns[0], fontsize = fontsize)
ax.set_ylabel("Unnormalized Density", fontsize = fontsize)
 
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
 
plt.tight_layout()
plt.savefig(examname + ".z.png")
 
 
 
 
 
import glob
linewidth = 2
fontsize = 17
files = glob.glob("./*_sample.txt")
 
for file in files:
 
    #basename = file.split("_")[0]
    df = pd.read_csv(file, delimiter = ",")
    if "_chain.txt" in file:
        sindex = 7 # start column index.
    elif "_sample.txt" in file:
        sindex = 1 # start column index.
    else:
        sys.exit("Unrecognized simulation output file: " + file)
 
    # histogram
 
    for histname in ["z", "logzplus1"]:
 
        fig = plt.figure(figsize = (8, 6))
        ax = plt.subplot(1,1,1)
        if histname == "z":
            ax.hist(df.values[:, sindex:])
        elif histname == "logzplus1":
            ax.hist(np.log(df.values[:, sindex:]))
        else:
            sys.exit("Unrecognized histogram name: " + histname)
        plt.minorticks_on()
        #ax.set_xscale("log")
        ax.set_ylabel("Count", fontsize = 17)
        ax.set_xlabel("log( z + 1 )", fontsize = 17)
        ax.tick_params(axis = "x", which = "minor")
        ax.tick_params(axis = "y", which = "minor")
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        plt.title("Histogram of the simulated redshifts from\nthe rate density model of " + modelName)
        plt.tight_layout()
        plt.savefig(examname + "." + histname + ".sample.png")

Visualization of the example output ⛓

Test:

test_pm_cosmicRate

Todo:

This generic interface can be extended to higher-rank input arrays.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, September 1, 2017, 12:00 AM, Institute for Computational Engineering and Sciences (ICES), The University of Texas Austin

Definition at line 1039 of file pm_cosmicRate.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_cosmicRate.F90