pm_io::getCountRecordLeft Interface Reference

Generate and return the number of records left (starting immediately after the last accessed record) in the record-oriented input file. More...

Detailed Description

Generate and return the number of records left (starting immediately after the last accessed record) in the record-oriented input file.

If any error occurs during the IO and the output iostat argument is missing, the program will halt by calling error stop.

Parameters

[in]	unit	: The input scalar integer of default kind IK containing the unit of the connected file whose number of record left is to be returned.
	isCountable	: The external user-specified function that takes one input scalar character of default kind SK of arbitrary length type parameter, containing the most recent record that has been read from the input file. It returns a scalar logical of default kind LK that is .true. if and only if the input record should be included in counting. The following illustrates the generic interface of isCountable, function isCountable(record) result(countable) use pm_kind, only: LK, SK character(*, SK), intent(in) :: record logical(LK) :: countable end function This user-defined countability check is extremely useful where certain records in the file ought to be excluded from counting or only records with specific patterns should be included (for example, excluding or including only records that are empty or begin with or end with or have specific patterns). (optional. If missing, all records are included in counting).
[in]	reset	: The input scalar logical of default kind LK. If .true., the record position in the file will be reset to where it was upon entering the procedure. If .false., the record position will be the end of the file. This option is useful for scenarios where a file has been partially read (e.g., fixed header), but the number of remaining file records is required to read the rest of the file. This is done by calling the Fortran intrinsic backspace for nrecord number of times. Note that the backspace statement is often very costly in computer resources. Therefore this use of this optional argument should be minimized in performance critical routines. (optional, default = .false.)
[out]	iostat	: The optional output scalar integer of default kind IK. If present and no error occurs, it is set to 0 on output. If present and an error occurs (e.g., if the input argument values are wrong or inconsistent), it is set to a positive non-zero value. If missing and an error occurs, then the program halts by calling error stop followed by the relevant error message.
[in,out]	iomsg	: The input/output scalar character of default kind SK containing the error message, if any error occurs. A length type parameter value of LEN_IOMSG is generally sufficient for iomsg to contain the output error messages. (optional. Its presence is relevant only if the iostat output argument is also present.)

Returns

nrecord : The output scalar integer of default kind IK, representing the number of records in the input file.

Possible calling interfaces ⛓

use pm_io, only: getCountRecordLeft
 
nrecord = getCountRecordLeft(file, isCountable = isCountable, reset = reset, iostat = iostat, iomsg = iomsg)

Warning

The input unit must be connected to a file prior to calling this procedure.
Additionally, this procedure will not close the file upon return.

See also

getCountRecord
isPreconnected
setRecordFrom
getFileUnit

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_io, only: display_type
    use pm_io, only: getCountRecordLeft
 
    implicit none
 
    integer(IK) :: unit
    character(255, SK) :: record
    type(display_type) :: disp
 
    disp = display_type(file = "main.out.F90")
 
    call disp%skip
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!Count the number of records in the record-oriented (sequential access) `main.F90` file.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip
 
    call disp%skip
    call disp%show("open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')")
                    open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')
    call disp%show("getCountRecordLeft(unit)")
    call disp%show( getCountRecordLeft(unit) )
    call disp%show("close(unit)")
                    close(unit)
    call disp%skip
 
    call disp%skip
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!Count the number of records in the `main.F90` file starting from the current position, then reset the position to where it was.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip
 
    call disp%skip
    call disp%show("open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')")
                    open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')
    call disp%show("read(unit,*); read(unit,*) ! move the position to the beginning of the third record.")
                    read(unit,*); read(unit,*)
    call disp%show("read(unit,'(a)') record; backspace(unit) ! read the current line as a reference to compare.")
                    read(unit,'(a)') record; backspace(unit)
    call disp%show("trim(record)")
    call disp%show( trim(record) , deliml = SK_"""" )
    call disp%show("getCountRecordLeft(unit, reset = .true._LK)")
    call disp%show( getCountRecordLeft(unit, reset = .true._LK) )
    call disp%show("read(unit,'(a)') record ! read the current line again to compare with the value before calling getCountRecordLeft().")
                    read(unit,'(a)') record
    call disp%show("trim(record)")
    call disp%show( trim(record) , deliml = SK_"""" )
    call disp%show("close(unit)")
                    close(unit)
    call disp%skip
 
    call disp%skip
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!Exclude certain records that match the user-specified behavior via isCountable.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip
 
    call disp%skip
    call disp%show("open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')")
                    open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')
    call disp%show("getCountRecordLeft(unit, isCountable = isCountable)")
    call disp%show( getCountRecordLeft(unit, isCountable = isCountable) )
    call disp%show("close(unit)")
                    close(unit)
    call disp%skip
 
contains
 
    function isCountable(record) result(countable)
        character(*, SK), intent(in)    :: record
        logical(LK)                     :: countable
        countable = index(record, SK_"call disp%skip", kind = IK) == 0_IK
    end function
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!Count the number of records in the record-oriented (sequential access) `main.F90` file.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')
getCountRecordLeft(unit)
+77
close(unit)
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!Count the number of records in the `main.F90` file starting from the current position, then reset the position to where it was.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')
read(unit,*); read(unit,*) ! move the position to the beginning of the third record.
read(unit,'(a)') record; backspace(unit) ! read the current line as a reference to compare.
trim(record)
"    use pm_kind, only: SK, IK, LK"
getCountRecordLeft(unit, reset = .true._LK)
+75
read(unit,'(a)') record ! read the current line again to compare with the value before calling getCountRecordLeft().
trim(record)
"    use pm_io, only: display_type"
close(unit)
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!Exclude certain records that match the user-specified behavior via isCountable.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
open(newunit = unit, file = 'main.F90', status = 'old', action = 'read')
getCountRecordLeft(unit, isCountable = isCountable)
+65
close(unit)
 
 

Test:

test_pm_io

Todo:

This procedure can be converted to a generic interface to add the optional iseq() external comparison procedures for custom exclusion or inclusion of lines in the count.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Tuesday March 7, 2017, 3:50 AM, Institute for Computational Engineering and Sciences (ICES), The University of Texas at Austin

Definition at line 2226 of file pm_io.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_io.F90