pm_distPois::setPoisCDF Interface Reference

Return the Cumulative Distribution Function (CDF) of the Poisson distribution. More...

Detailed Description

Return the Cumulative Distribution Function (CDF) of the Poisson distribution.

Parameters

[out]	cdf	: The output scalar (or array of the same rank, shape, and size as other array-like arguments), of the same type and kind as lambda, containing the CDF of the distribution at the specified input value(s).
[in]	countP1	: The input scalar (or array of the same rank, shape, and size as other array-like arguments), of the same type and kind as the input argument lambda, containing the value(s) at which the CDF must be computed plus 1.. Although countP1 is of type real, it must be a whole number. The enforcement of real type is to ensure the performance of this generic interface.
[in]	lambda	: The input scalar (or array of the same rank, shape, and size as other array-like arguments), of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the location parameter of the distribution.
[out]	info	: The output scalar of type integer of default kind IK. On output, it is set to positive the number of iterations taken for the series representation of the Gamma function to converge. If the algorithm fails to converge, then info is set to the negative of the number of iterations taken by the algorithm. An negative output value signifies the lack of convergence and failure to compute the CDF. For more information, see the documentation of setGammaInc.

Possible calling interfaces ⛓

use pm_distPois, only: setPoisCDF
 
call setPoisCDF(cdf, countP1, lambda, info)

Warning

The condition 0 < lambda must hold for the corresponding input arguments.
The condition 1. <= countP1 must hold for the corresponding input arguments.
The condition mod(countP1, 1._RKG) == 0._RKG must hold for the corresponding input arguments, that is, the input argument countP1 must be a whole number.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

The pure procedure(s) documented herein become impure when the ParaMonte library is compiled with preprocessor macro CHECK_ENABLED=1.
By default, these procedures are pure in release build and impure in debug and testing builds.

Remarks

The procedures under discussion are elemental.

See also

getPoisCDF

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_kind, only: RKG => RK ! all processor kinds are supported.
    use pm_io, only: display_type
    use pm_distPois, only: setPoisCDF
    use pm_err, only: setAsserted
 
    implicit none
 
    real(RKG) :: cdf(3)
    integer(IK) :: info(3)
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("call setPoisCDF(cdf(1), 1._RKG, 2._RKG, info(1))")
                    call setPoisCDF(cdf(1), 1._RKG, 2._RKG, info(1))
    call disp%show(.not."call setAsserted( info(1) < 0)")
                    call setAsserted(.not. info(1) < 0)
    call disp%show("cdf(1)")
    call disp%show( cdf(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setPoisCDF(cdf(1), 2._RKG, 2._RKG, info(1))")
                    call setPoisCDF(cdf(1), 2._RKG, 2._RKG, info(1))
    call disp%show(.not."call setAsserted( info(1) < 0)")
                    call setAsserted(.not. info(1) < 0)
    call disp%show("cdf(1)")
    call disp%show( cdf(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setPoisCDF(cdf(1), 3._RKG, 2._RKG, info(1))")
                    call setPoisCDF(cdf(1), 3._RKG, 2._RKG, info(1))
    call disp%show(.not."call setAsserted( info(1) < 0)")
                    call setAsserted(.not. info(1) < 0)
    call disp%show("cdf(1)")
    call disp%show( cdf(1) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setPoisCDF(cdf(1:3), 1._RKG + [real(RKG) :: 0, 1, 2], 2._RKG, info)")
                    call setPoisCDF(cdf(1:3), 1._RKG + [real(RKG) :: 0, 1, 2], 2._RKG, info)
    call disp%show(.not."call setAsserted( any(info < 0))")
                    call setAsserted(.not. any(info < 0))
    call disp%show("cdf(1:3)")
    call disp%show( cdf(1:3) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("call setPoisCDF(cdf(1:3), [real(RKG) :: 1, 2, 3], [0.1_RKG, 1._RKG, 10._RKG], info)")
                    call setPoisCDF(cdf(1:3), [real(RKG) :: 1, 2, 3], [0.1_RKG, 1._RKG, 10._RKG], info)
    call disp%show(.not."call setAsserted( any(info < 0))")
                    call setAsserted(.not. any(info < 0))
    call disp%show("cdf(1:3)")
    call disp%show( cdf(1:3) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
 
        use pm_arraySpace, only: getLinSpace
        real(RKG), allocatable :: countP1(:)
        integer(IK) :: info(4)
        integer :: fileUnit, i
        real(RKG) :: cdf(4)
 
        countP1 = getLinSpace(1._RKG, 21._RKG, 21_IK)
        open(newunit = fileUnit, file = "setPoisCDF.IK.txt")
        do i = 1, size(countP1)
            call setPoisCDF(cdf, countP1(i), [.1_RKG, 1._RKG, 4._RKG, 10._RKG], info)
            call setAsserted(.not. any(info < 0))
            write(fileUnit, "(*(g0,:,' '))") countP1(i) - 1._RKG, cdf
        end do
        close(fileUnit)
 
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
call setPoisCDF(cdf(1), 1._RKG, 2._RKG, info(1))
call setAsserted(.not. info(1) < 0)
cdf(1)
+0.13533528323661270
 
 
call setPoisCDF(cdf(1), 2._RKG, 2._RKG, info(1))
call setAsserted(.not. info(1) < 0)
cdf(1)
+0.40600584970983800
 
 
call setPoisCDF(cdf(1), 3._RKG, 2._RKG, info(1))
call setAsserted(.not. info(1) < 0)
cdf(1)
+0.67667641618306340
 
 
call setPoisCDF(cdf(1:3), 1._RKG + [real(RKG) :: 0, 1, 2], 2._RKG, info)
call setAsserted(.not. any(info < 0))
cdf(1:3)
+0.13533528323661270, +0.40600584970983800, +0.67667641618306340
 
 
call setPoisCDF(cdf(1:3), [real(RKG) :: 1, 2, 3], [0.1_RKG, 1._RKG, 10._RKG], info)
call setAsserted(.not. any(info < 0))
cdf(1:3)
+0.90483741803595952, +0.73575888234288467, +0.27693957155115745E-2
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import glob
import sys
 
fontsize = 17
 
kind = "IK"
label = [ r"$\lambda = 0.1$"
        , r"$\lambda = 1.0$"
        , r"$\lambda = 4.0$"
        , r"$\lambda = 10.$"
        ]
 
pattern = "*." + kind + ".txt"
fileList = glob.glob(pattern)
if len(fileList) == 1:
 
    df = pd.read_csv(fileList[0], delimiter = " ", header = None)
 
    fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 200)
    ax = plt.subplot()
 
    for i in range(1,len(df.values[0,:]+1)):
 
            plt.plot( df.values[:, 0]
                    , df.values[:,i]
                    , marker = "."
                    )
 
    plt.xticks(fontsize = fontsize - 2)
    plt.yticks(fontsize = fontsize - 2)
    ax.set_xlim([0, None])
    ax.set_xlabel("Count", fontsize = fontsize)
    ax.set_ylabel("CDF", fontsize = fontsize)
 
    plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
    ax.tick_params(axis = "y", which = "minor")
    ax.tick_params(axis = "x", which = "minor")
 
    ax.legend   ( label
                , fontsize = fontsize
               #, loc = "center left"
               #, bbox_to_anchor = (1, 0.5)
                )
 
    plt.savefig(fileList[0].replace(".txt",".png"))
 
else:
 
    sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distPois

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 676 of file pm_distPois.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distPois.F90