pm_mathBeta::getBetaInc Interface Reference

Generate and return the regularized Incomplete Beta Function \(I_x(\alpha, \beta)\) as defined in the details section of pm_mathBeta. More...

Detailed Description

Generate and return the regularized Incomplete Beta Function \(I_x(\alpha, \beta)\) as defined in the details section of pm_mathBeta.

Parameters

[in]	x	: The input scalar (or array of the same shape as other array-like arguments) of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128).
[in]	alpha	: The input scalar (or array of the same shape as other array-like arguments) of the same type and kind as x.
[in]	beta	: The input scalar (or array of the same shape as other array-like arguments) of the same type and kind as x.
[in]	signed	: The input scalar (or array of the same shape as other array-like arguments) of type logical of default kind LK. If signed = .false., the input x must be in range 0 <= x <= 1 and the output betaInc will be the expected incomplete Beta function in range 0 <= betaInc <= 1. If signed = .true., then the following rules hold: If the condition x < 0 holds, then the value x = 1 - x < 0 will be used instead of x. If the output betaInc is near 1, the output will be returned as betaInc = betaInc - 1 < 0 instead of betaInc. Therefore, the user is expected to be aware of the convention and apply the necessary correction (addition by 1) before using the output value. Specifying signed = .true. can lead to considerably more accurate calculations (by orders of magnitudes) for values of x and betaInc that are near 1. The loss of precision near 1 occurs because of inadequate resolution of real number representations in digital computers near 1 which is orders of magnitude worse than the precision near 0. (optional, default = .false., following the principle of least surprise.)

Returns

betaInc : The output object of the same type, kind, and rank as highest-rank input argument containing the regularized Incomplete Beta Function.

Possible calling interfaces ⛓

use pm_mathBeta, only: getBetaInc
 
betaInc = getBetaInc(x, alpha, beta, signed = signed)

Warning

The conditions 0 <= x .and. .not. signed .or. 0 <= x must hold for the corresponding input arguments.
The conditions 0 < alpha .and. 0 < beta must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The procedures under this generic interface will abort the program if the computation of the continued fraction representation of the regularized beta function fails to converge.
If error control is necessary, use the generic interface seBetaInc.

Remarks

The procedures under discussion are impure.

The procedures under discussion are elemental.

See also

getLogBeta
getBetaInc
getBetaLogPDF

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_kind, only: RK ! all processor kinds are supported.
    use pm_io, only: display_type
    use pm_mathBeta, only: getBetaInc
 
    implicit none
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute the regularized (lower) Incomplete Beta Function using its series representation.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("getBetaInc(x = 0._RK, alpha = 2._RK, beta = 3._RK)")
    call disp%show( getBetaInc(x = 0._RK, alpha = 2._RK, beta = 3._RK) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("getBetaInc(x = .5_RK, alpha = 2._RK, beta = 3._RK) ! 0.6875")
    call disp%show( getBetaInc(x = .5_RK, alpha = 2._RK, beta = 3._RK) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("getBetaInc(x = 1._RK, alpha = 2._RK, beta = 3._RK)")
    call disp%show( getBetaInc(x = 1._RK, alpha = 2._RK, beta = 3._RK) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute the regularized (lower) Incomplete Beta Function for a vector of points.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("getBetaInc(x = [0._RK, 0.5_RK, 1._RK], alpha = 2._RK, beta = 3._RK)")
    call disp%show( getBetaInc(x = [0._RK, 0.5_RK, 1._RK], alpha = 2._RK, beta = 3._RK) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute the regularized Incomplete Beta Function for a vector of input parameters.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("getBetaInc(x = [0._RK, 0.5_RK, 1._RK], alpha = [0.1_RK, 1._RK, 10._RK], beta = 3._RK) ! 0, 0.875, 1")
    call disp%show( getBetaInc(x = [0._RK, 0.5_RK, 1._RK], alpha = [0.1_RK, 1._RK, 10._RK], beta = 3._RK) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array of the regularized Incomplete Beta function for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    !block
    !    use pm_arraySpace, only: setLinSpace
    !    integer(IK) , parameter :: nx = 1000_IK
    !    real(RK) :: x(nx)
    !    integer :: fileUnit, i
    !    call setLinSpace(x, 0._RK, 1._RK)
    !    open(newunit = fileUnit, file = "getBetaInc.RK.txt")
    !    do i = 1, nx
    !        write(fileUnit, "(*(g0,:,' '))") x_RK(i), getBetaInc(x(i), 5._RK, [1.0_RK, 5.0_RK, 10._RK])
    !    end do
    !    close(fileUnit)
    !end block
 
    block
        use pm_kind, only: RKG => RKH, RKH
        use pm_arraySpace, only: setLinSpace
        integer(IK) , parameter :: nx = 1000
        real(RKG)   , parameter :: alpha(*) = [0.1_RKG, 10._RKG, 1._RKG, 0.1_RKG, 10._RKG], beta(*) = [0.1_RKG, 0.1_RKG, 1._RKG, 10._RKG, 10._RKG]
        real(RKG)   :: betaInc(max(size(alpha), size(beta)))
        real(RKG)   :: x(nx)
        integer     :: fileUnit, i
        call setLinSpace(x, 0._RKG, 1._RKG, fopen = .true._LK, lopen = .true._LK)
        open(newunit = fileUnit, file = "getBetaInc.RK.txt")
        do i = 1, nx
            betaInc = getBetaInc(x(i), alpha, beta)
            write(fileUnit, "(*(g0,:,','))") x(i), merge(1 + betaInc, betaInc, betaInc < 0)
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute the regularized (lower) Incomplete Beta Function using its series representation.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
getBetaInc(x = 0._RK, alpha = 2._RK, beta = 3._RK)
+0.0000000000000000
 
 
getBetaInc(x = .5_RK, alpha = 2._RK, beta = 3._RK) ! 0.6875
+0.68750000000000000
 
 
getBetaInc(x = 1._RK, alpha = 2._RK, beta = 3._RK)
+1.0000000000000000
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute the regularized (lower) Incomplete Beta Function for a vector of points.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
getBetaInc(x = [0._RK, 0.5_RK, 1._RK], alpha = 2._RK, beta = 3._RK)
+0.0000000000000000, +0.68750000000000000, +1.0000000000000000
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute the regularized Incomplete Beta Function for a vector of input parameters.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
getBetaInc(x = [0._RK, 0.5_RK, 1._RK], alpha = [0.1_RK, 1._RK, 10._RK], beta = 3._RK) ! 0, 0.875, 1
+0.0000000000000000, +0.87500000000000000, +1.0000000000000000
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
fontsize = 17
 
kind = "RK"
#label = [ r"$\alpha, \beta = 5., 1.0$"
#        , r"$\alpha, \beta = 5., 5.0$"
#        , r"$\alpha, \beta = 5., 10.$"
#        ]
label = [ r"$\alpha, \beta = .1, .1$"
        , r"$\alpha, \beta = 10, .1$"
        , r"$\alpha, \beta = 1., 1.$"
        , r"$\alpha, \beta = .1, 10$"
        , r"$\alpha, \beta = 10, 10$"
        ]
 
pattern = "*." + kind + ".txt"
fileList = glob.glob(pattern)
if len(fileList) == 1:
 
    df = pd.read_csv(fileList[0], delimiter = ",")
 
    fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
    ax = plt.subplot()
 
    for i in range(1,len(df.values[0,:]+1)):
 
            plt.plot( df.values[:, 0]
                    , df.values[:,i]
                    , linewidth = 2
                    )
 
    plt.xticks(fontsize = fontsize - 2)
    plt.yticks(fontsize = fontsize - 2)
    ax.set_xlabel("x", fontsize = fontsize)
    ax.set_ylabel("Regularized Lower\nIncomplete Beta Function", fontsize = fontsize)
    #ax.set_xscale("log")
    #ax.set_yscale("log")
 
    plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
    ax.tick_params(axis = "y", which = "minor")
    ax.tick_params(axis = "x", which = "minor")
 
    ax.legend   ( label
                , fontsize = fontsize
               #, loc = "center left"
               #, bbox_to_anchor = (1, 0.5)
                )
 
    plt.savefig(fileList[0].replace(".txt",".png"))
 
else:
 
    sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_mathBeta

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 280 of file pm_mathBeta.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_mathBeta.F90