pm_distPiwiPoweto::getPiwiPowetoLogPDF Interface Reference

Generate and return the natural logarithm of the Probability Density Function (PDF) of the (Truncated) PiwiPoweto distribution for an input logx within the support of the distribution logLimX(1) <= logx <= logLimX(n+1).
More...

Detailed Description

Generate and return the natural logarithm of the Probability Density Function (PDF) of the (Truncated) PiwiPoweto distribution for an input logx within the support of the distribution logLimX(1) <= logx <= logLimX(n+1).

See the documentation of pm_distPiwiPoweto for more information on the (Truncated) PiwiPoweto distribution.

Parameters

[in]	logx	: The input scalar of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the natural logarithm of the x value within the support of the distribution at which the PDF must be computed.
[in]	alpha	: The input vector of the same type and kind as logx, of the same size n as the number of the power-law components of the distribution, containing the shape parameter of the distribution (i.e., the exponents of the power-law components of the distribution).
[in]	logLimX	: The input vector of the same type and kind as logx, of size size(alpha) + 1 containing the natural logarithm of the limits of the n power-law components of the distribution in ascending order, such that logLimX(1) <= x <= logLimX(size(logLimX)). Setting logLimX(size(logLimX)) >= log(huge(logLimX)) effectively implies a right-opened semi-infinite support for the distribution. containing the natural logarithm of the scale parameters (i.e., the break points, or the minimum values of the power-law components) of the distribution.
[in]	logPDFNF	: The input vector of the same type, kind, and size as alpha, containing the natural logarithm of the normalization factors ( \(\eta\)) of power-law components of the distribution of the (Truncated) PiwiPoweto distribution. Specifying this argument when calling this procedure repeatedly with fixed \((\alpha, x_\mathrm{lim})\) parameters significantly improves the runtime performance. (optional, default = getPiwiPowetoLogPDFNF(alpha, logLimX))

Returns

logPDF : The output scalar of the same type and kind the input argument logx, containing the natural logarithm of the PDF of the distribution at the specified point within the support of the PDF.

Possible calling interfaces ⛓

use pm_distPiwiPoweto, only: getPiwiPowetoLogPDF
 
logPDF = getPiwiPowetoLogPDF(logx, alpha(1:n), logLimX(1:n+1), logPDFNF = logPDFNF(1:n))

Warning

The condition size(alpha) > 0 must hold for the corresponding input arguments.
The condition size(logLimX) == size(alpha) + 1 must hold for the corresponding input arguments.
The condition size(logPDFNF) == size(alpha) must hold for the corresponding input arguments.
The conditions logLimX(1) <= logx .and. logx < logLimX(size(logLimX)) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

See also

setPiwiPowetoLogPDF

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_distPiwiPoweto, only: getPiwiPowetoLogPDF
    use pm_distPiwiPoweto, only: getPiwiPowetoLogPDFNF
    use pm_arraySpace, only: setLinSpace
    use pm_io, only: display_type
 
    implicit none
 
    integer(IK), parameter  :: NP = 999_IK
    real                    :: logX(NP), logPDF(NP)
 
    type(display_type)      :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute the Probability Density Function (PDF) of the PiwiPoweto distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("logPDF(1) = getPiwiPowetoLogPDF(logx = log(3.), alpha = [-2.], logLimX = [log(2.), log(huge(0.))])")
                    logPDF(1) = getPiwiPowetoLogPDF(logx = log(3.), alpha = [-2.], logLimX = [log(2.), log(huge(0.))])
    call disp%show("logPDF(1)")
    call disp%show( logPDF(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))])")
                    logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))])
    call disp%show("logPDF(1)")
    call disp%show( logPDF(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0.], logLimX = [0.5, 1., 1.5]) ! Truncated PiwiPoweto with the upper bound `1.5`.")
                    logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0.], logLimX = [0.5, 1., 1.5]) ! Truncated PiwiPoweto with the upper bound `1.5`.
    call disp%show("logPDF(1)")
    call disp%show( logPDF(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Expedite repeated PDF computations by precomputing the normalization factors.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))], logPDFNF = getPiwiPowetoLogPDFNF(alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))]))")
                    logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))], logPDFNF = getPiwiPowetoLogPDFNF(alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))]))
    call disp%show("logPDF(1)")
    call disp%show( logPDF(1) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example logPDF array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        real, parameter :: LOG_HUGE = log(huge(0.))
        integer(IK) :: fileUnit, i
        real, allocatable :: logLimX(:), alpha(:)
        real :: logPDF(4)
        alpha = [3., 1., -1., -5.]
        logLimX = log([2., 5., 10., 15.])
        call setLinSpace(logX, x1 = log(0.001), x2 = log(20.), fopen = .true._LK, lopen = .true._LK)
        open(newunit = fileUnit, file = "getPiwiPowetoLogPDF.RK.txt")
        do i = 1, NP
            logPDF = -huge(0.)
            logPDF(1) = getPiwiPowetoLogPDF(logX(i), [alpha(1:2), 0., alpha(3:4)], [-LOG_HUGE, logLimX(1:4), LOG_HUGE]) ! PiwiPoweto
            if (logX(i) > logLimX(1)) logPDF(2) = getPiwiPowetoLogPDF(logX(i), alpha(2:4), [logLimX(1:3), LOG_HUGE]) ! left-truncated PiwiPoweto
            if (logX(i) < logLimX(4)) logPDF(3) = getPiwiPowetoLogPDF(logX(i), alpha(2:4), [-LOG_HUGE, logLimX(2:4)]) ! right-truncated PiwiPoweto
            if (logX(i) > logLimX(1) .and. logX(i) < logLimX(4)) logPDF(4) = getPiwiPowetoLogPDF(logX(i), alpha(1:3), logLimX(1:4)) ! doubly-truncated PiwiPoweto
            write(fileUnit,"(*(g0,:,', '))") exp(logX(i)), exp(logPDF)
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute the Probability Density Function (PDF) of the PiwiPoweto distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
logPDF(1) = getPiwiPowetoLogPDF(logx = log(3.), alpha = [-2.], logLimX = [log(2.), log(huge(0.))])
logPDF(1)
-1.21639538
 
 
logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))])
logPDF(1)
-1.44477296
 
 
logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0.], logLimX = [0.5, 1., 1.5]) ! Truncated PiwiPoweto with the upper bound `1.5`.
logPDF(1)
-0.887356758
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Expedite repeated PDF computations by precomputing the normalization factors.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
logPDF(1) = getPiwiPowetoLogPDF(logx = log(2.5), alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))], logPDFNF = getPiwiPowetoLogPDFNF(alpha = [1., 0., -1.5], logLimX = [0.5, 1., 1.5, log(huge(0.))]))
logPDF(1)
-1.44477296
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : "X ( real/imaginary components )"
        , "IK" : "X ( integer-valued )"
        , "RK" : "X ( real-valued )"
        }
legends =   [ r"5-piece Poweto"
            , r"3-piece left-truncated Poweto"
            , r"4-piece right-truncated Poweto"
            , r"4-piece doubly-truncated Poweto"
            ]
 
for kind in ["IK", "CK", "RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = ", ")
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
        ax = plt.subplot()
 
        if kind == "CK":
            plt.plot( df.values[:, 0]
                    , df.values[:,[2,4]]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "r"
                    )
            plt.plot( df.values[:,1]
                    , df.values[:,[3,5]]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "blue"
                    )
        else:
            plt.plot( df.values[:, 0]
                    , df.values[:,1:]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "r"
                    )
            ax.legend   ( legends
                        , fontsize = fontsize
                        )
 
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel(xlab[kind], fontsize = 17)
        ax.set_ylabel("Probability Density Function (PDF)", fontsize = 17)
        #ax.set_xscale("log")
        #ax.set_yscale("log")
 
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
 
        plt.tight_layout()
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distPiwiPoweto

Todo:

Low Priority: This generic interface can be extended to complex arguments.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 371 of file pm_distPiwiPoweto.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distPiwiPoweto.F90