pm_timer.F90

Go to the documentation of this file.

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!                                                                                                                            !!!!
!!!!    ParaMonte: Parallel Monte Carlo and Machine Learning Library.                                                           !!!!
!!!!                                                                                                                            !!!!
!!!!    Copyright (C) 2012-present, The Computational Data Science Lab                                                          !!!!
!!!!                                                                                                                            !!!!
!!!!    This file is part of the ParaMonte library.                                                                             !!!!
!!!!                                                                                                                            !!!!
!!!!    LICENSE                                                                                                                 !!!!
!!!!                                                                                                                            !!!!
!!!!       https://github.com/cdslaborg/paramonte/blob/main/LICENSE.md                                                          !!!!
!!!!                                                                                                                            !!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
module pm_timer
 
#if     CHECK_ENABLED
#define CHECK_ASSERTION(LINE,ASSERTION,MSG) \
block; \
use pm_err, only: getFine; \
use pm_val2str, only: getStr; \
use pm_err, only: setAsserted; \
call setAsserted(ASSERTION,getFine(__FILE__,LINE)//MODULE_NAME//MSG); \
end block;
#else
#define CHECK_ASSERTION(LINE,ASSERTION,MSG) continue;
#endif
 
    use pm_kind, only: SK, LK, IKD, RKD
 
    implicit none
 
    character(*, SK), parameter :: MODULE_NAME = "@pm_timer"
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    abstract interface
    function getTime_proc(since) result(timeInSec)
        use pm_kind, only: RKD
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
    end function
    end interface
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    abstract interface
    subroutine setIdle_proc(seconds)
        use pm_kind, only: RKD
        real(RKD), intent(in) :: seconds
    end subroutine
    end interface
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    type, abstract  :: timer_type
        real(RKD)   :: start
        real(RKD)   :: clock
        real(RKD)   :: delta
        real(RKD)   :: resol
    contains
        procedure(getTime_proc), nopass, deferred   :: time
        procedure(setIdle_proc), nopass, deferred   :: wait
    end type
 
    interface timer_type
        module procedure :: timer_typer
    end interface
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    type, extends(timer_type)       :: timerCPU_type
    contains
        procedure, nopass           :: time => getTimeCPU   
        procedure, nopass           :: wait => setIdleCPU   
    end type
 
    interface timerCPU_type
        module procedure            :: timerCPU_typer
    end interface
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    type, extends(timer_type)       :: timerDAT_type
    contains
        procedure, nopass           :: time => getTimeDAT   
        procedure, nopass           :: wait => setIdleDAT   
    end type
 
    interface timerDAT_type
        module procedure            :: timerDAT_typer
    end interface
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if MPI_ENABLED
    type, extends(timer_type)       :: timerMPI_type
    contains
        procedure, nopass           :: time => getTimeMPI   
        procedure, nopass           :: wait => setIdleMPI   
    end type
 
    interface timerMPI_type
        module procedure            :: timerMPI_typer
    end interface
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if OMP_ENABLED
    type, extends(timer_type)       :: timerOMP_type
    contains
        procedure, nopass           :: time => getTimeOMP   
        procedure, nopass           :: wait => setIdleOMP   
    end type
 
    interface timerOMP_type
        module procedure            :: timerOMP_typer
    end interface
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    !!>  \brief
    !!>  This s the derived type for generating objects containing information about the system clock count.
    !!>
    !!>  \final{Count_type}
    !!>
    !!>  \author
    !!>  Amir Shahmoradi, March 22, 2012, 00:00 AM, National Institute for Fusion Studies, The University of Texas Austin<br>
    !type                            :: SysClockCount_type
    !    integer(IKD)                :: start = 0_IKD    !< The scalar `integer` of kind double precision \IKD containing the processor-dependent starting clock counts of the system.
    !    integer(IKD)                :: clock = 0_IKD    !< The scalar `integer` of kind double precision \IKD containing the total processor clock counts since `start`.
    !    integer(IKD)                :: delta = 0_IKD    !< The scalar `integer` of kind double precision \IKD containing total processor clock count since the last clock count measurement.
    !    integer(IKD)                :: max   = 0_IKD    !< The scalar `integer` of kind double precision \IKD containing maximum value that the processor count may take, or `0` if there is no clock.
    !    integer(IKD)                :: rate  = 0_IKD    !< The scalar `integer` of kind double precision \IKD containing number of clock counts per second, or `0` if there is no clock.
    !end type
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    type, extends(timer_type)       :: timerSYS_type
       !type(SysClockCount_type)    :: Count    !< An object of type [SysClockCount_type](@ref pm_timer::SysClockCount_type) containing information about the system clock.
    contains
        procedure, nopass           :: time => getTimeSYS   
        procedure, nopass           :: wait => setIdleSYS   
    end type
 
    interface timerSYS_type
        module procedure            :: timerSYS_typer
    end interface
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
contains
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function timer_typer() result(timer)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: timer_typer
#endif
#if     MPI_ENABLED
        type(timerMPI_type) :: timer
        timer = timerMPI_type()
#elif   OMP_ENABLED
        type(timerOMP_type) :: timer
        timer = timerOMP_type()
#else
        type(timerSYS_type) :: timer
        timer = timerSYS_type()
#endif
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function timerCPU_typer() result(timer)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: timerCPU_typer
#endif
        type(timerCPU_type) :: timer
        timer%resol = getResTimerCPU()
        timer%start = timer%time()
        timer%delta = 0._RKD
        timer%clock = 0._RKD
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function timerDAT_typer() result(timer)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: timerDAT_typer
#endif
        type(timerDAT_type) :: timer
        timer%resol = 0.001_RKD
        timer%start = timer%time()
        timer%delta = 0._RKD
        timer%clock = 0._RKD
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if MPI_ENABLED
    function timerMPI_typer() result(timer)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: timerMPI_typer
#endif
        use mpi !mpi_f08, only: mpi_initialized, mpi_init, mpi_wtick
        type(timerMPI_type) :: timer
        logical :: initialized
        integer :: ierrMPI
!#if     CHECK_ENABLED
!        block
!            use pm_err, only: setAsserted
!            use pm_val2str, only: getStr
!            logical :: initialized, finalized
!            integer :: ierrMPI
!            call mpi_initialized(initialized, ierrMPI)
!            call setAsserted(ierrMPI /= 0 .and. initialized, MODULE_NAME//SK_"@timerMPI_typer(): The MPI library must be initialized before attempting to call the MPI timer.")
!            call mpi_finalized(finalized, ierrMPI)
!            call setAsserted(ierrMPI /= 0 .and. finalized, MODULE_NAME//SK_"@timerMPI_typer(): The MPI library must not be finalized prior to calling the MPI timer.")
!        end block
!#endif
        ierrMPI = 0
        call mpi_initialized(initialized, ierrMPI)
        if (.not. initialized .and. ierrMPI == 0) call mpi_init(ierrMPI)
        if (ierrMPI /= 0) error stop MODULE_NAME//SK_"@timerMPI_typer(): Failed to initialize the MPI library."
        timer%resol = real(mpi_wtick(), RKD)
        timer%start = timer%time()
        timer%delta = 0._RKD
        timer%clock = 0._RKD
    end function
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if OMP_ENABLED
    function timerOMP_typer() result(timer)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: timerOMP_typer
#endif
        use omp_lib
        type(timerOMP_type) :: timer
        timer%resol = real(omp_get_wtick(), RKD)
        timer%start = timer%time()
        timer%delta = 0._RKD
        timer%clock = 0._RKD
    end function
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function timerSYS_typer() result(timer)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: timerSYS_typer
#endif
        type(timerSYS_type) :: timer
        timer%resol = getResTimerSYS()
        timer%start = timer%time()
        timer%delta = 0._RKD
        timer%clock = 0._RKD
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function getTime(since) result(timeInSec)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getTime
#endif
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
#if     MPI_ENABLED
        timeInSec = getTimeMPI(since)
#elif   OMP_ENABLED
        timeInSec = getTimeOMP(since)
#else
        timeInSec = getTimeSYS(since)
#endif
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function getTimeCPU(since) result(timeInSec)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getTimeCPU
#endif
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
        call cpu_time(timeInSec)
        CHECK_ASSERTION(__LINE__, timeInSec >= 0._RKD, SK_"@getTimeCPU(): The CPU does not have a clock.") ! fpp
        if (present(since)) timeInSec = timeInSec - since
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function getTimeDAT(since) result(timeInSec)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getTimeDAT
#endif
        use pm_kind, only: IK, RKD
        use pm_dateTime, only: getJulianDay
        use pm_dateTime, only: SECONDS_PER_DAY
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
        integer(IK) :: values(8)
        call date_and_time(values = values)
        timeInSec = getJulianDay(values) * SECONDS_PER_DAY
        if (present(since)) timeInSec = timeInSec - since
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if MPI_ENABLED
    function getTimeMPI(since) result(timeInSec)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getTimeMPI
#endif
        use mpi !mpi_f08, only: mpi_wtime
        use pm_kind, only: IK, RKD
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
        timeInSec = mpi_wtime()
        if (present(since)) timeInSec = timeInSec - since
    end function
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if OMP_ENABLED
    function getTimeOMP(since) result(timeInSec)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getTimeOMP
#endif
        use pm_kind, only: IK, RKD
        use omp_lib, only: omp_get_wtime
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
        timeInSec = omp_get_wtime()
        if (present(since)) timeInSec = timeInSec - since
    end function
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
      end do      end do
    function getTimeSYS(since) result(timeInSec)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getTimeSYS
#endif
        real(RKD), intent(in), optional :: since
        real(RKD) :: timeInSec
        real(RKD) :: count_rate
        integer(IKD) :: count
       !integer(IKD) :: cmax
        call system_clock(count, count_rate)!, count_max = cmax)
        CHECK_ASSERTION(__LINE__, count > 0_IKD .and. count_rate > 0._RKD, SK_"@getTimeSYS(): The system does not have a clock.") ! .and. cmax > 0_IKD
        timeInSec = count / count_rate
        if (present(since)) timeInSec = timeInSec - since
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function getResTimer() result(resolution)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getResTimer
#endif
        real(RKD) :: resolution
#if     MPI_ENABLED
        resolution = getResTimerMPI()
#elif   OMP_ENABLED
        resolution = getResTimerOMP()
#else
        resolution = getResTimerSYS()
#endif
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function getResTimerCPU() result(resolution)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getResTimerCPU
#endif
        real(RKD) :: resolution
        real(RKD) :: resolution_
        call cpu_time(time = resolution_)
        CHECK_ASSERTION(__LINE__, resolution_ >= 0._RKD, SK_"@getResTimerCPU(): The CPU does not have a clock.") ! fpp
        do
            call cpu_time(time = resolution)
            if (resolution == resolution_) cycle
            resolution = resolution - resolution_
            exit
        end do
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    pure function getResTimerDAT() result(resolution)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getResTimerDAT
#endif
        real(RKD) :: resolution
        resolution = 0.001_RKD
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if MPI_ENABLED
    function getResTimerMPI() result(resolution)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getResTimerMPI
#endif
        use mpi !mpi_f08, only: mpi_wtick
        real(RKD) :: resolution
        resolution = real(mpi_wtick(), RKD)
    end function
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if OMP_ENABLED
    function getResTimerOMP() result(resolution)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getResTimerOMP
#endif
        use omp_lib, only: omp_get_wtick
        real(RKD) :: resolution
        resolution = real(omp_get_wtick(), RKD)
    end function
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    function getResTimerSYS() result(resolution)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: getResTimerSYS
#endif
        real(RKD) :: resolution
        call system_clock(count_rate = resolution)
        CHECK_ASSERTION(__LINE__, resolution > 0._RKD, SK_"@getResTimerSYS(): The system does not have a clock.") ! fpp
        resolution = 1._RKD / resolution
    end function
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setIdle(seconds)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: setIdle
#endif
        use pm_kind, only: RKD
        real(RKD)   , intent(in)    :: seconds
#if     MPI_ENABLED
        call setIdleMPI(seconds)
#elif   OMP_ENABLED
        call setIdleOMP(seconds)
#else
        call setIdleSYS(seconds)
#endif
    end subroutine
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setIdleCPU(seconds)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: setIdleCPU
#endif
        use pm_kind, only: RKD
        real(RKD)   , intent(in)    :: seconds
        real(RKD)                   :: since
        since = getTimeCPU()
        do
            if (getTimeCPU() - since > seconds) exit
        end do
    end subroutine
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setIdleDAT(seconds)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: setIdleDAT
#endif
        use pm_kind, only: RKD
        real(RKD)   , intent(in)    :: seconds
        real(RKD)                   :: since
        since = getTimeDAT()
        do
            if (getTimeDAT() - since > seconds) exit
        end do
    end subroutine
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if MPI_ENABLED
    subroutine setIdleMPI(seconds)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: setIdleMPI
#endif
        use pm_kind, only: RKD
        real(RKD)   , intent(in)    :: seconds
        real(RKD)                   :: since
        since = getTimeMPI()
        do
            if (getTimeMPI() - since > seconds) exit
        end do
    end subroutine
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
#if OMP_ENABLED
    subroutine setIdleOMP(seconds)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: setIdleOMP
#endif
        use pm_kind, only: RKD
        real(RKD)   , intent(in)    :: seconds
        real(RKD)                   :: since
        since = getTimeOMP()
        do
            if (getTimeOMP() - since > seconds) exit
        end do
    end subroutine
#endif
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setIdleSYS(seconds)
#if __INTEL_COMPILER && DLL_ENABLED && (_WIN32 || _WIN64)
        !DEC$ ATTRIBUTES DLLEXPORT :: setIdleSYS
#endif
        use pm_kind, only: RKD
        real(RKD)   , intent(in)    :: seconds
        real(RKD)                   :: since
        since = getTimeSYS()
        do
            if (getTimeSYS() - since > seconds) exit
        end do
    end subroutine
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
end module pm_timer ! LCOV_EXCL_LINE