pm_bench::benchBase_typer Interface Reference

Construct and return an object of type benchBase_type. More...

Detailed Description

Construct and return an object of type benchBase_type.

This is the constructor of the type benchBase_type for creating objects that facilitate the benchmarking of arbitrary procedures.

Parameters

[in]	name	: The input scalar character of arbitrary length of default kind SK, containing the benchmark name (typically the name of the procedure to be timed).
[in]	minsec	: The input scalar of type real of kind double precision RKD representing the minimum time in units of seconds that the overall benchmark should last. (optional, default = 0.05 seconds)
[in]	miniter	: The input scalar of type integer of default kind IK representing the minimum number of timing the user-specified wrapper procedure repeatedly. (optional, default = 1)
[in]	timer	: The input object of abstract class timer_type representing the benchmark timer. This object can be one of the available timers in pm_timer: timerCPU_type, timerDAT_type, timerMPI_type, timerOMP_type, timerSYS_type, or any other user-defined subclass of the abstract timer_type class. (optional, default = timer_type)

Returns

benchBase : The output scalar object of type benchBase_type.

Possible calling interfaces ⛓

use pm_kind, only: SK, IK, RKD
use pm_bench, only: benchBase_type
use pm_timer, only: timer_type
use pm_timer, only: timerCPU_type
use pm_timer, only: timerDAT_type
use pm_timer, only: timerMPI_type
use pm_timer, only: timerOMP_type
use pm_timer, only: timerSYS_type
type(benchBase_type) :: benchBase
character(:, SK) :: name
integer(IK) :: miniter
real(RKD) :: minsec
 
benchBase = benchBase_type(name, minsec = minsec, miniter = miniter, timer = timer_type())
benchBase = benchBase_type(name, minsec = minsec, miniter = miniter, timer = timerCPU_type())
benchBase = benchBase_type(name, minsec = minsec, miniter = miniter, timer = timerDAT_type())
benchBase = benchBase_type(name, minsec = minsec, miniter = miniter, timer = timerMPI_type())
benchBase = benchBase_type(name, minsec = minsec, miniter = miniter, timer = timerOMP_type())
benchBase = benchBase_type(name, minsec = minsec, miniter = miniter, timer = timerSYS_type())

Remarks

See also benchBase_type for possible calling interfaces.

Note that the timing of the user-specified procedure wrapper is performed until both conditions related to minsec and miniter are satisfied.
In other words, the timing is performed for at least minsec seconds and at least miniter number of iterations.
The default values for these two variables are are set so that the benchmark typically ends within 50 ms, unless the runtime of the user-specified procedure is longer than 50 ms.

Note

If the specified benchmark routine is to be called certain number of times, set minsec = 0. and miniter to desired number of times the routine must be timed.

See also

benchBase_type
timerDAT_type
timerMPI_type
timerOMP_type
timerSYS_type
timer_type

Example usage ⛓

program example
 
    use pm_kind, only: IK, LK, SK, RKD
    use pm_io, only: display_type
    use pm_bench, only: benchBase_type
    use pm_timer, only: timerCPU_type
    use pm_timer, only: timerDAT_type
    use pm_timer, only: timerSYS_type
 
    implicit none
 
    type(benchBase_type) :: benchBase
    real(RKD)           :: unifrnd
    real(RKD)           :: sumTime = 0._RKD
    real(RKD)           :: sumUnif = 0._RKD
    integer             :: i
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("benchBase = benchBase_type(name = SK_'random_number')")
                    benchBase = benchBase_type(name = SK_'random_number')
    call showTimerComponents()
    call disp%skip()
 
    call disp%skip()
    call disp%show("allocate(benchBase%timing%values(1000))")
    call disp%show("do i = 1, 1000")
    call disp%show("    benchBase%timer%start = benchBase%timer%time()")
    call disp%show("    call random_number(unifrnd)")
    call disp%show("    benchBase%timing%values(i) = benchBase%timer%time(since = benchBase%timer%start)")
    call disp%show("    sumTime = sumTime + benchBase%timing%values(i)")
    call disp%show("    if (sumTime > benchBase%minsec) exit")
    call disp%show("    sumUnif = sumUnif + unifrnd")
    call disp%show("end do")
                    allocate(benchBase%timing%values(1000))
                    do i = 1, 1000
                        benchBase%timer%start = benchBase%timer%time()
                        call random_number(unifrnd)
                        benchBase%timing%values(i) = benchBase%timer%time(since = benchBase%timer%start)
                        sumTime = sumTime + benchBase%timing%values(i)
                        if (sumTime > benchBase%minsec) exit
                        sumUnif = sumUnif + unifrnd
                    end do
    call disp%show("sum(benchBase%timing%values) / size(benchBase%timing%values)")
    call disp%show( sum(benchBase%timing%values) / size(benchBase%timing%values) )
    call disp%skip()
 
contains
 
    impure subroutine showTimerComponents()
        call disp%show("benchBase%name")
        call disp%show( benchBase%name , deliml = SK_"""" )
        call disp%show("benchBase%minsec")
        call disp%show( benchBase%minsec )
        call disp%show("benchBase%miniter")
        call disp%show( benchBase%miniter )
    end subroutine
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
benchBase = benchBase_type(name = SK_'random_number')
benchBase%name
"random_number"
benchBase%minsec
+0.50000000000000003E-1
benchBase%miniter
+1
 
 
allocate(benchBase%timing%values(1000))
do i = 1, 1000
    benchBase%timer%start = benchBase%timer%time()
    call random_number(unifrnd)
    benchBase%timing%values(i) = benchBase%timer%time(since = benchBase%timer%start)
    sumTime = sumTime + benchBase%timing%values(i)
    if (sumTime > benchBase%minsec) exit
    sumUnif = sumUnif + unifrnd
end do
sum(benchBase%timing%values) / size(benchBase%timing%values)
+0.27419533580541612E-7
 
 

Test:

test_pm_bench

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Wednesday 4:13 AM, August 13, 2016, Institute for Computational Engineering and Sciences (ICES), The University of Texas at Austin

Definition at line 308 of file pm_bench.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_bench.F90