pm_ellipsoid::setLogVolUnitBall Interface Reference

Return the natural logarithm of the volume of an \(\ndim\)-dimensional ball of unit-radius. More...

Detailed Description

Return the natural logarithm of the volume of an \(\ndim\)-dimensional ball of unit-radius.

The computation of the volume of an n-ball requires involves factorials which are computed in the procedures of this generic interface via the Fortran intrinsic log_gamma().
This generic subroutine interface is an exact functional-interface replacement for the generic functional interface getLogVolUnitBall.

Parameters

[out]	logVolUnitBall	: The output scalar (or array of the same rank as other input array-like arguments) of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing natural logarithm of the volume of the unit-radius hyper-ball.
[in]	ndim	: The input scalar containing the number of dimensions of the unit-radius hyper-ball. It can be, of type integer of default kind IK, in which case the output will be computed using an iterative factorial algorithm, or of the same type and kind as the output logVolUnitBall, in which case the output will be computed using the Fortran intrinsic log_gamma().

Possible calling interfaces ⛓

use pm_ellipsoid, only: setLogVolUnitBall
 
call setLogVolUnitBall(logVolUnitBall, ndim)

Warning

The condition 0 <= ndim must hold for the corresponding input arguments.
This condition is verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getLogVolUnitBall
Volume of an n-ball
Particular values of the Gamma function

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK, RKG => RKH
    use pm_io, only: display_type
    use pm_ellipsoid, only: setLogVolUnitBall
 
    implicit none
 
    real(RKG) :: logVolUnitBall(5)
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("call setLogVolUnitBall(logVolUnitBall(1), ndim = 2_IK)")
                    call setLogVolUnitBall(logVolUnitBall(1), ndim = 2_IK)
    call disp%show("logVolUnitBall(1)")
    call disp%show( logVolUnitBall(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setLogVolUnitBall(logVolUnitBall(1), ndim = 2._RKG)")
                    call setLogVolUnitBall(logVolUnitBall(1), ndim = 2._RKG)
    call disp%show("logVolUnitBall(1)")
    call disp%show( logVolUnitBall(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setLogVolUnitBall(logVolUnitBall(1:5), ndim = [integer(IK) :: 0, 1, 2, 3, 4])")
                    call setLogVolUnitBall(logVolUnitBall(1:5), ndim = [integer(IK) :: 0, 1, 2, 3, 4])
    call disp%show("logVolUnitBall(1:5)")
    call disp%show( logVolUnitBall(1:5) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setLogVolUnitBall(logVolUnitBall(1:5), ndim = [real(RKG) :: 0, 1, 2, 3, 4.5])")
                    call setLogVolUnitBall(logVolUnitBall(1:5), ndim = [real(RKG) :: 0, 1, 2, 3, 4.5])
    call disp%show("logVolUnitBall(1:5)")
    call disp%show( logVolUnitBall(1:5) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        use pm_arraySpace, only: setLinSpace
        integer(IK), parameter :: nsim = 1000_IK
        integer(IK) :: fileUnit, i
        real :: volUnitBall(nsim), ndim(nsim)
        open(newunit = fileUnit, file = "setLogVolUnitBall.RK.txt")
        call setLinSpace(ndim, 0., 20.)
        call setLogVolUnitBall(volUnitBall, ndim)
        do i = 1, nsim
            write(fileUnit, "(*(g0,:,','))") ndim(i), exp(volUnitBall(i))
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
call setLogVolUnitBall(logVolUnitBall(1), ndim = 2_IK)
logVolUnitBall(1)
+1.14472988584940017414342735135305866
 
 
call setLogVolUnitBall(logVolUnitBall(1), ndim = 2._RKG)
logVolUnitBall(1)
+1.14472988584940017414342735135305866
 
 
call setLogVolUnitBall(logVolUnitBall(1:5), ndim = [integer(IK) :: 0, 1, 2, 3, 4])
logVolUnitBall(1:5)
+0.00000000000000000000000000000000000, +0.693147180559945309417232121458176575, +1.14472988584940017414342735135305866, +1.43241195830118110158264635734688620, +1.59631259113885503886962258124794093
 
 
call setLogVolUnitBall(logVolUnitBall(1:5), ndim = [real(RKG) :: 0, 1, 2, 3, 4.5])
logVolUnitBall(1:5)
+0.00000000000000000000000000000000000, +0.693147180559945309417232121458176575, +1.14472988584940017414342735135305866, +1.43241195830118110158264635734688600, +1.63984031205242503356424402200248520
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
for kind in ["RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
 
    for file in fileList:
 
        df = pd.read_csv(file, delimiter = ",", header = None)
 
        # definitions for the axes
       #left, width = 0.1, 0.65
       #bottom, height = 0.1, 0.65
       #spacing = 0.015
 
        # start with a square Figure
        fig = plt.figure() # figsize = (8, 6)
 
        plt.rcParams.update({'font.size': fontsize - 2})
        ax = plt.subplot()
       #ax = fig.add_axes([left, bottom, width, height]) # scatter plot
       #ax_histx = fig.add_axes([left, bottom + height + spacing, width, 0.2], sharex = ax) # histx
       #ax_histy = fig.add_axes([left + width + spacing, bottom, 0.2, height], sharey = ax) # histy
       #
       #for axes in [ax, ax_histx, ax_histy]:
       #    axes.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
       #    axes.tick_params(axis = "y", which = "minor")
       #    axes.tick_params(axis = "x", which = "minor")
       #
       
 
        # the scatter plot:
        for i in range(0, len(df.values[0,:]), 2):
            ax.scatter  ( df.values[:,i]
                        , df.values[:,i+1]
                        , s = 8
                        , zorder = 1000
                        )
 
       #ax_histx.hist(df.values[:, 0], bins = 50, zorder = 1000)
       #ax_histy.hist(df.values[:, 1], bins = 50, orientation = "horizontal", zorder = 1000)
 
        #ax.set_aspect("equal")
        ax.set_xlim([0, df.values[-1,:].max()])
        ax.set_xlabel("ndim", fontsize = 17)
        ax.set_ylabel("Volume of ndim unit-ball", fontsize = 17)
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        plt.minorticks_on()
 
        plt.tight_layout()
        plt.savefig(file.replace(".txt",".png"))

Visualization of the example output ⛓

Benchmarks:

Benchmark :: The runtime performance of setLogVolUnitBall for integer vs. real input ndim. ⛓

! Test the performance of `setLogVolUnitBall()` with and without the selection `control` argument.
program benchmark
 
    use pm_bench, only: bench_type
    use pm_arraySpace, only: getLinSpace
    use pm_kind, only: IK, LK, RK1 => RKD, RK2 => RKS, RK, SK
    use iso_fortran_env, only: error_unit
 
    implicit none
 
    integer(IK)                         :: i
    integer(IK)                         :: idim
    integer(IK)                         :: fileUnit
    integer(IK)                         :: ndim_IK
 
    real(RK1)                           :: logVolUnitBall_RK1
    real(RK1)                           :: dum_RK1 = 0._RK1
    real(RK1)                           :: ndim_RK1
 
    real(RK2)                           :: logVolUnitBall_RK2
    real(RK2)                           :: dum_RK2 = 0._RK2
    real(RK2)                           :: ndim_RK2
    type(bench_type)    , allocatable   :: bench(:)
 
    bench = [ bench_type(name = SK_"ndimInt2RK1", exec = ndimInt2RK1, overhead = setOverhead_RK1) &
            , bench_type(name = SK_"ndimInt2RK2", exec = ndimInt2RK2, overhead = setOverhead_RK1) &
            , bench_type(name = SK_"ndimRealRK1", exec = ndimRealRK1, overhead = setOverhead_RK1) &
            , bench_type(name = SK_"ndimRealRK2", exec = ndimRealRK2, overhead = setOverhead_RK2) &
            ]
 
    write(*,"(*(g0,:,' '))")
    write(*,"(*(g0,:,' '))") "setLogVolUnitBallInt() vs. setLogVolUnitBallReal()"
    write(*,"(*(g0,:,' '))")
 
    open(newunit = fileUnit, file = "main.out", status = "replace")
 
        write(fileUnit, "(*(g0,:,','))") "ndim", (bench(i)%name, i = 1, size(bench))
        loopOverArraySize: do idim = 0, 20_IK
 
            ndim_IK   = idim
            ndim_RK1 = real(idim, RK1)
            ndim_RK2 = real(idim, RK2)
            write(*,"(*(g0,:,' '))") "Benchmarking with ndim = ", idim
            do i = 1, size(bench)
                bench(i)%timing = bench(i)%getTiming(minsec = 0.04_RK)
            end do
            write(fileUnit,"(*(g0,:,','))") idim, (bench(i)%timing%mean, i = 1, size(bench))
 
        end do loopOverArraySize
        write(*,"(*(g0,:,' '))") dum_RK1
        write(*,"(*(g0,:,' '))")
 
    close(fileUnit)
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead_RK1()
        call getDummy_RK1()
    end subroutine
 
    subroutine setOverhead_RK2()
        call getDummy_RK2()
    end subroutine
 
    subroutine getDummy_RK1()
        dum_RK1 = dum_RK1 + logVolUnitBall_RK1
    end subroutine
 
    subroutine getDummy_RK2()
        dum_RK2 = dum_RK2 + logVolUnitBall_RK2
    end subroutine
 
    subroutine ndimInt2RK1()
        use pm_ellipsoid, only: setLogVolUnitBall
        call setLogVolUnitBall(logVolUnitBall_RK1, ndim_IK)
        call getDummy_RK1()
    end subroutine
 
    subroutine ndimInt2RK2()
        use pm_ellipsoid, only: setLogVolUnitBall
        call setLogVolUnitBall(logVolUnitBall_RK2, ndim_IK)
        call getDummy_RK2()
    end subroutine
 
    subroutine ndimRealRK1()
        use pm_ellipsoid, only: setLogVolUnitBall
        call setLogVolUnitBall(logVolUnitBall_RK1, ndim_RK1)
        call getDummy_RK1()
    end subroutine
 
    subroutine ndimRealRK2()
        use pm_ellipsoid, only: setLogVolUnitBall
        call setLogVolUnitBall(logVolUnitBall_RK2, ndim_RK2)
        call getDummy_RK2()
    end subroutine
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
import os
dirname = os.path.basename(os.getcwd()) 
 
fontsize = 14
 
df = pd.read_csv("main.out", delimiter = ",")
colnames = list(df.columns.values)
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.plot( df[colnames[0]].values
            , df[colname].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel(colnames[0], fontsize = fontsize)
ax.set_ylabel("Runtime [ seconds ]", fontsize = fontsize)
ax.set_title(" vs. ".join(colnames[1:])+"\nLower is better.", fontsize = fontsize)
#ax.set_xscale("log")
ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.png")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
plt.plot( df[colnames[0]].values
        , np.ones(len(df[colnames[0]].values))
        , linestyle = "--"
       #, color = "black"
        , linewidth = 2
        )
for colname in colnames[2:]:
    plt.plot( df[colnames[0]].values
            , df[colname].values / df[colnames[1]].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel(colnames[0], fontsize = fontsize)
ax.set_ylabel("Runtime compared to {}".format(colnames[1]), fontsize = fontsize)
ax.set_title("Runtime Ratio Comparison. Lower means faster.\nLower than 1 means faster than {}().".format(colnames[1]), fontsize = fontsize)
#ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, bbox_to_anchor = (1, 0.5)
           #, loc = "center left"
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.ratio.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. The benchmark procedures named ndimInt2RK1 and ndimInt2RK2 call the generic interface setLogVolUnitBall with a ndim argument of type integer of kind IK and return the result as real of kind RKS and RKD respectively.
   Conversely, the procedures named ndimReal2RK1 and ndimReal2RK2 take ndim as real of kind RKS and RKD respectively and return results of the same type and kind as ndim.
   The first class of procedure interfaces (working with a ndim of type integer) compute the result using an iterative factorial computation approach.
   The second class of procedure interfaces (working with a ndim of type real) use the Fortran intrinsic log_gamma() to compute the results.
   This performance difference tends to be about a factor of 10 times for scalar optional arguments and grows substantially to larger factors with switching to increasing-size array-like optional dummy arguments.
   
2. From the benchmark results it appears that the interface accepting ndim of type RK32 offers the fastest algorithm, followed by the iterative methods.
   

Test:

test_pm_ellipsoid

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, April 23, 2017, 1:36 AM, Institute for Computational Engineering and Sciences (ICES), University of Texas at Austin

Definition at line 558 of file pm_ellipsoid.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_ellipsoid.F90