pm_optimization::setMinPowell Interface Reference

Compute and return the minimum value and the corresponding abscissa xmin(1:ndim) of the input arbitrary (ndim) dimensional-support function isolated to a fractional precision of about tol using the Powell unconstrained derivative-free minimization method.
More...

Detailed Description

Compute and return the minimum value and the corresponding abscissa xmin(1:ndim) of the input arbitrary (ndim) dimensional-support function isolated to a fractional precision of about tol using the Powell unconstrained derivative-free minimization method.

Parameters

[in]	getFunc	: The scalar function be minimized. On input, it must take a vector of size ndim of the same type and kind as the input/output argument xmin. On output, it must return a scalar of the same type and kind as the input/output argument xmin, containing the function value at the specified input vector point. The following demonstrates the interface of getFunc, function getFunc(x) result(func) real(RKG), intent(in) :: x(ndim) real(RKG) :: func end function where RKG can refer to any real type kind parameter any supported by the processor (e.g., RK, RK32, RK64, or RK128) supported by the library.
[in,out]	xmin	: The input/output vector of size ndim of type real of kind any supported by the processor (e.g., RK, RK32, RK64, or RK128). On input, it must contain the initial best guess abscissa at the function minimum. On output, it will contain the inferred abscissa at the function minimum, if the algorithm succeeds.
[in,out]	fmin	: The input/output scalar of the same type and kind as the input/output argument xmin. On input, it must contain getFunc(xmin). On output, it will contain the function value at the identified minimum abscissa xmin.
[in,out]	dirset	: The input/output matrix of the same type and kind as the input/output argument xmin, On input, it must contain the initial direction set matrix, each column of which is a unit vector along the corresponding coordinates axis. On output, the initial contents will be destroyed because the matrix is used as a workspace.
[in]	tol	: The input positive scalar of the same type and kind as the input/output argument xmin, containing the minimum distance that a new function evaluation point xmin can have from any previously evaluated point. Values smaller than the suggestion below might lead to algorithm failure due to roundoff error accumulation. A reasonable choice is tol = sqrt(epsilon(1._RKG)).
[in,out]	niter	: The input/output positive scalar of type integer of default kind IK containing the maximum number of allowed iterations at every step of the algorithm in search of a univariate minimum along a specific direction. On output, If the algorithm succeeds, niter will be set to the actual number of iterations taken to find the minimum which is by definition, less than or equal to the input value. If the algorithm fails to converge, it will be a number larger than the input value (by only 1 unit). A reasonable choice is niter = int(100 * precision(xmin) / 53.).

Possible calling interfaces ⛓

use pm_optimization, only: setMinPowell
 
call setMinPowell(getFunc, xmin, fmin, dirset, tol, niter)

Warning

The condition fmin == getFunc(xmin) must hold for the corresponding input arguments.
The condition 0 < niter must hold for the corresponding input arguments.
The condition 0 < tol must hold for the corresponding input arguments.

Remarks

The procedures under discussion are impure.

The procedures under discussion are recursive.

See also

getMinBrent
setMinBrent
isFailedMinPowell
setMinPowell

Example usage ⛓

program example
 
    use pm_kind, only: SK, IK, LK
    use pm_kind, only: RKG => RKH ! all processor kinds are supported.
    use pm_io, only: display_type
    use pm_optimization, only: setMinPowell
    use pm_arrayFill, only: getFilled
    use pm_matrixInit, only: getMatInit, uppLowDia
 
    implicit none
 
    integer(IK) :: niter
    integer(IK), parameter :: ndim = 4
    real(RKG) :: xmin(ndim), dirset(ndim, ndim), fmin
    type(display_type) :: disp
    disp = display_type(file = "main.out.F90")
 
    call disp%skip()
    call disp%show("getSq(x) = (x - [real(RKG) :: 1, 2, 3, 4])**2")
    call disp%show("niter = 100; xmin = getFilled(0., ndim); fmin = getSq(xmin); dirset = getMatInit([ndim, ndim], uppLowDia, 0._RKG, 0._RKG, 1._RKG)")
                    niter = 100; xmin = getFilled(0., ndim); fmin = getSq(xmin); dirset = getMatInit([ndim, ndim], uppLowDia, 0._RKG, 0._RKG, 1._RKG)
    call disp%show("call setMinPowell(getSq, xmin, fmin, dirset, epsilon(xmin)**.5, niter)")
                    call setMinPowell(getSq, xmin, fmin, dirset, epsilon(xmin)**.5, niter)
    call disp%show("if (100 < niter) error stop 'minimization failed.'")
                    if (100 < niter) error stop 'minimization failed.'
    call disp%show("[xmin, fmin]")
    call disp%show( [xmin, fmin] )
    call disp%skip()
 
contains
 
    function getSq(x) result(func)
        real(RKG)   , intent(in) :: x(ndim)
        real(RKG)   :: func
        integer(IK) :: idim
        func = sum((x - [real(RKG) :: (idim, idim = 1, ndim)])**2)
    end function
 
end program example

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example output ⛓

 
getSq(x) = (x - [real(RKG) :: 1, 2, 3, 4])**2
niter = 100; xmin = getFilled(0., ndim); fmin = getSq(xmin); dirset = getMatInit([ndim, ndim], uppLowDia, 0._RKG, 0._RKG, 1._RKG)
call setMinPowell(getSq, xmin, fmin, dirset, epsilon(xmin)**.5, niter)
if (100 < niter) error stop 'minimization failed.'
[xmin, fmin]
+1.00000000000000000000000000000000000, +2.00000000000000000000000000000000000, +3.00000000000000000000000000000000077, +4.00000000000000000000000000000000000, +0.593472984109987421717077641847622322E-66
 
 

Test:

test_pm_optimization

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Amir Shahmoradi, Tuesday March 7, 2017, 3:50 AM, Institute for Computational Engineering and Sciences (ICES), The University of Texas Austin

Definition at line 1257 of file pm_optimization.F90.

---

The documentation for this interface was generated from the following file:

• src/fortran/main/pm_optimization.F90