pm_distNorm::setNormRandBox Interface Reference

Return a scalar or array of arbitrary rank of random values from the univariate Normal distribution, using the Box-Muller algorithm. More...

Detailed Description

Return a scalar or array of arbitrary rank of random values from the univariate Normal distribution, using the Box-Muller algorithm.

The procedures of this generic interface use the Box-Muller transform method to convert two uniformly distributed random input numbers to two output Normal-distributed random numbers.
The procedures deliberately return two output random values to ensure the purity of the procedures.
A more flexible implementation is available under the generic interface getNormRand.

Parameters

[in,out]	rand1	: The input/output scalar or array of the same shape as other array-like arguments, of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128). On input, it must contain a uniformly-distributed random number in the range \([0, 1)\). On output, it contains a Normal-distributed random value.
[in,out]	rand2	: The input/output scalar or array of the same shape as other array-like arguments, of the same type and kind as rand1. On input, it must contain a uniformly-distributed random number in the range \([0, 1)\). On output, it contains a Normal-distributed random value.
[out]	failed	: The output scalar or array of the same shape as other array-like arguments, of type logical of default kind LK that is .true. if and only if the Box-Muller rejection method fails to generate two Normal-random values. In such a case, the procedure should be called until failed = .false. is returned on output indicating success. (optional. If missing, the trigonometric Normal random number generation method will be used which is slightly (by about \(\ms{25%}\)) slower but guaranteed to succeed.)

Possible calling interfaces ⛓

use pm_kind, only: LK
use pm_distNorm, only: setNormRandBox
logical(LK) :: failed
 
! Box-Muller: Trigonometric-method implementation.
 
call random_number(rand1)
call random_number(rand2)
call setNormRandBox(rand1, rand2)
 
! Box-Muller: Rejection-method implementation.
 
do
    call random_number(rand1)
    call random_number(rand2)
    call setNormRandBox(rand1, rand2, failed)
    if (.not. failed) exit
end do

The condition 0. <= rand1 .and. rand1 < 1. must hold for the corresponding input arguments.
The condition 0. <= rand2 .and. rand2 < 1. must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

Warning

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getNormRand
setNormRand
setNormRandBox
getNormLogPDF
getNormCDF
setNormRandBox

Example usage ⛓

program example
 
    use pm_kind, only: SK
    use pm_kind, only: IK, RK ! all real kinds are supported.
    use pm_distNorm, only: setNormRandBox
    use pm_arraySpace, only: setLinSpace
    use pm_arraySpace, only: setLogSpace
    use pm_io, only: display_type
 
    implicit none
 
    integer(IK), parameter  :: NP = 1000_IK
    real(RK), dimension(NP) :: rand
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    !call setLinSpace(mean, x1 = -5._RK, x2 = +5._RK)
    !call setLogSpace(std, logx1 = log(0.1_RK), logx2 = log(10._RK))
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Generate random numbers from the (Standard) Normal distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Normal random number from a Standard Normal distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("call random_number(rand(1:2))")
                    call random_number(rand(1:2))
    call disp%show("call setNormRandBox(rand(1), rand(2))")
                    call setNormRandBox(rand(1), rand(2))
    call disp%show("rand(1:2)")
    call disp%show( rand(1:2) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example rand array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    ! Box-Muller Basic (Trigonometric) method.
 
    block
        integer(IK) :: fileUnit, i
        integer(IK), parameter :: NP = 5000_IK
        real(RK), dimension(NP) :: rand1, rand2, rand3
        call random_number(rand1)
        call random_number(rand2)
        call random_number(rand3)
        call setNormRandBox(rand1(1::2), rand1(2::2)); rand1 = rand1 * 3.0_RK + 2._RK
        call setNormRandBox(rand2(1::2), rand2(2::2)); rand2 = rand2 * 1.0_RK + 0._RK
        call setNormRandBox(rand3(1::2), rand3(2::2)); rand3 = rand3 * 1.0_RK - 5._RK
        open(newunit = fileUnit, file = "setNormRandBox.RK.txt")
        write(fileUnit,"(3(g0,:,' '))") ( rand1(i) &
                                        , rand2(i) &
                                        , rand3(i) &
                                        , i = 1,NP &
                                        )
        close(fileUnit)
    end block
 
    ! Box-Muller Polar (Rejection) method.
 
    block
        logical :: failed
        integer(IK) :: fileUnit, i, j
        integer(IK), parameter :: NP = 5000_IK
        real(RK), dimension(2) :: rand1, rand2, rand3
        open(newunit = fileUnit, file = "setNormRandBox.RK.txt")
        do i = 1, NP
            do
                call random_number(rand1(1:2))
                call setNormRandBox(rand1(1), rand1(2), failed = failed)
                if (.not. failed) exit
            end do
            rand1(1:2) = rand1(1:2) * 3 + 2
            do
                call random_number(rand2(1:2))
                call setNormRandBox(rand2(1), rand2(2), failed = failed)
                if (.not. failed) exit
            end do
            do
                call random_number(rand3(1:2))
                call setNormRandBox(rand3(1), rand3(2), failed = failed)
                if (.not. failed) exit
            end do
            rand3(1:2) = rand3(1:2) - 5._RK
            do j = 1, 2
                write(fileUnit,"(3(g0,:,' '))") rand1(j), rand2(j), rand3(j)
            end do
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Generate random numbers from the (Standard) Normal distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Normal random number from a Standard Normal distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
call random_number(rand(1:2))
call setNormRandBox(rand(1), rand(2))
rand(1:2)
-0.79983576933167955, +0.36302835062356015
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : "Normal Random Number ( real/imaginary components )"
        , "IK" : "Normal Random Number ( integer-valued )"
        , "RK" : "Normal Random Number ( real-valued )"
        }
legends =   [ r"$\mu = -5.,~\sigma = 1.0$"
            , r"$\mu = 0.0,~\sigma = 1.0$"
            , r"$\mu = 2.0,~\sigma = 3.0$"
            ]
 
for kind in ["IK", "CK", "RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = " ", header = None)
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
        ax = plt.subplot()
 
        if kind == "CK":
            plt.hist( df.values[:,0:3]
                    , histtype = "stepfilled"
                    , alpha = 0.5
                    , bins = 75
                    )
        else:
            plt.hist( df.values[:,0:3]
                    , histtype = "stepfilled"
                    , alpha = 0.5
                    , bins = 75
                    )
            ax.legend   ( legends
                        , fontsize = fontsize
                        )
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel(xlab[kind], fontsize = 17)
        ax.set_ylabel("Count", fontsize = 17)
        ax.set_title("Histograms of {} Normal random numbers".format(len(df.values[:, 0])), fontsize = 17)
 
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
 
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Benchmarks:

Benchmark :: The runtime performance of setNormRandBox for different implementations of the Box-Muller algorithm. ⛓

module internal
    use pm_kind, only: RKG => RK
    implicit none
contains
    impure subroutine setNormRandBox(rand1, rand2)
        real(RKG)   , intent(out)   :: rand1, rand2
        real(RKG)                   :: factor, rsq
        do
            call random_number(rand1)
            call random_number(rand2)
            rand1 = 2._RKG * rand1 - 1._RKG
            rand2 = 2._RKG * rand2 - 1._RKG
            rsq = rand1**2 + rand2**2
            if (0._RKG < rsq .and. rsq < 1._RKG) exit
        end do
        factor = sqrt(-2._RKG * log(rsq) / rsq)
        rand1 = rand1 * factor
        rand2 = rand2 * factor
    end subroutine
end module
 
 
! Test the performance of `setNormRandBoxBasic()` vs. `setNormRandBoxPolar()`.
program benchmark
 
    use iso_fortran_env, only: error_unit
    use pm_bench, only: bench_type, benchMulti_type
    use pm_io, only: display_type
    use pm_kind, only: SK, IK, LK, RK
    use internal, only: RKG
 
    implicit none
 
    integer(IK)                         :: itime
    integer(IK)                         :: ibench
    real(RKG)                           :: rand1 = 0._RKG, rand2 = 0._RKG
    real(RKG)                           :: dummy = 0._RKG
    type(benchMulti_type)               :: bench
    type(display_type)                  :: disp
    integer(IK)                         :: miniter = 10000_IK
 
    bench = benchMulti_type([ bench_type(name = SK_"setNormRandBoxBasic", exec = setNormRandBoxBasic, overhead = setOverhead, minsec = 0._RK, miniter = miniter) &
                            , bench_type(name = SK_"setNormRandBoxPolar", exec = setNormRandBoxPolar, overhead = setOverhead, minsec = 0._RK, miniter = miniter) &
                            , bench_type(name = SK_"setNormRandBoxPolarImpure", exec = setNormRandBoxPolarImpure, overhead = setOverhead, minsec = 0._RK, miniter = miniter) &
                           !, bench_type(name = SK_"getNormRandBox", exec = getNormRandBox, overhead = setOverhead, minsec = 0._RK, miniter = miniter) &
                            ], sorted = .true._LK, repeat = 1_IK)
 
    disp = display_type()
    call disp%show(bench%name, tmsize = 1_IK, bmsize = 1_IK)
    disp = display_type(file = "main.out")
 
    write(disp%unit, "(*(g0,:,','))") (bench%case(ibench)%name, ibench = 1, size(bench%case))
    do itime = 1, size(bench%case(1)%timing%values)
        call disp%show([(bench%case(ibench)%timing%values(itime), ibench = 1, size(bench%case))])
    end do
 
    write(*,"(*(g0,:,' '))") dummy
    write(*,"(*(g0,:,' '))")
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead()
        call initialize()
        call finalize()
    end subroutine
 
    subroutine initialize()
        call random_number(rand1)
        call random_number(rand2)
    end subroutine
 
    subroutine finalize()
        dummy = dummy + rand1 + rand2
    end subroutine
 
    subroutine setNormRandBoxBasic()
        use pm_distNorm, only: setNormRandBox
        call initialize()
        call setNormRandBox(rand1, rand2)
        call finalize()
    end subroutine
 
    subroutine setNormRandBoxPolar()
        use pm_distNorm, only: setNormRandBox
        logical(LK) :: failed
        call initialize()
        do
            call setNormRandBox(rand1, rand2, failed)
            if (.not. failed) exit
            call random_number(rand1)
            call random_number(rand2)
        end do
        call finalize()
    end subroutine
 
    !subroutine getNormRandBox()
    !    block
    !        use pm_distNorm, only: getNormRandBox
    !        rand1 = getNormRandBox(mean = 0._RKG)
    !        rand2 = getNormRandBox(mean = 0._RKG)
    !        call finalize()
    !    end block
    !end subroutine
 
    subroutine setNormRandBoxPolarImpure()
        use internal, only: setNormRandBox
        call setNormRandBox(rand1, rand2)
        call finalize()
    end subroutine
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
import os
dirname = os.path.basename(os.getcwd()) 
 
fontsize = 14
 
df = pd.read_csv("main.out", delimiter = ",")
colnames = list(df.columns.values)
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[:]:
    plt.hist( np.log10(df[colname].values)
            , histtype = "step"
            , linewidth = 2
            , alpha = .5
            , bins = 50
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Log10( Runtime [ seconds ] )", fontsize = fontsize)
ax.set_ylabel("Count", fontsize = fontsize)
ax.set_title(" vs. ".join(colnames[:])+"\nLower is better.", fontsize = fontsize)
#ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[:]
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.png")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.hist( np.log10(df[colname].values / df[colnames[0]].values)
            , histtype = "step"
            , linewidth = 2
            , alpha = .5
            , bins = 50
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Log10( Runtime Ratio compared to {} )".format(colnames[0]), fontsize = fontsize)
ax.set_ylabel("Count", fontsize = fontsize)
ax.set_title("Runtime Ratio Comparison. Lower means faster.\nLower than 0 means faster than {}().".format(colnames[0]), fontsize = fontsize)
#ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, bbox_to_anchor = (1, 0.5)
           #, loc = "center left"
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.ratio.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. The benchmark procedures named setNormRandBoxBasic and setNormRandBoxPolar call the generic interface setNormRandBox with the Basic and Polar (rejection sampling) implementations of the Box-Muller method, respectively.
   While both implementations are pure subroutines, the third benchmark implementation is setNormRandBoxPolarImpure is an impure implementation of the Polar method that internally that does not require passing uniform random numbers to the subroutine.
   
2. The benchmark results confirm the widespread community observation that the Polar implementation of the Box-Muller method (which uses rejection sampling) is slightly (by about 25%%) faster than the Basic implementation which involves two rather costly internal trigonometric function evaluations.
   

Test:

test_pm_distNorm

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 2866 of file pm_distNorm.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distNorm.F90