pm_distNormShell::getNormShellLogUDF Interface Reference

Generate and return the natural logarithm of the NormShell density function value(s) at the specified input point X, for the specified set of parameters of the single or mixture of NormShell distributions.
More...

Detailed Description

Generate and return the natural logarithm of the NormShell density function value(s) at the specified input point X, for the specified set of parameters of the single or mixture of NormShell distributions.

See the documentation of pm_distNormShell for details of the NormShell density function.

Parameters

[in]	X	: The input vector of size (1:ndim) of, type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128), containing the ndim-dimensional point at which the function must be evaluated.
[in]	center	: The input argument of the same type and kind as X, representing the center (location parameter: \(\mu\)) of the density function(s). It can be, a contiguous vector of the same rank and size as the input X: center(1:ndim). a contiguous matrix whose first dimension is of the same size as the input X, and its second dimension is the number of unique density functions in the mixture: center(1:ndim, 1:nmix). (optional, default = 0.. It must be present if and only if the input argument invCov is also present.)
[in]	invCov	: The input argument of the same type and kind as X, representing the inverse covariance matrix(es) ( \(\Sigma^{-1}\)) of the Normal distribution(s) of the density function(s). It can be, a contiguous square matrix of the same rank as the size of the input X: invCov(1:ndim, 1:ndim). a contiguous array of rank 3 whose first and second dimensions are of the same size as the input X, and its third dimension is the number of unique density functions in the mixture: invCov(1:ndim, 1:ndim, 1:nmix). (optional, default = the identity matrix. It must be present if and only if the input argument center is also present.)
[in]	width	: The input positive-valued argument of the same type and kind as the input X, representing the width of the shell(s) as specified by the shape parameter ( \(\omega\)) of the density function(s). It can be, a scalar representing the width of the single density function. a contiguous vector of size nmix, representing the widths of individual density function(s) in the mixture. (optional, default = 1.)
[in]	radius	: The input positive-valued argument of the same type and kind as the input X, representing the radius of the shell(s) as specified by the shape parameter ( \(\rho\)) of the density function(s). It can be, a scalar representing the radius of the single density function. a contiguous vector of size nmix, representing the radii of individual density function(s) in the mixture. (optional, default = 1.)

Returns

logUDF : The output of the same type and kind as the input argument X representing the natural logarithm of the value(s) of the density function(s) at the specified location X and parameters sets.
It is,

1. a scalar if and only if the dimensionality of the input arguments corresponds to a single density function.
2. a vector of size nmix if and only if the dimensionality of the input arguments corresponds to a mixture of nmix density functions.

Possible calling interfaces ⛓

use pm_distNormShell, only: getNormShellLogUDF
 
! single density function.
 
logUDF = getNormShellLogUDF(X(1:ndim), width = width, radius = radius)
logUDF = getNormShellLogUDF(X(1:ndim), center(1:ndim), invCov(1:ndim, 1:ndim), width = width, radius = radius)
 
! mixture of density functions.
 
logUDF(1:nmix) = getNormShellLogUDF(X(1:ndim), width = width(1:nmix), radius = radius(1:nmix))
logUDF(1:nmix) = getNormShellLogUDF(X(1:ndim), center(1:ndim, 1:nmix), invCov(1:ndim, 1:ndim, 1:nmix), width = width(1:nmix), radius = radius(1:nmix))

Warning

The condition all([0. < width]) must hold for the corresponding input arguments.
The condition all([0. < radius]) must hold for the corresponding input arguments.
The condition size(X, 1) == size(center, 1) must hold for the corresponding input arguments.
The condition all(size(X, 1) == [size(invCov, 1), size(invCov, 2)]) must hold for the corresponding input arguments.
The condition size(invCov, rank(invCov)) == size(center, rank(invCov)) must hold for the corresponding input arguments.
These conditions are verified only if the library is built with the preprocessor macro CHECK_ENABLED=1.

Remarks

The procedures under discussion are impure.

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK
    use pm_kind, only: RKG => RK ! all real kinds are supported.
    use pm_distNormShell, only: getNormShellLogUDF
    use pm_arraySpace, only: getLinSpace
    use pm_arraySpace, only: setLinSpace
    use pm_arraySpace, only: setLogSpace
    use pm_io, only: display_type
 
    implicit none
 
    integer(IK), parameter  :: NP = 5_IK
 
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("getNormShellLogUDF([0._RKG]) ! 1D")
    call disp%show( getNormShellLogUDF([0._RKG]) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("getNormShellLogUDF([0._RKG], [0._RKG], reshape([1._RKG], [1,1]), 5._RKG, 2._RKG) ! 1D")
    call disp%show( getNormShellLogUDF([0._RKG], [0._RKG], reshape([1._RKG], [1,1]), 5._RKG, 2._RKG) )
    call disp%skip()
 
    call disp%skip()
    call disp%show("getNormShellLogUDF([real(RKG) :: 0, 1], center = [-1._RKG, 1._RKG], invCov = reshape([1._RKG, .5_RKG, .5_RKG, 1._RKG], [2, 2]), width = 0.5_RKG, radius = 2._RKG) ! 2D")
    call disp%show( getNormShellLogUDF([real(RKG) :: 0, 1], center = [-1._RKG, 1._RKG], invCov = reshape([1._RKG, .5_RKG, .5_RKG, 1._RKG], [2, 2]), width = 0.5_RKG, radius = 2._RKG) )
    call disp%skip()
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! Output an example density array for visualization.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    block
        integer(IK) :: fileUnit, i, j
        integer(IK), parameter :: nmix = 4
        real(RKG) , parameter :: signif = 2
        real(RKG) :: point(1000), width(nmix), radius(nmix), center(1, nmix), invCov(1, 1, nmix)
        center = reshape([-1._RKG, +0._RKG, +1._RKG, +2._RKG], shape(center))
        invCov = 1._RKG / reshape([+1._RKG, +2._RKG, +5._RKG, 0.5_RKG], shape(invCov))
        radius = [1._RKG, 5._RKG, 2._RKG, 0.5_RKG]
        width = .5_RKG
        call setLinSpace( point &
                        , x1 = -10._RKG &
                        , x2 = +10._RKG &
                        )
        open(newunit = fileUnit, file = "getNormShellLogUDF.D1.RK.txt")
        do i = 1, size(point)
            write(fileUnit,"(*(f0.8,:,','))") point(i), exp(getNormShellLogUDF(point(i:i), center, invCov, width, radius))
        end do
        close(fileUnit)
    end block
 
    block
        use pm_mathSubAdd, only: operator(.subadd.)
        use pm_arrayMembership, only: operator(.inrange.)
        use pm_matrixInit, only: uppLowDia, getMatInit
        use pm_mathLogSumExp, only: getLogSumExp
        integer(IK) :: fileUnit, i, j
        real(RKG)   , parameter :: signif = 2_IK
        integer(IK) , parameter :: ndim = 2_IK, nmix = 2_IK, npnt = 700_IK
        real(RKG) :: grid(ndim, npnt, npnt), center(ndim, nmix), invCov(ndim, ndim, nmix), width(nmix), radius(nmix)
        center = 2 * reshape([-1._RKG, -1._RKG, 1._RKG, 1._RKG], shape(center))
        invCov = spread(getMatInit([ndim, ndim], uppLowDia, 0._RKG, 0._RKG, 1._RKG), 3, nmix)
        invCov(1,2,1) = 0.5
        invCov(2,1,1) = 0.5
        radius = [2._RKG, 2._RKG]
        width = .5_RKG * [1._RKG, 1._RKG]
        do i = 1, ndim
            grid(i, :, :) = spread(getLinSpace(x1 = -6._RKG, x2 = +6._RKG, count = npnt) , 3 - i, npnt)
        end do
        open(newunit = fileUnit, file = "getNormShellLogUDF.D2.RK.txt")
        do i = 1, size(grid, 2)
            do j = 1, size(grid, 3)
                write(fileUnit,"(*(f0.8,:,','))") grid(:, i, j), exp(getLogSumExp(getNormShellLogUDF(grid(:, i, j), center, invCov, width, radius)))
            end do
        end do
        close(fileUnit)
    end block
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
getNormShellLogUDF([0._RKG]) ! 1D
-0.50000000000000000
 
 
getNormShellLogUDF([0._RKG], [0._RKG], reshape([1._RKG], [1,1]), 5._RKG, 2._RKG) ! 1D
-0.80000000000000016E-1
 
 
getNormShellLogUDF([real(RKG) :: 0, 1], center = [-1._RKG, 1._RKG], invCov = reshape([1._RKG, .5_RKG, .5_RKG, 1._RKG], [2, 2]), width = 0.5_RKG, radius = 2._RKG) ! 2D
-2.0000000000000000
 
 

Postprocessing of the example output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
import math
import glob
import sys
 
linewidth = 2
fontsize = 17
 
marker ={ "CK" : "-"
        , "IK" : "."
        , "RK" : "-"
        }
xlab =  { "CK" : "X ( real/imaginary components )"
        , "IK" : "X ( integer-valued )"
        , "RK" : "X ( real-valued )"
        }
legends =   [ r"$\mu = -1.,~\Sigma = 1., \omega = .5, \rho = 1.$"
            , r"$\mu = +0.,~\Sigma = 2., \omega = .5, \rho = 5.$"
            , r"$\mu = +1.,~\Sigma = 5., \omega = .5, \rho = 2.$"
            , r"$\mu = +2.,~\Sigma = .5, \omega = .5, \rho = .5$"
            ]
 
for kind in ["IK", "CK", "RK"]:
 
        # Make 1d plot.
 
    pattern = "*.D1."+kind+".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = ",")
 
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 300)
        ax = plt.subplot()
 
        if kind == "CK":
            plt.plot( df.values[:, 0]
                    , df.values[:,1:5]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "r"
                    )
            plt.plot( df.values[:,1]
                    , df.values[:,1:5]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "blue"
                    )
        else:
            plt.plot( df.values[:, 0]
                    , df.values[:,1:5]
                    , marker[kind]
                    , linewidth = linewidth
                   #, color = "r"
                    )
            ax.legend   ( legends
                        , fontsize = fontsize
                        )
 
            plt.xticks(fontsize = fontsize - 2)
            plt.yticks(fontsize = fontsize - 2)
            ax.set_xlabel(xlab[kind], fontsize = 17)
            ax.set_ylabel("Probability Density Function (PDF)", fontsize = 17)
 
            plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
            ax.tick_params(axis = "y", which = "minor")
            ax.tick_params(axis = "x", which = "minor")
 
            plt.tight_layout()
            plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")
    # Make 2d plot.
 
    pattern = "*.D2."+kind+".txt"
    fileList = glob.glob(pattern)
    if len(fileList) == 1:
 
        df = pd.read_csv(fileList[0], delimiter = ",", header = None)
        df = df.values
 
        npnt = math.isqrt(len(df[:, 0]))
        gridx = np.reshape(df[:, 0], newshape = (npnt, npnt), order = 'F')
        gridy = np.reshape(df[:,1], newshape = (npnt, npnt), order = 'F')
        gridz = np.reshape(df[:,2], newshape = (npnt, npnt), order = 'C')
 
        fig, ax = plt.subplots(subplot_kw = {"projection": "3d"})
        fig = plt.figure(figsize = 1.25 * np.array([6.4, 4.8]), dpi = 300)
        ax = fig.add_subplot(1, 1, 1, projection = '3d')
        
        ax.plot_surface(gridx, gridy, gridz, cmap = 'viridis', linewidth = 0)
        ax.set_xlabel('X axis')
        ax.set_ylabel('Y axis')
        ax.set_zlabel("Log ( Density )", fontsize = 17)
        
        plt.xticks(fontsize = fontsize - 2)
        plt.yticks(fontsize = fontsize - 2)
        
        plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
        ax.tick_params(axis = "y", which = "minor")
        ax.tick_params(axis = "x", which = "minor")
        
        plt.tight_layout()
        plt.savefig(fileList[0].replace(".txt",".png"))
 
    elif len(fileList) > 1:
 
        sys.exit("Ambiguous file list exists.")

Visualization of the example output ⛓

Test:

test_pm_distNormShell

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Oct 16, 2009, 11:14 AM, Michigan

Definition at line 161 of file pm_distNormShell.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_distNormShell.F90