pm_distBand::setBandPhoton Interface Reference

Generate and return the photon integral (the photon fluence in units of photon counts) of the Band model for the given distribution parameters from the corresponding energy integral of the distribution (the energy fluence in units of the input break energy).
More...

Detailed Description

Generate and return the photon integral (the photon fluence in units of photon counts) of the Band model for the given distribution parameters from the corresponding energy integral of the distribution (the energy fluence in units of the input break energy).

See the documentation of pm_distBand for more information on the Band distribution.
This generic interface computes one of the following quantities:

1. Conversion of energy fluence to photon fluence.
   

   \begin{equation} \large \sphot = \sergs \frac { \int_{\ms{lb}}^{\ms{ub}} f_{\ms{BAND}}(E | \alpha, \beta, \ebreak) dE } { \int_{\ms{lb}}^{\ms{ub}} E ~ f_{\ms{BAND}}(E | \alpha, \beta, \ebreak) dE } ~. \end{equation}

2. Conversion of energy fluence to photon fluence in a different energy range.
   

   \begin{equation} \large \sphot = \sergs \frac { \int_{\ms{lbnew}}^{\ms{ubnew}} f_{\ms{BAND}}(E | \alpha, \beta, \ebreak) dE } { \int_{\ms{lb}}^{\ms{ub}} E ~ f_{\ms{BAND}}(E | \alpha, \beta, \ebreak) dE } ~. \end{equation}

3. Conversion of photon fluence to photon fluence in a different energy range.
   

   \begin{equation} \large \sphot = \sphot \frac { \int_{\ms{lbnew}}^{\ms{ubnew}} f_{\ms{BAND}}(E | \alpha, \beta, \ebreak) dE } { \int_{\ms{lb}}^{\ms{ub}} f_{\ms{BAND}}(E | \alpha, \beta, \ebreak) dE } ~. \end{equation}

Warning

The input arguments lbnew, ubnew, energy, lb, ub, ebreak must all be unit-less (without physical dimensions) or all have the same physical units (typically, \(\kev\)).

Note

The physical units of the input or output arguments can be changed via the facilities of module pm_physUnit.

Parameters

[in,out]	photon	: The input/output positive scalar or array of the same shape as any input array-like argument, of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the photon fluence (UCDF) of the distribution. If the input argument energy is present, then photon has intent(out). On output, the value of photon represents the photon fluence of the Band model in the original or the newly-specified energy window. If the input argument energy is missing, then photon has intent(inout). On input, the value of photon is used as the original photon fluence to computed the amplitude of the Band model in the old energy window. On output, the value of photon represents the photon fluence of the Band model in the new energy window.
[in]	energy	: The input positive scalar or array of the same shape as any input array-like argument, of the same type and kind as the input argument photon, representing the energy fluence (integral) of the Band distribution with the specified input distribution parameters. (optional. If missing, the original fluence is read from the input value of photon and is assumed to be the photon fluence.)
[in]	lbnew	: The input positive scalar or array of the same shape as any input array-like argument, of the same type and kind as the input argument photon, representing the new lower bound of the Band distribution. (optional. It must be present if and only if the input argument ubnew is present and energy is missing.)
[in]	ubnew	: The input positive scalar or array of the same shape as any input array-like argument, of the same type and kind as the input argument photon, representing the new upper bound of the Band distribution. (optional. It must be present if and only if the input argument lbnew is present and energy is missing.)
[in]	lb	: The input positive scalar or array of the same shape as any input array-like argument, of the same type and kind as the input argument photon, representing the lower bound of the Band distribution.
[in]	ub	: The input positive scalar or array of the same shape as any input array-like argument, of the same type and kind as the input argument photon, representing the upper bound of the Band distribution.
[in]	alpha	: The input scalar or array of the same shape as other array-like arguments of the same type and kind as photon, containing the first shape parameter of the distribution.
[in]	beta	: The input scalar or array of the same shape as other array-like arguments of the same type and kind as photon, containing the second shape parameter of the distribution.
[in]	ebreak	: The input scalar or array of the same shape as other array-like arguments of the same type and kind as photon, containing the spectral break energy values.
[out]	info	: The input scalar of type integer of default kind IK. On output, it is set to positive the number of iterations taken for the series representation of the Gamma function to converge. If the algorithm fails to converge, then info is set to the negative of the number of iterations taken by the algorithm or, to the output error returned by brute force integrator getQuadErr. An negative output value signifies the lack of convergence and failure to compute the UCDF. This is likely to happen if the input value for alpha or beta are too extreme.

Possible calling interfaces ⛓

use pm_distBand, only: setBandPhoton
 
call setBandPhoton(photon, energy, lb, ub, alpha, beta, ebreak, info)
call setBandPhoton(photon, lbnew, ubnew, lb, ub, alpha, beta, ebreak, info)
call setBandPhoton(photon, lbnew, ubnew, energy, lb, ub, alpha, beta, ebreak, info)

Warning

The condition 0 < lb must hold for the corresponding input arguments.
The condition lb < ub must hold for the corresponding input arguments.
The condition 0 < lbnew must hold for the corresponding input arguments.
The condition lbnew < ubnew must hold for the corresponding input arguments.
The condition 0 < photon must hold for the corresponding input arguments.
The condition 0 < energy must hold for the corresponding input arguments.
The condition 0 < lbnew must hold for the corresponding input arguments.
The condition 0 < ubnew must hold for the corresponding input arguments.
The condition alpha /= -2 must hold for the corresponding input arguments.
The condition 0 < ebreak must hold for the corresponding input arguments.
The condition beta < alpha must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

Note

The normalization (and the physical units) of the input energy is irrelevant as long as the other dimensional input values (e.g., ebreak) are computed in the same physical dimensions and with the same normalizations.

See also

getBandUDF
setBandUCDF
setBandMean
getBandZeta
getBandEpeak
getBandEbreak
setBandPhoton
setBandEnergy

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_kind, only: RKG => RKH ! all processor kinds are supported.
    use pm_io, only: display_type
    use pm_distBand, only: getBandEbreak
    use pm_distBand, only: setBandPhoton
    use pm_physUnit, only: ERGS2KEV, KEV2ERGS
 
    implicit none
 
    integer(IK) :: info
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    block
 
        use pm_kind, only: RKG => RKD
        real(RKG) :: photons, fluence, lbnew, ubnew, lb, ub, alpha, beta, ebreak
 
        call disp%skip()
        call disp%show("fluence = 2.044544e-07_RKG * ERGS2KEV; lbnew = 50._RKG; ubnew = 300._RKG; lb = 50._RKG; ub = 300._RKG; alpha = -9.469590e-01_RKG; beta = -3.722981_RKG; ebreak = getBandEbreak(alpha, beta, 1.928073e+02_RKG);")
                        fluence = 2.044544e-07_RKG * ERGS2KEV; lbnew = 50._RKG; ubnew = 300._RKG; lb = 50._RKG; ub = 300._RKG; alpha = -9.469590e-01_RKG; beta = -3.722981_RKG; ebreak = getBandEbreak(alpha, beta, 1.928073e+02_RKG);
        call disp%show("call setBandPhoton(photons, fluence, lb, ub, alpha, beta, ebreak, info)")
                        call setBandPhoton(photons, fluence, lb, ub, alpha, beta, ebreak, info)
        call disp%show("if (info < 0) error stop")
                        if (info < 0) error stop
        call disp%show("photons ! photon fluence 1.084876")
        call disp%show( photons )
        call disp%skip()
 
    end block
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
 
        use pm_arraySpace, only: setLogSpace
        integer(IK), parameter :: NP = 1000_IK
        real(RKG) :: photons(4), epeak(NP), alpha(4), beta(4)
        integer :: fileUnit, i
        integer(IK) :: info(4)
 
        alpha = [.5_RKG, 1.5_RKG, -.5_RKG, -1.1_RKG]
        beta = -[.5_RKG, 1._RKG, 2._RKG, 3._RKG]
        call setLogSpace(epeak, log(1._RKG), log(10000._RKG))
        open(newunit = fileUnit, file = "setBandPhoton.RK.txt")
        do i = 1, NP
            call setBandPhoton(photons, 50._RKG, 300._RKG, 1._RKG, 0.01_RKG, 20000._RKG, alpha, beta, getBandEbreak(alpha, beta, epeak(i)), info)
            if (any(info < 0)) error stop
            write(fileUnit, "(*(g0,:,' '))") epeak(i), photons
        end do
        close(fileUnit)
 
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
fluence = 2.044544e-07_RKG * ERGS2KEV; lbnew = 50._RKG; ubnew = 300._RKG; lb = 50._RKG; ub = 300._RKG; alpha = -9.469590e-01_RKG; beta = -3.722981_RKG; ebreak = getBandEbreak(alpha, beta, 1.928073e+02_RKG);
call setBandPhoton(photons, fluence, lb, ub, alpha, beta, ebreak, info)
if (info < 0) error stop
photons ! photon fluence 1.084876
+1.0860736204671377
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
fontsize = 17
 
kind = "RK"
label = [ r"$\alpha, \beta = +0.5, -0.5, x_b = 0.5$"
        , r"$\alpha, \beta = +1.5, -1.0, x_b = 1.5$"
        , r"$\alpha, \beta = -0.5, -2.0, x_b = 2.0$"
        , r"$\alpha, \beta = -1.1, -3.0, x_b = 5.0$"
        ]
 
pattern = "*." + kind + ".txt"
fileList = glob.glob(pattern)
if len(fileList) == 1:
 
    df = pd.read_csv(fileList[0], delimiter = " ")
 
    fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
    ax = plt.subplot()
 
    for i in range(1,len(df.values[0,:]+1)):
 
        plt.plot( df.values[:, 0]
                , df.values[:,i]
                , linewidth = 2
                )
 
    plt.xticks(fontsize = fontsize - 2)
    plt.yticks(fontsize = fontsize - 2)
    ax.set_xlabel("Epeak [ keV ]", fontsize = fontsize)
    ax.set_ylabel("Photon count in 50-300 keV range", fontsize = fontsize)
    ax.set_xscale("log")
    ax.set_yscale("log")
 
    plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
    ax.tick_params(axis = "y", which = "minor")
    ax.tick_params(axis = "x", which = "minor")
 
    ax.legend   ( label
                , fontsize = fontsize
               #, loc = "center left"
               #, bbox_to_anchor = (1, 0.5)
                )
 
    plt.savefig(fileList[0].replace(".txt",".png"))
 
else:
 
    sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distBand

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 1276 of file pm_distBand.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distBand.F90