pm_mathLogSubExp::getLogSubExp Interface Reference

Generate and return the natural logarithm of the subtraction of the exponential of the smaller input logarithmic value from the larger input logarithmic value robustly (without causing overflow). More...

Detailed Description

Generate and return the natural logarithm of the subtraction of the exponential of the smaller input logarithmic value from the larger input logarithmic value robustly (without causing overflow).

Parameters

[in]	smaller	: The input scalar, or array of the same rank, shape, and size as other array-like input arguments, of either type complex of kind any supported by the processor (e.g., CK, CK32, CK64, or CK128), or type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), representing the smaller of the two logarithmic values to be added. If it is complex, then the real component of the complex value must be smaller than the real component of the (larger) complex value. (optional, it must be present if and only if the input argument larger is also present.)
[in]	larger	: The input scalar, or array of the same rank, shape, and size as other array-like input arguments, of the same type and kind as the input argument smaller, representing the larger of the two logarithmic values to be added. If it is complex, then the real component of the complex value must be larger than the real component of the (larger) complex value. (optional, it must be present if and only if the input argument smaller is also present.)
[in]	minMax	: The input vector of length 2 of either type complex of kind any supported by the processor (e.g., CK, CK32, CK64, or CK128) or, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), representing the smaller and the larger of the two logarithmic values to be added as minMax(1) and minMax(2). If it is complex, then the real component of the complex value must be smaller than the real component of the (larger) complex value. If the smaller and larger values are not known a priori, the vector minMax can be instead constructed by calling getMinMax. (optional, it must be present if and only if the input arguments smaller and larger are missing.)
	control	: The input scalar object that can be, the constant selection or equivalently, an object of type selection_type. Specifying this option enables the runtime checks for underflow occurrence via branching and dynamic dispatch. Enabling this option can aid runtime efficiency when the smaller to larger ratio is expected to cause underflow. In such cases, the exponentiation is avoided if control = selection, leading to faster runtime by avoiding exponentiation since it is highly expensive (on the order of ~200 CPU cycles). See the relevant benchmark here. The presence of this argument is merely for compile-time resolution of the procedures of this generic interface. (optional. If missing, a sequence control flow will be assumed without dynamic dispatch.)

Returns

logSubExp : The output scalar of the same type and kind as the input larger and smaller containing the natural logarithm of the subtraction of the exponential of the larger input logarithmic value from the smaller input logarithmic value, computed robustly.

Possible calling interfaces ⛓

use pm_mathLogSubExp, only: getLogSubExp
 
logSubExp = getLogSubExp(smaller, larger)
logSubExp = getLogSubExp(smaller, larger, control)
logSubExp = getLogSubExp(minMax(1:2))
logSubExp = getLogSubExp(minMax(1:2), control)
!

Warning

As the argument names suggest, the value of the input argument larger must be larger than or equal to the value of the input argument smaller.
When the input arguments are of type complex, this condition must hold for the real components of the numbers.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under this generic interface are elemental when the input arguments smaller and larger are present.

Note

The smaller and larger input values can be quickly obtained by a one-line call to setMinMax.
Alternatively, the smaller and larger values can be sorted in a minMax(1:2) array by calling getMinMax and passing the result directly to getLogSubExp.

See also

getLog1p
get1mexp
getMinMax
setMinMax
getLogAddExp
getLogSubExp
getLogSumExp

Example usage ⛓

program example
 
    use pm_kind, only: SK
    use pm_io, only: display_type
    use pm_kind, only: IK, CKS, CKD, CKH, RKS, RKD, RKH
    use pm_mathLogSubExp, only: getLogSubExp
    use pm_mathMinMax, only: getMinMax
    use pm_distUnif, only: getUnifRand
 
    implicit none
 
    type(display_type) :: disp
 
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%")
    call disp%show("!32-bit real")
    call disp%show("!%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp( getLogSubExp(smaller = log(4._RKS), larger = log(10._RKS)) )")
    call disp%show( exp( getLogSubExp(smaller = log(4._RKS), larger = log(10._RKS)) ) )
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%")
    call disp%show("!64-bit real")
    call disp%show("!%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp( getLogSubExp(smaller = log(4._RKD), larger = log(10._RKD)) )")
    call disp%show( exp( getLogSubExp(smaller = log(4._RKD), larger = log(10._RKD)) ) )
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%")
    call disp%show("!128-bit real")
    call disp%show("!%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp( getLogSubExp(smaller = log(4._RKH), larger = log(10._RKH)) )")
    call disp%show( exp( getLogSubExp(smaller = log(4._RKH), larger = log(10._RKH)) ) )
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%")
    call disp%show("!32-bit complex")
    call disp%show("!%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp( getLogSubExp(smaller = log((4._CKS, -4._CKS)), larger = log((10._CKS, -10._CKS))) )")
    call disp%show( exp( getLogSubExp(smaller = log((4._CKS, -4._CKS)), larger = log((10._CKS, -10._CKS))) ) )
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%")
    call disp%show("!64-bit complex")
    call disp%show("!%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp( getLogSubExp(smaller = log((4._CKD, -4._CKD)), larger = log((10._CKD, -10._CKD))) )")
    call disp%show( exp( getLogSubExp(smaller = log((4._CKD, -4._CKD)), larger = log((10._CKD, -10._CKD))) ) )
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%")
    call disp%show("!128-bit complex")
    call disp%show("!%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp( getLogSubExp(smaller = log((4._CKH, -4._CKH)), larger = log((10._CKH, -10._CKH))) )")
    call disp%show( exp( getLogSubExp(smaller = log((4._CKH, -4._CKH)), larger = log((10._CKH, -10._CKH))) ) )
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("!Input arguments as a vector of [minimum, maximum] by calling getMinMax()")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%show("exp(getLogSubExp(getMinMax(getUnifRand(-1., 1., 2_IK))))")
    call disp%show( exp(getLogSubExp(getMinMax(getUnifRand(-1., 1., 2_IK)))) )
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%
!32-bit real
!%%%%%%%%%%%
 
exp( getLogSubExp(smaller = log(4._RKS), larger = log(10._RKS)) )
+6.00000000
 
!%%%%%%%%%%%
!64-bit real
!%%%%%%%%%%%
 
exp( getLogSubExp(smaller = log(4._RKD), larger = log(10._RKD)) )
+6.0000000000000027
 
!%%%%%%%%%%%%
!128-bit real
!%%%%%%%%%%%%
 
exp( getLogSubExp(smaller = log(4._RKH), larger = log(10._RKH)) )
+5.99999999999999999999999999999999923
 
!%%%%%%%%%%%%%%
!32-bit complex
!%%%%%%%%%%%%%%
 
exp( getLogSubExp(smaller = log((4._CKS, -4._CKS)), larger = log((10._CKS, -10._CKS))) )
(+6.00000048, -6.00000048)
 
!%%%%%%%%%%%%%%
!64-bit complex
!%%%%%%%%%%%%%%
 
exp( getLogSubExp(smaller = log((4._CKD, -4._CKD)), larger = log((10._CKD, -10._CKD))) )
(+5.9999999999999973, -5.9999999999999964)
 
!%%%%%%%%%%%%%%%
!128-bit complex
!%%%%%%%%%%%%%%%
 
exp( getLogSubExp(smaller = log((4._CKH, -4._CKH)), larger = log((10._CKH, -10._CKH))) )
(+6.00000000000000000000000000000000000, -5.99999999999999999999999999999999923)
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
!Input arguments as a vector of [minimum, maximum] by calling getMinMax()
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
exp(getLogSubExp(getMinMax(getUnifRand(-1., 1., 2_IK))))
+0.305024594
 

Benchmarks:

Benchmark :: The effects of the control argument on runtime efficiency ⛓

The following program compares the runtime performance of getLogSubExp algorithm with and without checking for underflows.

! Test the performance of `getLogSubExp()` with and without the `control` argument.
program benchmark
 
    use iso_fortran_env, only: error_unit
    use pm_bench, only: bench_type
    use pm_kind, only: IK, LK, RK, SK
 
    implicit none
 
    integer(IK)                         :: i
    integer(IK)                         :: iarr
    integer(IK)                         :: fileUnitN
    integer(IK)                         :: fileUnitU
    integer(IK) , parameter             :: NARR = 11_IK
    integer(IK) , parameter             :: NBENCH = 2_IK
    integer(IK)                         :: arraySize(NARR)
    real(RK)                            :: dummySum = 0._RK
    real(RK)                            :: maxArray
    real(RK)    , allocatable           :: Larger(:)
    real(RK)    , allocatable           :: Smaller(:)
    real(RK)    , allocatable           :: LogSubExp(:)
    type(bench_type)                    :: bench(2,NBENCH)
    logical(LK)                         :: underflowEnabled
 
    bench(1:2,1) = bench_type(name = SK_"getLogSubExpSequence ", exec = getLogSubExpSequence , overhead = setOverhead)
    bench(1:2,2) = bench_type(name = SK_"getLogSubExpSelection ", exec = getLogSubExpSelection , overhead = setOverhead)
 
    arraySize = [( 2_IK**iarr, iarr = 1_IK, NARR )]
 
    write(*,"(*(g0,:,' '))")
    write(*,"(*(g0,:,' '))") "getLogSubExp(...) vs. getLogSubExp(..., control) vs. direct method."
    write(*,"(*(g0,:,' '))")
 
    open(newunit = fileUnitN, file = "main.normal.out", status = "replace")
    open(newunit = fileUnitU, file = "main.underflow.out", status = "replace")
 
        write(fileUnitN, "(*(g0,:,','))") "arraySize", (bench(1,i)%name, i = 1, NBENCH)
        write(fileUnitU, "(*(g0,:,','))") "arraySize", (bench(2,i)%name, i = 1, NBENCH)
 
        loopOverArraySize: do iarr = 1, NARR
 
            allocate(Larger(arraySize(iarr)))
            allocate(Smaller(arraySize(iarr)))
            allocate(LogSubExp(arraySize(iarr)))
            write(*,"(*(g0,:,' '))") "Benchmarking with array size", arraySize(iarr)
 
            underflowEnabled = .false._LK
            do i = 1, NBENCH
                bench(1,i)%timing = bench(1,i)%getTiming(minsec = 0.07_RK)
            end do
            write(fileUnitN,"(*(g0,:,','))") arraySize(iarr), (bench(1,i)%timing%mean, i = 1, NBENCH)
 
            underflowEnabled = .true._LK
            do i = 1, NBENCH
                bench(2,i)%timing = bench(2,i)%getTiming(minsec = 0.07_RK)
            end do
            write(fileUnitU,"(*(g0,:,','))") arraySize(iarr), (bench(2,i)%timing%mean, i = 1, NBENCH)
 
            deallocate(LogSubExp, Smaller, Larger)
 
        end do loopOverArraySize
        write(*,"(*(g0,:,' '))") dummySum
        write(*,"(*(g0,:,' '))")
 
    close(fileUnitN)
    close(fileUnitU)
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead()
        call setArray()
        call getDummy()
    end subroutine
 
    subroutine setArray()
        use pm_mathMinMax, only: setMinMax
        call random_number(Larger)
        call random_number(Smaller)
        if (underflowEnabled) then
            Larger = Larger * (maxexponent(0._RK) - minexponent(0._RK)) + minexponent(0._RK)
            Smaller = Smaller * (maxexponent(0._RK) - minexponent(0._RK)) + minexponent(0._RK)
        end if
        call setMinMax(Smaller, Larger)
    end subroutine
 
    subroutine getDummy()
        dummySum = dummySum + LogSubExp(1)
    end subroutine
 
    subroutine getLogSubExpSequence()
        use pm_mathLogSubExp, only: getLogSubExp
        call setArray()
        LogSubExp(:) = getLogSubExp(Smaller, Larger)
        call getDummy()
    end subroutine
 
    subroutine getLogSubExpSelection()
        use pm_mathLogSubExp, only: getLogSubExp, selection
        call setArray()
        LogSubExp(:) = getLogSubExp(Smaller, Larger, selection)
        call getDummy()
    end subroutine
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
import os
dirname = os.path.basename(os.getcwd()) 
 
fontsize = 14
 
 
 
df = pd.read_csv("main.normal.out")
colnames = list(df.columns.values)
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.plot( df[colnames[0]].values
           #, np.ones(len(df[colnames[0]].values))
            , df[colname].values / df[colnames[1]].values
            , linewidth = 2
           #, linestyle = "-"
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Array Size", fontsize = fontsize)
ax.set_ylabel("Runtime Ratio ( W.R.T. cenabled = .false. )", fontsize = fontsize)
ax.set_title("Performance when the input arrays\ncause no underflow instances.\nLower is better.", fontsize = fontsize)
ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".normal.png")
 
 
 
df = pd.read_csv("main.underflow.out")
colnames = list(df.columns.values)
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.plot( df[colnames[0]].values
           #, np.ones(len(df[colnames[0]].values))
            , df[colname].values / df[colnames[1]].values
            , linewidth = 2
           #, linestyle = "-"
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Array Size", fontsize = fontsize)
ax.set_ylabel("Runtime Ratio W.R.T. {})".format(colnames[1]), fontsize = fontsize)
ax.set_title("Performance when the input arrays\ncause many underflow instances.\nLower is better.", fontsize = fontsize)
ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".underflow.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. If the ratio of the smaller to larger input arguments causes frequent underflows, then setting control = selection to allow branching will likely result in a faster runtime.
   Conversely, if the divisions are not expected to cause any or too many underflows, then removing the input argument control when calling getLogSubExp will lead to a better runtime performance (at the expense of occasional expensive but redundant exponentiation operations).
   
2. If the procedure getLogSubExp is to be called billions of times, then it would make sense to manually inline the procedure implementation in your code as procedure call and processing of optional arguments will have a non-negligible performance overhead.
   

Test:

test_pm_mathLogSubExp

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Thursday 1:45 AM, August 22, 2019, Dallas, TX

Definition at line 166 of file pm_mathLogSubExp.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_mathLogSubExp.F90