pm_sampleACT::getACT Interface Reference

Generate and return the integrated auto-correlation time (ACT) of the discrete signal.
More...

Detailed Description

Generate and return the integrated auto-correlation time (ACT) of the discrete signal.

This generic interface a flexible wrapper for the lower-level potentially faster generic interface setACF.
See the documentation of the parent module pm_sampleACT for algorithmic details and auto-correlation definition.

Parameters

[in]	seq	: The input contiguous vector of arbitrary size (of minimum 2) of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the sequence auto-correlation time must be computed.
[in]	weight	: The input vector of type integer of default kind IK of the same size as the input seq, containing the weights of the corresponding elements of the input seq. (optional, default = [(1, i = 1, size(seq))])
[in]	method	: The input scalar constant that can be: the constant batchMeans or an object of type batchMeans_type(size = size), implying that the returned ACT is computed using the BatchMeans method with the optionally specified size. If the size component of the input object of type batchMeans_type(size = size) is unset or 0, an appropriate default based on the length of the input sequence will be determined and used. This option offers a reasonable tradeoff between good estimate and computational efficiency. However, the results depend heavily on the specified batch size, hence, still underestimate the actual ACT. the constant batchMeansMax or an object of type batchMeans_type(smin, smax, step), implying that the returned ACT is computed as the maximum of the BatchMeans method for the specified range of batch sizes `getRange(batchMeans_type%smin, batchMeans_type%smax, batchMeans_type%step). If the components of the input object of type batchMeans_type(smin, smax, step) are unset (default), then smin and step will be both set to 1 and smax is set to size(seq) / 2. This option will likely yield the least biased results but will be computationally significantly more demanding. the constant cumSum or an object of type cumSum_type(signif), implying that the returned ACT is simply the cumulative sum of auto-correlations of the input sequence at all possible lags: act = 1 + 2 * sum(getACT(seq)). This option is merely provided for exploratory and education reasons. the constant cumSumMax or an object of type cumSumMax_type(smin, smax, step), implying that the returned ACT is computed as the maximum of the cumulative sum of auto-correlations of the input sequence at all possible lags. This option is merely provided for exploratory and education reasons. This option is merely provided for exploratory and education reasons. (optional, default = batchMeans_type(size = size(seq)**0.66).)

Returns

act : The output scalar of the same type and kind as that of the input sequence, containing the estimated integrated autocorrelation time of the input sequence.

Possible calling interfaces ⛓

use pm_sampleACT, only: getACT
 
act = getACT(seq(:), method = method)
act = getACT(seq(:), weight, method = method)

Warning

The condition 1 < methodsmin must hold for the corresponding input arguments.
The condition 0 < methodsignif must hold for the corresponding input arguments.
The condition size(weight) == size(seq) must hold for the corresponding input arguments.
The condition methodsmin <= methodsmax <= size(seq, 1) / 2 must hold for the corresponding input arguments.
The condition methodsize * 2 < sum(weight) must hold for the corresponding input arguments, otherwise sum(weight) will be returned as the act.
The condition 1 < size(seq) must hold for the corresponding input arguments, otherwise act will be set to lenseq on return.
The condition 0 < methodstep must hold for the corresponding input arguments.
The condition 0 < methodsize must hold for the corresponding input arguments.

Remarks

The procedures under discussion are impure.

See also

getACT
getACF
setACF
getCor
setCor
getRho
setRho
getCov
setCov
setECDF
getMean
setMean
getShifted
setShifted
getVar
setVar

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_io, only: getErrTableRead, TAB
    use pm_sampleACT, only: batchMeansMax, batchMeansMax_type
    use pm_sampleACT, only: batchMeans, batchMeans_type
    use pm_sampleACT, only: cumSumMax, cumSumMax_type
    use pm_sampleACT, only: cumSum, cumSum_type
    use pm_sampleACT, only: getACT
    use pm_io, only: display_type
 
    implicit none
 
    integer(IK) :: skip
    type(display_type) :: disp
    character(:), allocatable :: format
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!Compute the cross-correlation of two samples.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    block
        use pm_kind, only: TKG => RKS ! All other real types are also supported.
        real(TKG), allocatable :: table(:,:)
        real(TKG) :: act
        call disp%skip()
        call disp%show("if (0 /= getErrTableRead(SK_'duluth.txt', table, sep = TAB, roff = 1_IK)) error stop 'table read failed.'")
                        if (0 /= getErrTableRead(SK_'duluth.txt', table, sep = TAB, roff = 1_IK)) error stop 'table read failed.'
        call disp%show("act = getACT(table(:,2)) ! temperature see visualization below.")
                        act = getACT(table(:,2)) ! temperature see visualization below.
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = batchMeans)")
                        act = getACT(table(:,2), method = batchMeans)
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = batchMeans_type(size = 365_IK))")
                        act = getACT(table(:,2), method = batchMeans_type(size = 365_IK))
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = batchMeansMax_type())")
                        act = getACT(table(:,2), method = batchMeansMax_type())
                        skip = int(act, IK)
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = batchMeansMax_type(step = 10_IK))")
                        act = getACT(table(:,2), method = batchMeansMax_type(step = 10_IK))
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = cumSum)")
                        act = getACT(table(:,2), method = cumSum)
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = cumSum_type(signif = 5_IK))")
                        act = getACT(table(:,2), method = cumSum_type(signif = 5_IK))
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = cumSum_type(signif = 0_IK))")
                        act = getACT(table(:,2), method = cumSum_type(signif = 0_IK))
        call disp%show("act")
        call disp%show( act )
        call disp%show("act = getACT(table(:,2), method = cumSumMax)")
                        act = getACT(table(:,2), method = cumSumMax)
        call disp%show("act")
        call disp%show( act )
        call disp%skip()
    end block
 
    block
        use pm_arrayResize, only: setResized
        use pm_io, only: getErrTableWrite, trans
        use pm_arrayRange, only: getRange
        use pm_kind, only: TKG => RKS ! All other real types are also supported.
        character(:, SK), allocatable :: header
        integer(IK), allocatable :: sbatch(:)
        real(TKG), allocatable :: output(:,:)
        real(TKG), allocatable :: table(:,:)
        integer(IK) :: ibatch
        if (0 /= getErrTableRead(SK_'duluth.txt', table, header, sep = TAB)) error stop 'table read failed.'
        sbatch = getRange(2_IK, size(table, 1, IK) / 2_IK)
        call setResized(output, [size(sbatch, 1, IK), 2_IK])
        do ibatch = 1, size(sbatch, 1, IK)
            output(ibatch, 1) = sbatch(ibatch)
            output(ibatch, 2) = getACT(table(:, 2), batchMeans_type(sbatch(ibatch)))
        end do
        if (0 /= getErrTableWrite(SK_'getACT.duluth.batchMeans.txt', output, header = SK_"batchSize"//TAB//SK_"ACT", sep = TAB)) error stop 'table read failed.'
        ! Write the thinned sample.
        table = table(1 : size(table, 1, IK) : skip, :)
        if (0 /= getErrTableWrite(SK_'getACT.duluth.thinned.txt', table, header//SK_" (BMM-thinned)", sep = TAB)) error stop 'table read failed.'
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!Compute the cross-correlation of two samples.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
if (0 /= getErrTableRead(SK_'duluth.txt', table, sep = TAB, roff = 1_IK)) error stop 'table read failed.'
act = getACT(table(:,2)) ! temperature see visualization below.
act
+12.7669811
act = getACT(table(:,2), method = batchMeans)
act
+12.7669811
act = getACT(table(:,2), method = batchMeans_type(size = 365_IK))
act
+3.07212925
act = getACT(table(:,2), method = batchMeansMax_type())
act
+87.1719818
act = getACT(table(:,2), method = batchMeansMax_type(step = 10_IK))
act
+74.3042755
act = getACT(table(:,2), method = cumSum)
act
+99.3170776
act = getACT(table(:,2), method = cumSum_type(signif = 5_IK))
act
+99.0806656
act = getACT(table(:,2), method = cumSum_type(signif = 0_IK))
act
+99.3170776
act = getACT(table(:,2), method = cumSumMax)
act
+99.3170776
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
import os
 
linewidth = 2
fontsize = 17
 
parent = os.path.basename(os.path.dirname(__file__))
pattern = parent + "*.txt"
files = glob.glob(pattern)
 
for file in files:
 
    df = pd.read_csv(file, delimiter = "\t")
 
    #print(df.values)
    fig = plt.figure(figsize = (8, 6))
    ax = plt.subplot(1,1,1)
    ax.plot ( df.values[:, 0]
            , df.values[:,1]
            , zorder = 1000
            )
    #ax.scatter  ( df.values[:, 0]
    #            , df.values[:,1]
    #            , zorder = 1000
    #            , s = 1
    #            )
    plt.minorticks_on()
    ax.set_xlabel(df.columns.values[0], fontsize = 17)
    ax.set_ylabel(df.columns.values[1], fontsize = 17)
    ax.tick_params(axis = "x", which = "minor")
    ax.tick_params(axis = "y", which = "minor")
    plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
    ax.legend(["Duluth, MN"], fontsize = fontsize)
    plt.tight_layout()
    plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Test:

test_pm_sampleACT

Internal naming convention:

The following illustrates the internal naming convention used for the procedures within this generic interface.

getACT_CSD_WTI_D1_CK5()
   ||| ||| ||| || |||
   ||| ||| ||| || The type and kind parameters of the input sequence.
   ||| ||| ||| The dimension of the input sequence `seq`.
   ||| ||| Weight type: WTTI => integer weight, ONE => no weight.
   ||| The method: BMD => BatchMeans Default, BMM => BatchMeans Maximum, CSD => CumSum Default, CSM => CumSum Maximum
   ACF: Cross-Correlation Function.

Todo:

High Priority: The performance of the implementations of this generic interface can be improved by minimizing allocations and converting function calls to subroutine calls.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Fatemeh Bagheri, Monday 02:15 AM, September 27, 2021, Dallas, TX

Definition at line 220 of file pm_sampleACT.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_sampleACT.F90