pm_distPiwiPoweto::getPiwiPowetoLogPDFNF Interface Reference

Generate and return the natural logarithm of the normalization factors of the components of the Probability Density Function (PDF) of the (Truncated) PiwiPoweto distribution for the input parameter vectors \((\alpha, x_\mathrm{lim})\). More...

Detailed Description

Generate and return the natural logarithm of the normalization factors of the components of the Probability Density Function (PDF) of the (Truncated) PiwiPoweto distribution for the input parameter vectors \((\alpha, x_\mathrm{lim})\).

See the documentation of pm_distPiwiPoweto for the definition of the normalization factors.

The primary use of this interface is to compute the normalization factors of the (Truncated) PiwiPoweto distribution for a fixed set of parameters and use it in subsequent repeated calculations of the (Truncated) PiwiPoweto PDF to improve the runtime performance by eliminating redundant calculations.

Parameters

[in]	alpha	: The input vector of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), of the same size n as the number of the power-law components of the distribution, containing the shape parameter(s) of the distribution (i.e., the exponents (plus one) of the power-law components of the distribution).
[in]	logLimX	: The input vector of the same type and kind as alpha, of size size(alpha) + 1 containing the natural logarithm of the scale parameters (i.e., the break points, or the limits) of the n power-law components of the distribution. The scale parameter(s) must be in ascending order, such that logLimX(1) <= x <= logLimX(size(logLimX)). Setting logLimX(1) <= -log(huge(logLimX)) effectively implies a left-opened semi-infinite support for the distribution. Setting logLimX(size(logLimX)) >= log(huge(logLimX)) effectively implies a right-opened semi-infinite support for the distribution.
[out]	cumSumArea	: The output vector of the same type, kind, and size as logLimX, each element of which corresponds to the cumulative area underneath the distribution from the minimum of the support exp(logLimX(1)) to the corresponding element of exp(logLimX). By definition, the conditions cumSumArea(1) == 0. and cumSumArea(size(cumSumArea)) == 1. and isAscending(cumSumArea) hold. This output vector is a side-product of the computation of the normalization factors. It is also required for random number generation from the (Truncated) PiwiPoweto distribution. Precomputing and supplying this vector to the random number generator routines significantly improves the runtime performance. (optional. If missing, it will be computed implicitly within the algorithm and discarded upon return.)

Returns

logPDFNF : The output vector of the same type, kind, and size as the input argument alpha, containing the natural logarithm of the normalization factors of the power-law components of the (Truncated) PiwiPoweto distribution.

Possible calling interfaces ⛓

use pm_distPiwiPoweto, only: getPiwiPowetoLogPDFNF
 
logPDFNF(1:n) = getPiwiPowetoLogPDFNF(alpha(1:n), logLimX(1:n+1)) ! PiwiPoweto truncated at the upper limit `exp(logLimX(n+1))`.
logPDFNF(1:n) = getPiwiPowetoLogPDFNF(alpha(1:n), logLimX(1:n+1), cumSumArea(1:n+1)) ! PiwiPoweto truncated at the upper limit `exp(logLimX(n+1))`.
!

Warning

The condition size(alpha) > 0 must hold for the corresponding input arguments.
The condition size(logLimX) == size(alpha) + 1 must hold for the corresponding input arguments.
The condition size(cumSumArea) == size(alpha) + 1 must hold for the corresponding input arguments.
The condition size(logPDFNF) == size(alpha) must hold for the corresponding input arguments.
The condition alpha(1) > 0 .or. logLimX(1) > 0 must hold for the corresponding input arguments.
The condition alpha(size(alpha)) < 0 .or. logLimX(size(logLimX)) < log(huge(logLimX)) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds. The procedures under this generic interface are always impure when the output argument cumSumArea is present.

See also

getPiwiPowetoLogPDF
setPiwiPowetoLogPDF

Example usage ⛓

program example
 
    use pm_kind, only: IK
    use pm_kind, only: SK
    use pm_io, only: display_type
    use pm_arraySpace, only: getLinSpace
    use pm_arraySpace, only: getLogSpace
    use pm_distUnif, only: getUnifRand
    use pm_distPiwiPoweto, only: getPiwiPowetoLogPDFNF
 
    implicit none
 
    integer(IK) , parameter :: NP = 4_IK
    real        , allocatable :: alpha(:), logPDFNF(:), logLimX(:), cumSumArea(:)
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    alpha = [getUnifRand(-5., +5., NP - 1), -3.]
    logLimX = [getLinSpace(log(0.001), log(20.), NP), log(huge(0.))]
    allocate(cumSumArea, mold = logLimX)
    allocate(logPDFNF, mold = alpha)
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute the natural logarithm of the normalization factor of the PiwiPoweto distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("alpha")
    call disp%show( alpha )
    call disp%show("logLimX")
    call disp%show( logLimX )
    call disp%show("logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX)")
                    logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX)
    call disp%show("logPDFNF")
    call disp%show( logPDFNF )
    call disp%skip()
 
    call disp%skip()
    call disp%show("alpha")
    call disp%show( alpha )
    call disp%show("logLimX")
    call disp%show( logLimX )
    call disp%show("logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea)")
                    logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea)
    call disp%show("logPDFNF")
    call disp%show( logPDFNF )
    call disp%show("cumSumArea")
    call disp%show( cumSumArea )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute the natural logarithm of the normalization factor of the Truncated PiwiPoweto distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("alpha(1 : NP - 1)")
    call disp%show( alpha(1 : NP - 1) )
    call disp%show("logLimX(1 : NP)")
    call disp%show( logLimX(1 : NP) )
    call disp%show("logPDFNF = getPiwiPowetoLogPDFNF(alpha(1 : NP - 1), logLimX(1 : NP), cumSumArea(1 : NP)) ! `logLimX(NP)` is serves as the upper bound of the support of the distribution.")
                    logPDFNF = getPiwiPowetoLogPDFNF(alpha(1 : NP - 1), logLimX(1 : NP), cumSumArea(1 : NP))
    call disp%show("logPDFNF")
    call disp%show( logPDFNF )
    call disp%show("cumSumArea")
    call disp%show( cumSumArea )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example PDF array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        integer :: fileUnit, i
        alpha = getLinSpace(-5., 5., count = 100_IK)
        logLimX = getLinSpace(log(0.001), log(20.), count = size(alpha, 1, IK) + 1_IK)
        logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX)
        deallocate(cumSumArea); allocate(cumSumArea, mold = logLimX)
        logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea)
        open(newunit = fileUnit, file = "getPiwiPowetoLogPDFNF.RK.txt")
        write(fileUnit,"(2(g0,:,' '))") (exp(logLimX(i)), cumSumArea(i), i = 1, size(cumSumArea))
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute the natural logarithm of the normalization factor of the PiwiPoweto distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
alpha
+2.03216553, -4.66930389, -1.11287546, -3.00000000
logLimX
-6.90775537, -3.60659266, -0.305429935, +2.99573231, +88.7228394
logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX)
logPDFNF
+7.67782784, -16.4916420, -15.4054031, -9.75208282
 
 
alpha
+2.03216553, -4.66930389, -1.11287546, -3.00000000
logLimX
-6.90775537, -3.60659266, -0.305429935, +2.99573231, +88.7228394
logPDFNF = getPiwiPowetoLogPDFNF(alpha, logLimX, cumSumArea)
logPDFNF
+7.67782784, -16.4916420, -15.4054031, -9.75208282
cumSumArea
+0.00000000, +0.696499825, +0.999999404, +0.999999642, +0.999999642
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute the natural logarithm of the normalization factor of the Truncated PiwiPoweto distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
alpha(1 : NP - 1)
+2.03216553, -4.66930389, -1.11287546
logLimX(1 : NP)
-6.90775537, -3.60659266, -0.305429935, +2.99573231
logPDFNF = getPiwiPowetoLogPDFNF(alpha(1 : NP - 1), logLimX(1 : NP), cumSumArea(1 : NP)) ! `logLimX(NP)` is serves as the upper bound of the support of the distribution.
logPDFNF
+7.67782879, -16.4916420, -15.4054022
cumSumArea
+0.00000000, +0.696500540, +1.00000012, +1.00000036, +0.999999642
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : r"Scale Parameters: $x_{min}$ ( real/imaginary )"
        , "IK" : r"Scale Parameters: $x_{min}$ ( integer-valued )"
        , "RK" : r"Scale Parameters: $x_{min}$ ( real-valued )"
        }
 
for kind in ["IK", "CK", "RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = " ")
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
        ax = plt.subplot()
 
        if kind == "CK":
            plt.plot( df.values[:, 0]
                    , df.values[:,2]
                    , marker[kind]
                    , color = "r"
                    )
            plt.plot( df.values[:, 1]
                    , df.values[:,3]
                    , marker[kind]
                    , color = "blue"
                    )
        else:
            plt.plot( df.values[:, 0]
                    , df.values[:, 1]
                    , marker[kind]
                    , color = "r"
                    )
 
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel(xlab[kind], fontsize = fontsize)
        ax.set_ylabel("Cumulative Area Under PDF Components", fontsize = fontsize)
        ax.set_xscale("log")
        #ax.set_yscale("log")
 
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
 
        plt.tight_layout()
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distPiwiPoweto

Todo:

Low Priority: This generic interface can be extended to complex arguments.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 179 of file pm_distPiwiPoweto.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distPiwiPoweto.F90