pm_distPiwiPoweto::setPiwiPowetoCDF Interface Reference

Return the Cumulative Distribution Function (CDF) of the (Truncated) PiwiPoweto distribution for an input logx within the support of the distribution logLimX(1) <= logx <= logLimX(size(logLimX)).
More...

Detailed Description

Return the Cumulative Distribution Function (CDF) of the (Truncated) PiwiPoweto distribution for an input logx within the support of the distribution logLimX(1) <= logx <= logLimX(size(logLimX)).

See the documentation of pm_distPiwiPoweto for more information on the (Truncated) PiwiPoweto distribution.

Parameters

[out]	cdf	: The output scalar of the same type and kind the input argument logx, containing the Cumulative Distribution Function (CDF) at the specified logx.
[in]	logx	: The input scalar of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the natural logarithm of the point at which the CDF must be computed.
[in]	alpha	: The input vector of the same type and kind as logx, of the same size n as the number of the power-law components of the distribution, containing the shape parameter of the distribution (i.e., the exponents of the power-law components of the distribution).
[in]	logLimX	: The input vector of the same type and kind as alpha, of size size(alpha) + 1 containing the natural logarithm of the scale parameters (i.e., the break points, or the limits) of the n power-law components of the distribution. The scale parameter(s) must be in ascending order, such that logLimX(1) <= x <= logLimX(size(logLimX)). Setting logLimX(1) <= -log(huge(logLimX)) effectively implies a left-opened semi-infinite support for the distribution. Setting logLimX(size(logLimX)) >= log(huge(logLimX)) effectively implies a right-opened semi-infinite support for the distribution.
[in]	logPDFNF	: The input vector of the same type, kind, and size as alpha, containing the natural logarithm of the normalization factors ( \(\eta\)) of power-law components of the distribution of the (Truncated) PiwiPoweto distribution. Specifying this argument when calling this procedure repeatedly with fixed \((\alpha, x_\mathrm{lim})\) parameters significantly improves the runtime performance. This input vector can be readily obtained by calling getPiwiPowetoLogPDFNF(alpha, logLimX).
[in]	cumSumArea	: The output vector of the same type, kind, and size as logLimX, each element of which corresponds to cumulative area underneath the distribution from the minimum of the support exp(logLimX(1)) to the corresponding element of exp(logLimX). By definition, cumSumArea(1) == 0. and cumSumArea(size(cumSumArea)) == 1., and isAscending(cumSumArea) hold. This output vector is a side-product of the computation of the normalization factors. It is also required for random number generation from the (Truncated) PiwiPoweto distribution. Precomputing and supplying this vector to the random number generator routines significantly improves the runtime performance. This vector can be readily obtained by calling getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea).

Possible calling interfaces ⛓

use pm_distPiwiPoweto, only: setPiwiPowetoCDF
 
call setPiwiPowetoCDF(cdf, logx, alpha(1:n), logLimX(1:n+1), logPDFNF(1:n), cumSumArea(1:n+1))
call setPiwiPowetoCDF(cdf, logx, alpha(1:n), logLimX(1:n+1), logPDFNF(1:n), cumSumArea(1:n+1), bin)

Warning

The condition size(alpha) > 0 must hold for the corresponding input arguments.
The condition size(logLimX) == size(alpha) + 1 must hold for the corresponding input arguments.
The condition size(cumSumArea) == size(alpha) + 1 must hold for the corresponding input arguments.
The condition size(logPDFNF) == size(alpha) must hold for the corresponding input arguments.
The conditions logLimX(1) <= logx .and. logx <= logLimX(size(logLimX)) must hold for the corresponding input arguments.
The conditions 0 < bin .and. bin < size(logLimX) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

See also

getPiwiPowetoCDF

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_distPiwiPoweto, only: getPiwiPowetoLogPDFNF
    use pm_distPiwiPoweto, only: setPiwiPowetoCDF
    use pm_arraySearch, only: getBin
    use pm_arraySpace, only: setLinSpace
    use pm_io, only: display_type
 
    implicit none
 
    integer(IK), parameter  :: NP = 999_IK
    real                    :: logx(NP), CDF(NP)
    real, allocatable       :: logLimX(:), alpha(:), cumSumArea(:)
 
    type(display_type)      :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("logx(1) = log(2.5)")
                    logx(1) = log(2.5)
    call disp%show("alpha = [1., 0., -1.5]")
                    alpha = [1., 0., -1.5]
    call disp%show("logLimX = log([0.5, 1., 1.5, huge(0.)])")
                    logLimX = log([0.5, 1., 1.5, huge(0.)])
    call disp%show("if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)")
                    if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)
    call disp%show("call setPiwiPowetoCDF(CDF(1), logx(1), alpha, logLimX, logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea), cumSumArea = cumSumArea)")
                    call setPiwiPowetoCDF(CDF(1), logx(1), alpha, logLimX, logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea), cumSumArea = cumSumArea)
    call disp%show("CDF(1)")
    call disp%show( CDF(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! If the target `x` value is known a prior to belong to a specific component of the CDF, specify it explicitly to expedite the CDF computation.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("logx(1) = log(2.5)")
                    logx(1) = log(2.5)
    call disp%show("alpha = [1., 0., -1.5]")
                    alpha = [1., 0., -1.5]
    call disp%show("logLimX = log([0.5, 1., 1.5, huge(0.)])")
                    logLimX = log([0.5, 1., 1.5, huge(0.)])
    call disp%show("if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)")
                    if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)
    call disp%show("call setPiwiPowetoCDF(CDF(1), logx(1), alpha, logLimX, logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea), cumSumArea = cumSumArea, bin = getBin(logLimX, logx(1)))")
                    call setPiwiPowetoCDF(CDF(1), logx(1), alpha, logLimX, logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea), cumSumArea = cumSumArea, bin = getBin(logLimX, logx(1)))
    call disp%show("CDF(1)")
    call disp%show( CDF(1) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example CDF array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        real, parameter :: LOG_HUGE = log(huge(0.))
        integer(IK) :: fileUnit, i
        real :: CDF(4)
        alpha = [3., 1., -1., -5.]
        logLimX = log([2., 5., 10., 15.])
        call setLinSpace(logx, x1 = log(0.001), x2 = log(20.), fopen = .true._LK, lopen = .true._LK)
        if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea(size(logLimX)+2))
        open(newunit = fileUnit, file = "setPiwiPowetoCDF.RK.txt")
        do i = 1, NP
            call setPiwiPowetoCDF(CDF(1), logx(i), [alpha(1:2), 0., alpha(3:4)], [-LOG_HUGE, logLimX(1:4), LOG_HUGE], getPiwiPowetoLogPDFNF([alpha(1:2), 0., alpha(3:4)], [-LOG_HUGE, logLimX(1:4), LOG_HUGE], cumSumArea(1:6)), cumSumArea(1:6)) ! PiwiPoweto
            if (logx(i) > logLimX(1)) then
                call setPiwiPowetoCDF(CDF(2), logx(i), alpha(2:4), [logLimX(1:3), LOG_HUGE], getPiwiPowetoLogPDFNF(alpha(2:4), [logLimX(1:3), LOG_HUGE], cumSumArea(1:4)), cumSumArea(1:4)) ! left-truncated PiwiPoweto
            else
                CDF(2) = 0.
            end if
            if (logx(i) < logLimX(4)) then
                call setPiwiPowetoCDF(CDF(3), logx(i), alpha(2:4), [-LOG_HUGE, logLimX(2:4)], getPiwiPowetoLogPDFNF(alpha(2:4), [-LOG_HUGE, logLimX(2:4)], cumSumArea(1:4)), cumSumArea(1:4)) ! right-truncated PiwiPoweto
            else
                CDF(3) = 1.
            end if
            if (logx(i) > logLimX(1) .and. logx(i) < logLimX(4)) then
                call setPiwiPowetoCDF(CDF(4), logx(i), alpha(1:3), logLimX(1:4), getPiwiPowetoLogPDFNF(alpha(1:3), logLimX(1:4), cumSumArea(1:4)), cumSumArea(1:4)) ! doubly-truncated PiwiPoweto
            elseif (logx(i) <= logLimX(1)) then
                CDF(4) = 0.
            else
                CDF(4) = 1.
            end if
            write(fileUnit,"(*(g0,:,', '))") exp(logx(i)), CDF
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
logx(1) = log(2.5)
alpha = [1., 0., -1.5]
logLimX = log([0.5, 1., 1.5, huge(0.)])
if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)
call setPiwiPowetoCDF(CDF(1), logx(1), alpha, logLimX, logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea), cumSumArea = cumSumArea)
CDF(1)
+0.802918077
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! If the target `x` value is known a prior to belong to a specific component of the CDF, specify it explicitly to expedite the CDF computation.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
logx(1) = log(2.5)
alpha = [1., 0., -1.5]
logLimX = log([0.5, 1., 1.5, huge(0.)])
if (allocated(cumSumArea)) deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)
call setPiwiPowetoCDF(CDF(1), logx(1), alpha, logLimX, logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea), cumSumArea = cumSumArea, bin = getBin(logLimX, logx(1)))
CDF(1)
+0.802918077
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : "X ( real/imaginary components )"
        , "IK" : "X ( integer-valued )"
        , "RK" : "X ( real-valued )"
        }
legends =   [ r"5-piece Poweto"
            , r"3-piece left-truncated Poweto"
            , r"4-piece right-truncated Poweto"
            , r"4-piece doubly-truncated Poweto"
            ]
 
for kind in ["IK", "CK", "RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = ", ")
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
        ax = plt.subplot()
 
        if kind == "CK":
            plt.plot( df.values[:, 0]
                    , df.values[:,[2,4]]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "r"
                    )
            plt.plot( df.values[:, 1]
                    , df.values[:,[3,5]]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "blue"
                    )
        else:
            plt.plot( df.values[:, 0]
                    , df.values[:,1:]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "r"
                    )
            ax.legend   ( legends
                        , fontsize = fontsize
                        )
 
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel(xlab[kind], fontsize = 17)
        ax.set_ylabel("Cumulative Distribution Function (CDF)", fontsize = 17)
        #ax.set_xscale("log")
        #ax.set_yscale("log")
 
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
 
        plt.tight_layout()
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distPiwiPoweto

Todo:

Low Priority: This generic interface can be extended to complex arguments.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 967 of file pm_distPiwiPoweto.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distPiwiPoweto.F90