pm_clusKmeans::setCenter Interface Reference

Compute and return the centers of the clusters corresponding to the input sample, cluster membership IDs, and sample distances-squared from their corresponding cluster centers.
More...

Detailed Description

Compute and return the centers of the clusters corresponding to the input sample, cluster membership IDs, and sample distances-squared from their corresponding cluster centers.

This generic interface is the second step in the iterative process of refining a set of initial cluster centers toward a final set of clusters and their members.
As such, this generic interface is of little use with invoking setMember beforehand.
The metric used within this generic interface is the Euclidean distance.

Parameters

[in]	membership	: The input vector of shape (1:nsam) of type integer of default kind IK, containing the membership of each input sample in sample from its nearest cluster center, such that cluster(membership(i)) is the nearest cluster center to the ith sample sample(:, i) at a squared-distance of disq(i).
[in]	disq	: The input vector of shape (1:nsam) of the same type and kind as the input argument sample, containing the Euclidean squared distance of each input sample in sample from its nearest cluster center.
[in]	sample	: The input vector, or matrix of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the sample of nsam points in a ndim-dimensional space whose corresponding cluster centers must be computed. If sample is a vector of shape (1 : nsam) and center is a vector of shape (1 : ncls), then the input sample must be a collection of nsam points (in univariate space). If sample is a matrix of shape (1 : ndim, 1 : nsam) and center is a matrix of shape (1 : ndim, 1 : ncls), then the input sample must be a collection of nsam points (in ndim-dimensional space).
[out]	center	: The output vector of shape (1:ncls) or matrix of shape (1 : ndim, 1 : ncls) of the same type and kind as the input argument sample, containing the set of ncls cluster centers (centroids) computed based on the input sample memberships and minimum distances.
[out]	size	: The output vector of shape (1:ncls) type integer of default kind IK, containing the sizes (number of members) of the clusters with the corresponding centers output in the argument center.
[out]	potential	: The output vector of shape (1:ncls) of the same type and kind as the input argument sample, the ith element of which contains the sum of squared distances of all members of the ith cluster from the cluster center as output in the ith element of center.

Possible calling interfaces ⛓

use pm_clusKmeans, only: setCenter
 
call setCenter(sample(1 : nsam)             , membership(1 : nsam)  , disq(1 : nsam), center(1 : ncls)          , size(1 : ncls), potential(1 : ncls))
call setCenter(sample(1 : ndim, 1 : nsam)   , membership(1 : nsam)  , disq(1 : nsam), center(1 : ndim, 1 : ncls), size(1 : ncls), potential(1 : ncls))

Warning

The condition ubound(center, rank(center)) > 0 must hold for the corresponding input arguments.
The condition ubound(sample, rank(sample)) == ubound(disq, 1) must hold for the corresponding input arguments.
The condition ubound(center, rank(center)) == ubound(size, 1) must hold for the corresponding input arguments.
The condition ubound(center, rank(center)) == ubound(potential, 1) must hold for the corresponding input arguments.
The condition ubound(sample, rank(sample)) == ubound(membership, 1) must hold for the corresponding input arguments.
The condition ubound(sample, 1) == ubound(center, 1) .or. (rank(sample) == 1 .and. rank(center) == 1) must hold for the corresponding input arguments.
The condition all(0 < membership .and. membership <= ubound(center, rank(center))) must hold for the corresponding input arguments.
The condition all(0 <= disq) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

This generic interface implements one of the two major steps involved in Kmeans clustering.

See also

setKmeans
setCenter
setMember
setKmeansPP

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_kind, only: RKG => RKS ! all other real kinds are also supported.
    use pm_io, only: display_type
    use pm_distUnif, only: getUnifRand
    use pm_arrayResize, only: setResized
    use pm_clusKmeans, only: setCenter
    use pm_clusKmeans, only: setMember
 
    implicit none
 
    integer(IK) :: ndim, nsam, ncls
    real(RKG)   , allocatable  :: sample(:,:), center(:,:), disq(:), potential(:)
    integer(IK) , allocatable  :: membership(:), size(:)
    type(display_type) :: disp
 
    disp = display_type(file = "main.out.F90")
 
    call disp%skip
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute cluster centers based on an input sample and cluster memberships and member-center distances.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip
 
    call disp%skip()
    call disp%show("ndim = getUnifRand(1, 5); nsam = getUnifRand(1, 5); ncls = getUnifRand(1, 5);")
                    ndim = getUnifRand(1, 5); nsam = getUnifRand(1, 5); ncls = getUnifRand(1, 5);
    call disp%show("[ndim, nsam, ncls]")
    call disp%show( [ndim, nsam, ncls] )
    call disp%show("center = getUnifRand(0., 5., ndim, ncls) ! initialize random centers.")
                    center = getUnifRand(0., 5., ndim, ncls) ! initialize random centers.
    call disp%show("center")
    call disp%show( center )
    call disp%show("sample = getUnifRand(0., 5., ndim, nsam) ! Create a random sample.")
                    sample = getUnifRand(0., 5., ndim, nsam) ! Create a random sample.
    call disp%show("sample")
    call disp%show( sample )
    call disp%show("call setResized(disq, nsam)")
                    call setResized(disq, nsam)
    call disp%show("call setResized(membership, nsam)")
                    call setResized(membership, nsam)
    call disp%show("call setResized(potential, ncls)")
                    call setResized(potential, ncls)
    call disp%show("call setResized(size, ncls)")
                    call setResized(size, ncls)
    call disp%show("call setMember(membership, disq, sample, center) ! get sample points memberships.")
                    call setMember(membership, disq, sample, center) ! get sample points memberships.
    call disp%skip()
 
    call disp%show("call setCenter(membership, disq, sample, center, size, potential) ! now compute the new clusters.")
                    call setCenter(membership, disq, sample, center, size, potential) ! now compute the new clusters.
    call disp%show("size")
    call disp%show( size )
    call disp%show("center")
    call disp%show( center )
    call disp%show("potential")
    call disp%show( potential )
    call disp%skip()
 
    call disp%show("call setCenter(membership, disq, sample(1,:), center(1,:), size, potential) ! sample points memberships in one-dimension.")
                    call setCenter(membership, disq, sample(1,:), center(1,:), size, potential) ! sample points memberships in one-dimension.
    call disp%show("size")
    call disp%show( size )
    call disp%show("center(1,:)")
    call disp%show( center(1,:) )
    call disp%show("potential")
    call disp%show( potential )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        integer(IK) :: funit, i
        ndim = 2
        ncls = 5
        nsam = 5000
        center = getUnifRand(0., 1., ndim, ncls)
        sample = getUnifRand(0., 1., ndim, nsam)
        call setResized(disq, nsam)
        call setResized(membership, nsam)
        call setResized(potential, ncls)
        call setResized(size, ncls)
        ! output the sample and the initial centers.
        call setMember(membership, disq, sample, center)
        open(newunit = funit, file = "setMember.center.txt")
            do i = 1, ncls
                write(funit, "(*(g0,:,','))") i, center(:,i)
            end do
        close(funit)
        open(newunit = funit, file = "setMember.sample.txt")
            do i = 1, nsam
                write(funit, "(*(g0,:,','))") membership(i), sample(:,i)
            end do
        close(funit)
        call setCenter(membership, disq, sample, center, size, potential)
        open(newunit = funit, file = "setCenter.center.txt")
            do i = 1, ncls
                write(funit, "(*(g0,:,','))") i, center(:,i)
            end do
        close(funit)
        open(newunit = funit, file = "setCenter.sample.txt")
            do i = 1, nsam
                write(funit, "(*(g0,:,','))") membership(i), sample(:,i)
            end do
        close(funit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute cluster centers based on an input sample and cluster memberships and member-center distances.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
ndim = getUnifRand(1, 5); nsam = getUnifRand(1, 5); ncls = getUnifRand(1, 5);
[ndim, nsam, ncls]
+1, +3, +1
center = getUnifRand(0., 5., ndim, ncls) ! initialize random centers.
center
+1.28157318
sample = getUnifRand(0., 5., ndim, nsam) ! Create a random sample.
sample
+3.64694548, +1.80137849, +2.11540985
call setResized(disq, nsam)
call setResized(membership, nsam)
call setResized(potential, ncls)
call setResized(size, ncls)
call setMember(membership, disq, sample, center) ! get sample points memberships.
 
call setCenter(membership, disq, sample, center, size, potential) ! now compute the new clusters.
size
+3
center
+2.52124476
potential
+6.56046629
 
call setCenter(membership, disq, sample(1,:), center(1,:), size, potential) ! sample points memberships in one-dimension.
size
+3
center(1,:)
+2.52124476
potential
+6.56046629
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
 
fontsize = 17
 
prefixes =  { "setMember" : "Memberships based on initial centers."
            , "setCenter" : "Inferred new centers based on memberships."
            }
for prefix in list(prefixes.keys()):
 
    legends = []
    fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
    ax = plt.subplot()
 
    fileList = glob.glob(prefix + "*.txt")
    if len(fileList) == 2:
        for file in fileList:
 
            kind = file.split(".")[1]
            df = pd.read_csv(file, delimiter = ",", header = None)
 
            if kind == "center":
                ax.scatter  ( df.values[:, 1]
                            , df.values[:,2]
                            , zorder = 100
                            , marker = "*"
                            , c = "red"
                            , s = 50
                            )
                legends.append("center")
            elif kind == "sample":
                ax.scatter  ( df.values[:, 1]
                            , df.values[:,2]
                            , c = df.values[:, 0]
                            , s = 10
                            )
                legends.append("sample")
            else:
                sys.exit("Ambiguous file exists: {}".format(file))
 
        ax.legend(legends, fontsize = fontsize)
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel("X", fontsize = 17)
        ax.set_ylabel("Y", fontsize = 17)
        ax.set_title(prefixes[prefix], fontsize = fontsize)
 
        plt.axis('equal')
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
        ax.set_axisbelow(True)
        plt.tight_layout()
 
        plt.savefig(prefix + ".png")
    else:
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_clusKmeans

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, September 1, 2012, 12:00 AM, National Institute for Fusion Studies, The University of Texas Austin

Definition at line 904 of file pm_clusKmeans.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_clusKmeans.F90