pm_distPareto::setParetoLogRand Interface Reference

Return a scalar (or array of arbitrary rank) of the natural logarithm(s) of random value(s) from the (Truncated) Pareto distribution with parameters \((\alpha, x_\mathrm{min}, x_\mathrm{max})\). More...

Detailed Description

Return a scalar (or array of arbitrary rank) of the natural logarithm(s) of random value(s) from the (Truncated) Pareto distribution with parameters \((\alpha, x_\mathrm{min}, x_\mathrm{max})\).

See the documentation of pm_distPareto for more information on generating random numbers from the (Truncated) Pareto distribution.

Parameters

[out]	logRand	: The output scalar (or array of the same rank, shape, and size as other array like arguments), of the same type and kind as alpha, containing the random value(s) from the specified distribution.
[in]	negExpRand	: The input scalar (or array of the same rank, shape, and size as other array like arguments), of the same type and kind as alpha, containing a random value from the standard Negative Exponential distribution ( \(\mu = 0, \sigma = 1.\)). This argument can be readily obtained by calling getNegExpRand(sigma = 1.).
[in]	alpha	: The input scalar (or array of the same rank, shape, and size as other array like arguments), of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the shape parameter ( \(\alpha\)) of the distribution.
[in]	logMinX	: The input scalar (or array of the same rank, shape, and size as other array like arguments), of the same type and kind as alpha, containing the natural logarithm of the first scale parameter of the distribution, representing the minimum of the support of the distribution.
[in]	logCDFNF	: The input scalar (or array of the same rank, shape, and size as other array like arguments), of the same type and kind as alpha, containing the natural logarithm of the normalization factor of the CDF of the (Truncated) Pareto distribution. Specifying this argument when calling this procedure repeatedly with fixed \((\alpha, x_\mathrm{min}, x_\mathrm{max})\) parameters will significantly improve the runtime performance. This argument can be readily obtained by calling getParetoLogCDFNF(alpha, logMinX, logMaxX). (optional, default = getParetoLogCDFNF(alpha, logMinX, logMaxX). If present, it implies a (Truncated) Pareto distribution.)

Possible calling interfaces ⛓

use pm_distPareto, only: setParetoLogRand
 
call setParetoLogRand(logRand, negExpRand, alpha, logMinX) ! Pareto distributed.
call setParetoLogRand(logRand, negExpRand, alpha, logMinX, logCDFNF) ! Truncated Pareto distributed.
!

Warning

The condition alpha < 0 must hold for the corresponding input arguments.
The condition negExpRand <= 0 must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getParetoLogRand

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_distPareto, only: getParetoLogCDFNF
    use pm_distPareto, only: setParetoLogRand
    use pm_distNegExp, only: getNegExpRand
    use pm_io, only: display_type
 
    implicit none
 
    real                    :: logx(3)
 
    type(display_type)      :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute random value(s) from the Pareto distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setParetoLogRand(logx(1), negExpRand = getNegExpRand(1.), alpha = -2., logMinX = -2.) ! Pareto distribution.")
                    call setParetoLogRand(logx(1), negExpRand = getNegExpRand(1.), alpha = -2., logMinX = -2.) ! Pareto distribution.
    call disp%show("logx(1)")
    call disp%show( logx(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setParetoLogRand(logx(1:3), negExpRand = getNegExpRand([1., 1., 1.]), alpha = -[+2., +3., +4.], logMinX = -2.) ! Pareto distribution.")
                    call setParetoLogRand(logx(1:3), negExpRand = getNegExpRand([1., 1., 1.]), alpha = -[+2., +3., +4.], logMinX = -2.) ! Pareto distribution.
    call disp%show("logx(1:3)")
    call disp%show( logx(1:3) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%show("! Compute random value(s) from the Truncated Pareto distribution.")
    call disp%show("!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%")
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setParetoLogRand(logx(1), negExpRand = getNegExpRand(1.), alpha = -2., logMinX = -2., logCDFNF = getParetoLogCDFNF(alpha = -2., logMinX = -2., logMaxX = 5.)) ! Truncated Pareto distribution.")
                    call setParetoLogRand(logx(1), negExpRand = getNegExpRand(1.), alpha = -2., logMinX = -2., logCDFNF = getParetoLogCDFNF(alpha = -2., logMinX = -2., logMaxX = 5.)) ! Truncated Pareto distribution.
    call disp%show("logx(1)")
    call disp%show( logx(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setParetoLogRand(logx(1:3), negExpRand = getNegExpRand([1., 1., 1.]), alpha = -[+2., +3., +4.], logMinX = -2., logCDFNF = getParetoLogCDFNF(alpha = -[+2., +3., +4.], logMinX = -2., logMaxX = 5.)) ! Truncated Pareto distribution.")
                    call setParetoLogRand(logx(1:3), negExpRand = getNegExpRand([1., 1., 1.]), alpha = -[+2., +3., +4.], logMinX = -2., logCDFNF = getParetoLogCDFNF(alpha = -[+2., +3., +4.], logMinX = -2., logMaxX = 5.)) ! Truncated Pareto distribution.
    call disp%show("logx(1:3)")
    call disp%show( logx(1:3) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        use pm_arraySpace, only: setLinSpace
        real :: alpha(3), logMinX(3), logMaxX(3), logx(3)
        integer(IK) :: fileUnit, i
        alpha = -[.5, 1., 10.]
        logMinX = log([3., 1., 2.])
        logMaxX = log([5., 4., huge(0.)])
        open(newunit = fileUnit, file = "setParetoLogRand.RK.txt")
        do i = 1, 2000_IK
            call setParetoLogRand(logx(1:2), getNegExpRand([1., 1.]), alpha(1:2), logMinX(1:2), getParetoLogCDFNF(alpha(1:2), logMinX(1:2), logMaxX(1:2)))
            call setParetoLogRand(logx(3), getNegExpRand(1.), alpha(3), logMinX(3), 0.)
            write(fileUnit, "(*(g0,:,', '))") exp(logx)
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute random value(s) from the Pareto distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
call setParetoLogRand(logx(1), negExpRand = getNegExpRand(1.), alpha = -2., logMinX = -2.) ! Pareto distribution.
logx(1)
+1.85159397
 
 
call setParetoLogRand(logx(1:3), negExpRand = getNegExpRand([1., 1., 1.]), alpha = -[+2., +3., +4.], logMinX = -2.) ! Pareto distribution.
logx(1:3)
-1.91962278, -1.77407873, -1.42170680
 
 
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
! Compute random value(s) from the Truncated Pareto distribution.
!%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 
call setParetoLogRand(logx(1), negExpRand = getNegExpRand(1.), alpha = -2., logMinX = -2., logCDFNF = getParetoLogCDFNF(alpha = -2., logMinX = -2., logMaxX = 5.)) ! Truncated Pareto distribution.
logx(1)
-1.94397461
 
 
call setParetoLogRand(logx(1:3), negExpRand = getNegExpRand([1., 1., 1.]), alpha = -[+2., +3., +4.], logMinX = -2., logCDFNF = getParetoLogCDFNF(alpha = -[+2., +3., +4.], logMinX = -2., logMaxX = 5.)) ! Truncated Pareto distribution.
logx(1:3)
-1.94168150, -1.98973334, -1.86360693
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
linewidth = 2
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : "Random Value ( Real / Imaginary ))"
        , "IK" : "Random Value ( Integer )"
        , "RK" : "Random Value ( Real )"
        }
legends =   [ r"$\alpha = -.5, x_{min} = +3., x_{max} = +5$"
            , r"$\alpha = -1., x_{min} = +1., x_{max} = +4$"
            , r"$\alpha = -10, x_{min} = +2., x_{max} = +\infty$"
            ]
 
for kind in ["IK", "CK", "RK"]:
 
    pattern = "*." + kind + ".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = ", ")
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
        ax = plt.subplot()
 
        if kind == "CK":
            ax.hist ( df.values[:, 0]
                    , bins = 30
                    , histtype = "stepfilled"
                    , density = True
                    , alpha = 0.7
                    )
            ax.hist ( df.values[:, 1]
                    , bins = 30
                    , histtype = "stepfilled"
                    , density = True
                    , alpha = 0.7
                    )
        else:
            ax.hist ( df.values[:,:]
                    , bins = 50
                    , histtype = "stepfilled"
                    , density = True
                    , alpha = 0.7
                    )
            ax.legend   ( legends[::-1]
                        , fontsize = fontsize
                        )
 
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        ax.set_xlabel(xlab[kind], fontsize = 17)
        ax.set_ylabel("Density", fontsize = 17)
        ax.set_title("Histogram of {} randomly generated values".format(len(df.values)), fontsize = fontsize)
        #ax.set_yscale("log")
        #ax.set_xscale("log")
 
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
        ax.set_axisbelow(True)
 
        plt.tight_layout()
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distPareto

Todo:

Critical Priority: This interface can be extended to support vector-like logRand arguments other than the elemental approach.
Such an extension would be sensible only if the new interface improves the performance against the elemental approach.

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 1925 of file pm_distPareto.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distPareto.F90